build.gradle

buildscript {
    repositories {
        maven {
            url = 'https://files.minecraftforge.net/maven'
        }
        maven {
            url = 'https://maven.cleanroommc.com'
        }
        maven {
            url = 'https://repo.spongepowered.org/maven'
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
        classpath 'org.spongepowered:mixingradle:0.6-SNAPSHOT'
    }
}

apply plugin: 'net.minecraftforge.gradle.forge'
apply plugin: 'org.spongepowered.mixin'

version = project.mod_version
group = project.maven_group
archivesBaseName = project.archives_base_name

sourceCompatibility = targetCompatibility = '1.8'

compileJava {
    sourceCompatibility = targetCompatibility = '1.8'
}

minecraft {
    version = '1.12.2-14.23.5.2847'
    runDir = 'run'
    mappings = 'stable_39'
    def args = []
    args << '-Dfml.coreMods.load=' + coremod_plugin_class_name
    args << '-Dmixin.hotSwap=true'
    args << '-Dmixin.checks.interfaces=true'
    args << '-Dmixin.debug.export=true'
    clientJvmArgs.addAll(args)
    serverJvmArgs.addAll(args)
}

repositories {
    maven {
        url = 'https://maven.cleanroommc.com'
    }
    maven {
        url 'https://cfa2.cursemaven.com'
    }
    maven {
        url 'https://cursemaven.com'
    }
    maven { // CraftTweaker
        url = 'https://maven.blamejared.com/'
    }
    maven {
        url 'https://dvs1.progwml6.com/files/maven/'
    }
    maven {
        url 'https://dl.cloudsmith.io/public/geckolib3/geckolib/maven/'
    }
    maven {
        url 'https://maven.hellfiredev.net/'
    }
    maven {
        url 'https://modmaven.dev/'
    }
}

dependencies {

    compile 'zone.rong:mixinbooter:4.2'

    compileOnly 'curse.maven:ae2-extended-life-570458:4105092'
    compile 'software.bernie.geckolib:forge-1.12.2-geckolib:3.0.21'
    compile 'CraftTweaker2:CraftTweaker2-MC1120-Main:1.12-4.1.20.673'
    compile 'mezz.jei:jei_1.12.2:4.15.0.293'
    compile 'curse.maven:the-one-probe-245211:2667280'

    compileOnly 'curse.maven:baubles-227083:2518667'
    compileOnly "curse.maven:botania-225643:3330934"
    compileOnly 'curse.maven:codechicken-lib-1-8-242818:2779848'
    compileOnly 'curse.maven:extra-utilities-225561:2678374'
    compileOnly 'curse.maven:gregtech-ce-unofficial-557242:4527757'
    compileOnly "curse.maven:lightningcraft-237422:2872478"
    compileOnly 'curse.maven:mcmultipart-239431:2615930'
    compileOnly 'curse.maven:mekanism-268560:2835175'
    compileOnly 'curse.maven:nuclearcraft-overhauled-336895:3386487' // Not very latest, requires Forge 2860
    compileOnly 'curse.maven:qmd-362056:3662442'
    compileOnly 'curse.maven:thaumcraft-223628:2629023'
    compileOnly 'curse.maven:thaumic-jei-285492:2705304'
    compileOnly 'curse.maven:prodigy-tech-297414:2769520'
    compileOnly 'curse.maven:patchouli-306770:3162874'
    compileOnly 'curse.maven:natures-aura-306626:2882138'
    compileOnly 'curse.maven:project-e-226410:2702991'
    compileOnly 'curse.maven:blood-magic-224791:2822288'
    compileOnly 'curse.maven:guide-api-228832:2645992'
    compileOnly 'curse.maven:embers-rekindled-300777:3695248'
    compileOnly 'curse.maven:thaumic-augmentation-319441:3536155'
    compileOnly 'me.desht.pneumaticcraft:pneumaticcraft-repressurized:1.12.2-0.11.9-384'
    compileOnly 'hellfirepvp.astralsorcery:astralsorcery:1.12.2-1.10.23-v161'
}

sourceSets {

    main {
        ext.refMap = 'mixins.' + archives_base_name + '.refmap.json'
    }

}

processResources {
    // this will ensure that this task is redone when the versions change.
    inputs.property 'version', project.version
    inputs.property 'mcversion', project.minecraft.version
    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
        // replace version and mcversion
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
    // copy everything else except the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
    rename '(.+_at.cfg)', 'META-INF/$1' // Access Transformers
}

jar {
    manifest {
        def attribute_map = [:]
        attribute_map['FMLCorePlugin'] = project.coremod_plugin_class_name
        attribute_map['FMLAT'] = 'multiblocked_at.cfg'
        attribute_map['FMLCorePluginContainsFMLMod'] = true
        attribute_map['ForceLoadAsMod'] = true
        attributes(attribute_map)
    }
}