build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath group: 'ch.raffael.gradlePlugins.antlr4', name: 'gradle-antlr4-plugin', version: '1.0'
    }
}

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'application'
apply plugin: 'ch.raffael.antlr4'

idea {
    module {
        sourceDirs += file('src-gen/antlr4')
    }
}

repositories {
    mavenCentral()
}

allprojects {
    sourceCompatibility = 1.8
    targetCompatibility = 1.8
}

antlr4 {
    generateDir = file('src-gen/antlr4')
    source = file('src/main/antlr')
}

version = 'git describe --tags --always HEAD'.execute().text.trim()

processResources {
    inputs.property "version", project.version
    filter(org.apache.tools.ant.filters.ReplaceTokens, tokens: [version: project.version])
}

distributions {
    main {
        mainClassName = "com.ptransportation.LIN.Compiler"
    }
}

compileJava.dependsOn antlr4

dependencies {
    compile 'com.beust:jcommander:1.48'
    compile 'org.antlr:antlr4:4.+'
}