justfile

default: switch

# Rebuild the system and apply the changes
switch:
    #!/usr/bin/env bash
    set -euo pipefail

    if [ ! -f "host.nix" ]
    then
        echo "host.nix was not found, please generate one using \`just generate-host\` and then try again"
        exit 1
    fi

    echo "Staging host.nix with git add -N and assuming it won't get updated"
    git add -N host.nix && git update-index --assume-unchanged host.nix

    DID_FAIL=0
    OS_NAME="$(uname)"

    case "$OS_NAME" in
        Darwin) just darwin-rebuild-switch ;;
        *) echo "Not sure how to support $OS_NAME" && DID_FAIL=1 ;;
    esac

# Rebuild using darwin-rebuild and apply the changes
darwin-rebuild-switch:
    #!/usr/bin/env bash
    set -euo pipefail

    if command -v darwin-rebuild > /dev/null
    then
        darwin-rebuild switch --flake "$PWD"#macbook
        exit 0
    fi

    echo "darwin-rebuild not found, using nix run instead"
    nix run nix-darwin -- switch --flake "$PWD"#macbook

# Rebuild using darwin-rebuild but don't apply the changes
darwin-rebuild-build:
    #!/usr/bin/env bash
    set -euo pipefail

    if command -v darwin-rebuild > /dev/null
    then
        darwin-rebuild build --flake "$PWD"#macbook
        exit 0
    fi

    echo "darwin-rebuild not found, using nix run instead"
    nix run nix-darwin -- build --flake "$PWD"#macbook

# Rollback using darwin-rebuild
darwin-rebuild-rollback:
    #!/usr/bin/env bash
    set -euo pipefail

    if command -v darwin-rebuild > /dev/null
    then
        darwin-rebuild build --flake "$PWD"#macbook --rollback
        exit 0
    fi

    echo "darwin-rebuild not found, using nix run instead"
    nix run nix-darwin -- build --flake "$PWD"#macbook --rollback

# Run a repl
repl:
    nix repl

# Generate the host file
generate-host:
    #!/usr/bin/env bash
    MESSAGE="This file is automatically generated using \`just generate-host\`"
    printf '# %s\n{ username = "%s"; hostname = "%s"; }\n' "$MESSAGE" "$(whoami)" "$(hostname)" | tee host.nix

# Update the flake
update:
    #!/usr/bin/env bash

    nix flake update

    if [ ! -z "$(git diff --name-only ./flake.lock)" ]
    then
        git add ./flake.lock
        git commit -m "Update Flake inputs" -- ./flake.lock
    fi