-
Notifications
You must be signed in to change notification settings - Fork 1
/
format.clj
187 lines (169 loc) · 7.72 KB
/
format.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
(ns provisdom.math.format
(:require
[clojure.spec.alpha :as s]
[clojure.spec.gen.alpha :as gen]
[clojure.spec.test.alpha :as st]
[orchestra.spec.test :as ost]
[provisdom.utility-belt.strings :as strings]
[provisdom.math.core :as m]
[clojure.string :as str]))
(s/def ::digits
(s/with-gen ::m/long+
#(gen/large-integer* {:min 1 :max 35})))
(s/def ::max-digits ::digits)
(s/def ::max-length ::m/long+)
(s/def ::decimal-places
(s/with-gen ::m/long-non-
#(gen/large-integer* {:min 0 :max 35})))
(s/def ::max-decimal-places ::decimal-places)
(s/def ::money? boolean?)
(def by-letter
{"T" 1000000000000
"B" 1000000000
"M" 1000000
"K" 1000})
(defn trim-number-as-string
"Trims number of any unnecessary characters e.g. -0.3 and 0.30."
[s]
(let [s (cond (str/starts-with? s "-0") (trim-number-as-string (str "-" (strings/trim-start s "-0")))
(str/includes? s ".") (strings/trim-end s "0")
:else s)]
(strings/trim-start s "0")))
(s/fdef trim-number-as-string
:args (s/cat :s string?)
:ret string?)
(defn format-as-float
"Formats `finite` into float form with a number of decimal places."
[finite decimal-places]
(format (str "%." decimal-places "f") (double finite)))
(s/fdef format-as-float
:args (s/cat :finite ::m/finite :decimal-places ::decimal-places)
:ret string?)
(defn format-as-exponential
"Formats `finite` into exponential form with a number of digits."
([finite] (format-as-exponential finite {}))
([finite {::keys [digits]}]
(if digits
(str/replace
(str/replace
(format (str "%." (long (dec digits)) "E")
(double finite))
"E+0"
"E+")
"E-0"
"E-")
(let [s (str/replace
(str/replace
(format (str "%." 15 "E") (double finite))
"E+0"
"E+")
"E-0"
"E-")]
(loop [s1 s]
(if (str/includes? s1 "0E")
(recur (str/replace s1 "0E" "E"))
s1))))))
(s/fdef format-as-exponential
:args (s/cat :finite ::m/finite
:opts (s/? (s/keys :opt [::digits])))
:ret string?)
(defn format-number
"Formats `number` into its best form."
([number max-length] (format-number number max-length {}))
([number max-length {::keys [max-decimal-places max-digits]}]
(cond (m/nan? number) "NaN"
(m/inf+? number) "Inf"
(m/inf-? number) "-Inf"
:else (let [rounded-number (double (if max-decimal-places
(read-string (format-as-float number max-decimal-places))
number))
rounded-number-as-string (if max-digits
(format-as-exponential rounded-number {::digits max-digits})
(str rounded-number))
shortened-number (if max-digits
(read-string rounded-number-as-string)
rounded-number)
new-max-length (min max-length (count rounded-number-as-string))
standard-digits (count (str (m/round shortened-number :toward-zero)))
want-exponential? (or (and (> standard-digits new-max-length)
(> standard-digits (+ 5.5 (* -0.5 (m/sgn shortened-number)))))
(< (m/abs shortened-number) 0.0001))]
(loop [i (max new-max-length 1)]
(let [s (if want-exponential?
(format-as-exponential shortened-number {::digits i})
(format-as-float shortened-number (dec i)))]
(if (or (m/one? i) (<= (count s) new-max-length))
s
(recur (dec i)))))))))
(s/fdef format-number
:args (s/cat :number ::m/number
:max-length ::max-length
:opts (s/? (s/keys :opt [::max-decimal-places ::max-digits])))
:ret string?)
;;;SHORTHAND
(defn unparse-shorthand
"Converts `number` into shorthand."
([number max-length] (unparse-shorthand number max-length {}))
([number max-length {::keys [max-decimal-places max-digits money?]}]
(cond (m/nan? number) "NaN"
(m/inf+? number) "Inf"
(m/inf-? number) "-Inf"
:else (let [rounded-number (double (if max-decimal-places
(read-string
(format-as-float number max-decimal-places))
number))
shortened-number (if max-digits
(read-string
(format-as-exponential rounded-number {::digits max-digits}))
rounded-number)
absolute-value (m/abs shortened-number)
f (fn [x letter]
(let [adjusted-number (str (format-number (/ x (by-letter letter))
(max 1 (dec max-length))))
without-ending (if (str/ends-with? adjusted-number ".0")
(strings/butlast-string
(strings/butlast-string adjusted-number))
adjusted-number)]
(str without-ending letter)))
s (cond (>= absolute-value 1e15) (format-number shortened-number max-length)
(>= absolute-value (by-letter "T")) (f shortened-number "T")
(>= absolute-value (by-letter "B")) (f shortened-number "B")
(>= absolute-value (by-letter "M")) (f shortened-number "M")
(>= absolute-value (by-letter "K")) (f shortened-number "K")
:else (format-number shortened-number max-length))]
(if money?
(if (neg? shortened-number)
(str "-$" (strings/rest-string s))
(str "$" s))
s)))))
(s/fdef unparse-shorthand
:args (s/cat :number ::m/number
:max-length ::max-length
:opts (s/? (s/keys :opt [::max-decimal-places ::max-digits ::money?])))
:ret string?)
(defn parse-shorthand
"Converts a shorthand string, `s`, into a number if possible. Otherwise
returns nil."
[s]
(let [removed-money (cond (str/starts-with? s "$") (strings/rest-string s)
(str/starts-with? s "-$") (str "-" (strings/trim-start s "-$"))
:else s)]
(case removed-money
"NaN" m/nan
"Inf" m/inf+
"-Inf" m/inf-
(let [f (fn [x letter]
(let [n (read-string (strings/butlast-string x))]
(when (number? n)
(* (by-letter letter) n))))]
(try (cond (str/ends-with? removed-money "T") (f removed-money "T")
(str/ends-with? removed-money "B") (f removed-money "B")
(str/ends-with? removed-money "M") (f removed-money "M")
(str/ends-with? removed-money "K") (f removed-money "K")
:else (let [n (read-string removed-money)]
(when (number? n)
n)))
(catch Exception _ nil))))))
(s/fdef parse-shorthand
:args (s/cat :s string?)
:ret (s/nilable ::m/number))