-
Notifications
You must be signed in to change notification settings - Fork 8
/
Coco.atg
533 lines (475 loc) · 23.8 KB
/
Coco.atg
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
/*-------------------------------------------------------------------------
Coco.ATG -- Attributed Grammar
Compiler Generator Coco/R,
Copyright (c) 1990, 2004 Hanspeter Moessenboeck, University of Linz
extended by M. Loeberbauer & A. Woess, Univ. of Linz
ported from C# to Java by W. Ahorner
with improvements by Pat Terry, Rhodes University
This program is free software; you can redistribute it and/or modify it
under the terms of the GNU General Public License as published by the
Free Software Foundation; either version 2, or (at your option) any
later version.
This program is distributed in the hope that it will be useful, but
WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
for more details.
You should have received a copy of the GNU General Public License along
with this program; if not, write to the Free Software Foundation, Inc.,
59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
As an exception, it is allowed to write an extension of Coco/R that is
used as a plugin in non-free software.
If not otherwise stated, any source code generated by Coco/R (other than
Coco/R itself) does not fall under the GNU General Public License.
-------------------------------------------------------------------------*/
/*-------------------------------------------------------------------------
compile with:
javac Coco.Coco Coco.ATG -package Coco
-------------------------------------------------------------------------*/
$package=Coco
COMPILER Coco
static final int id = 0;
static final int str = 1;
public Trace trace; // other Coco objects referenced by this ATG
public Tab tab;
public DFA dfa;
public ParserGen pgen;
boolean genScanner;
String tokenString; // used in declarations of literal tokens
String noString = "-none-"; // used in declarations of literal tokens
/*-------------------------------------------------------------------------*/
CHARACTERS
letter = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz_".
digit = "0123456789".
cr = '\r'.
lf = '\n'.
tab = '\t'.
stringCh = ANY - '"' - '\\' - cr - lf.
charCh = ANY - '\'' - '\\' - cr - lf.
printable = '\u0020' .. '\u007e'.
hex = "0123456789abcdef".
TOKENS
ident = letter { letter | digit }.
number = digit { digit }.
string = '"' { stringCh | '\\' printable } '"'.
badString = '"' { stringCh | '\\' printable } (cr | lf).
char = '\'' ( charCh | '\\' printable { hex } ) '\''.
PRAGMAS
ddtSym = '$' { digit | letter }. (. tab.SetDDT(la.val); .)
optionSym = '$' letter { letter } '='
{ digit | letter
| '-' | '.' | ':'
}. (. tab.SetOption(la.val); .)
COMMENTS FROM "/*" TO "*/" NESTED
COMMENTS FROM "//" TO lf
IGNORE cr + lf + tab
/*-------------------------------------------------------------------------*/
PRODUCTIONS
Coco (. Symbol sym; Graph g, g1, g2; String gramName; CharSet s; int beg; .)
=
[ // import statements
ANY (. beg = t.pos; .)
{ ANY } (. pgen.usingPos = new Position(beg, la.pos, 0); .)
]
"COMPILER" (. genScanner = true;
tab.ignored = new CharSet(); .)
ident (. gramName = t.val;
beg = la.pos;
.)
{ ANY } (. tab.semDeclPos = new Position(beg, la.pos, 0); .)
[ "IGNORECASE" (. dfa.ignoreCase = true; .) ] /* pdt */
[ "CHARACTERS" { SetDecl }]
[ "TOKENS" { TokenDecl<Node.t> }]
[ "PRAGMAS" { TokenDecl<Node.pr> }]
{ "COMMENTS" (. boolean nested = false; .)
"FROM" TokenExpr<out g1>
"TO" TokenExpr<out g2>
[ "NESTED" (. nested = true; .)
] (. dfa.NewComment(g1.l, g2.l, nested); .)
}
{ "IGNORE" Set<out s> (. tab.ignored.Or(s); .)
}
SYNC
"PRODUCTIONS" (. if (genScanner) dfa.MakeDeterministic();
tab.DeleteNodes();
.)
{ ident (. sym = tab.FindSym(t.val);
boolean undef = sym == null;
if (undef) sym = tab.NewSym(Node.nt, t.val, t.line);
else {
if (sym.typ == Node.nt) {
if (sym.graph != null) SemErr("name declared twice");
} else SemErr("this symbol kind not allowed on left side of production");
sym.line = t.line;
}
boolean noAttrs = sym.attrPos == null;
sym.attrPos = null;
boolean noRet = sym.retVar==null;
sym.retVar = null;
.)
[ AttrDecl<sym> ] (. if (!undef)
if (noAttrs != (sym.attrPos == null)
|| noRet != (sym.retVar == null))
SemErr("attribute mismatch between declaration and use of this symbol");
.)
[ SemText<out sym.semPos> ]
WEAK '='
Expression<out g> (. sym.graph = g.l;
tab.Finish(g);
.)
WEAK '.'
}
"END" ident (. if (gramName.compareTo(t.val) != 0)
SemErr("name does not match grammar name");
tab.gramSy = tab.FindSym(gramName);
if (tab.gramSy == null)
SemErr("missing production for grammar name");
else {
sym = tab.gramSy;
if (sym.attrPos != null)
SemErr("grammar symbol must not have attributes");
}
tab.noSym = tab.NewSym(Node.t, "???", 0); // noSym gets highest number
tab.SetupAnys();
tab.RenumberPragmas();
if (tab.ddt[2]) tab.PrintNodes();
if (errors.count == 0) {
System.out.println("checking");
tab.CompSymbolSets();
if (tab.ddt[7]) tab.XRef();
if (tab.GrammarOk()) {
System.out.print("parser");
pgen.WriteParser();
if (genScanner) {
System.out.print(" + scanner");
dfa.WriteScanner();
if (tab.ddt[0]) dfa.PrintStates();
}
System.out.println(" generated");
if (tab.ddt[8]) pgen.WriteStatistics();
}
}
if (tab.ddt[6]) tab.PrintSymbolTable();
.)
'.'
.
/*------------------------------------------------------------------------------------*/
SetDecl (. CharSet s; .)
=
ident (. String name = t.val;
CharClass c = tab.FindCharClass(name);
if (c != null) SemErr("name declared twice");
.)
'=' Set<out s> (. if (s.Elements() == 0) SemErr("character set must not be empty");
c = tab.NewCharClass(name, s);
.)
'.'
.
/*------------------------------------------------------------------------------------*/
Set<out CharSet s> (. CharSet s2; .)
=
SimSet<out s>
{ '+' SimSet<out s2> (. s.Or(s2); .)
| '-' SimSet<out s2> (. s.Subtract(s2); .)
}
.
/*------------------------------------------------------------------------------------*/
SimSet<out CharSet s> (. int n1, n2; .)
= (. s = new CharSet(); .)
( ident (. CharClass c = tab.FindCharClass(t.val);
if (c == null) SemErr("undefined name"); else s.Or(c.set);
.)
| string (. String name = t.val;
name = tab.Unescape(name.substring(1, name.length()-1));
for (int i = 0; i < name.length(); i++)
if (dfa.ignoreCase) s.Set(Character.toLowerCase(name.charAt(i)));
else s.Set(name.charAt(i)); .)
| Char<out n1> (. s.Set(n1); .)
[ ".." Char<out n2> (. for (int i = n1; i <= n2; i++) s.Set(i); .)
]
| "ANY" (. s = new CharSet(); s.Fill(); .)
)
.
/*--------------------------------------------------------------------------------------*/
Char<out int n>
=
char (. String name = t.val; n = 0;
name = tab.Unescape(name.substring(1, name.length()-1));
if (name.length() == 1) n = name.charAt(0);
else SemErr("unacceptable character value");
if (dfa.ignoreCase && (char)n >= 'A' && (char)n <= 'Z') n += 32;
.)
.
/*------------------------------------------------------------------------------------*/
TokenDecl<int typ> (. SymInfo s; Symbol sym; Graph g; .)
=
Sym<out s> (. sym = tab.FindSym(s.name);
if (sym != null) SemErr("name declared twice");
else {
sym = tab.NewSym(typ, s.name, t.line);
sym.tokenKind = Symbol.fixedToken;
}
tokenString = null;
.)
SYNC
( '=' TokenExpr<out g> '.' (. if (s.kind == str) SemErr("a literal must not be declared with a structure");
tab.Finish(g);
if (tokenString == null || tokenString.equals(noString))
dfa.ConvertToStates(g.l, sym);
else { // TokenExpr is a single string
if (tab.literals.get(tokenString) != null)
SemErr("token string declared twice");
tab.literals.put(tokenString, sym);
dfa.MatchLiteral(tokenString, sym);
}
.)
| (. if (s.kind == id) genScanner = false;
else dfa.MatchLiteral(sym.name, sym);
.)
)
[ SemText<out sym.semPos> (. if (typ != Node.pr) SemErr("semantic action not allowed here"); .)
]
.
/*------------------------------------------------------------------------------------*/
AttrDecl<Symbol sym> (. int beg, col; .)
=
'<' // attributes denoted by < ... >
( ('^' | "out") (. beg = la.pos; .)
TypeName (. sym.retType = scanner.buffer.GetString(beg, la.pos); .)
ident (. sym.retVar = t.val; .)
( '>'
| ',' (. beg = la.pos; col = la.col; .)
{ ANY } '>' (. if (t.pos > beg)
sym.attrPos = new Position(beg, t.pos, col); .)
)
| (. beg = la.pos; col = la.col; .)
[ ANY { ANY } ] '>' (. if (t.pos > beg)
sym.attrPos = new Position(beg, t.pos, col); .)
)
|
"<." // attributes denoted by <. ... .>
( ('^' | "out") (. beg = la.pos; .)
TypeName (. sym.retType = scanner.buffer.GetString(beg, la.pos); .)
ident (. sym.retVar = t.val; .)
( ".>"
| ',' (. beg = la.pos; col = la.col; .)
{ ANY } ".>" (. if (t.pos > beg)
sym.attrPos = new Position(beg, t.pos, col); .)
)
| (. beg = la.pos; col = la.col; .)
[ ANY { ANY } ] ".>" (. if (t.pos > beg)
sym.attrPos = new Position(beg, t.pos, col); .)
).
/*------------------------------------------------------------------------------------*/
// type names may contain angle brackets for generics
TypeName
= ident {'.' ident | '[' ']' | '<' TypeName {',' TypeName} '>'}.
/*------------------------------------------------------------------------------------*/
Expression<out Graph g> (. Graph g2; .)
=
Term<out g> (. boolean first = true; .)
{ WEAK '|'
Term<out g2> (. if (first) { tab.MakeFirstAlt(g); first = false; }
tab.MakeAlternative(g, g2);
.)
}
.
/*------------------------------------------------------------------------------------*/
Term<out Graph g> (. Graph g2; Node rslv = null; g = null; .)
=
( [ (. rslv = tab.NewNode(Node.rslv, null, la.line); .)
Resolver<out rslv.pos> (. g = new Graph(rslv); .)
]
Factor<out g2> (. if (rslv != null) tab.MakeSequence(g, g2);
else g = g2;
.)
{ Factor<out g2> (. tab.MakeSequence(g, g2); .)
}
| (. g = new Graph(tab.NewNode(Node.eps, null, 0)); .)
) (. if (g == null) // invalid start of Term
g = new Graph(tab.NewNode(Node.eps, null, 0));
.)
.
/*------------------------------------------------------------------------------------*/
Factor<out Graph g> (. SymInfo s; Position pos; boolean weak = false;
g = null; .)
=
( [ "WEAK" (. weak = true; .)
]
Sym<out s> (. Symbol sym = tab.FindSym(s.name);
if (sym == null && s.kind == str)
sym = (Symbol)tab.literals.get(s.name);
boolean undef = sym == null;
if (undef) {
if (s.kind == id)
sym = tab.NewSym(Node.nt, s.name, 0); // forward nt
else if (genScanner) {
sym = tab.NewSym(Node.t, s.name, t.line);
dfa.MatchLiteral(sym.name, sym);
} else { // undefined string in production
SemErr("undefined string in production");
sym = tab.eofSy; // dummy
}
}
int typ = sym.typ;
if (typ != Node.t && typ != Node.nt)
SemErr("this symbol kind is not allowed in a production");
if (weak)
if (typ == Node.t) typ = Node.wt;
else SemErr("only terminals may be weak");
Node p = tab.NewNode(typ, sym, t.line);
g = new Graph(p);
.)
[ Attribs<p> (. if (s.kind != id) SemErr("a literal must not have attributes"); .)
] (. if (undef) {
sym.attrPos = p.pos; // dummy
sym.retVar = p.retVar; // AH - dummy
} else if ((p.pos == null) != (sym.attrPos == null)
|| (p.retVar == null) != (sym.retVar == null))
SemErr("attribute mismatch between declaration and use of this symbol");
.)
| '(' Expression<out g> ')'
| '[' Expression<out g> ']' (. tab.MakeOption(g); .)
| '{' Expression<out g> '}' (. tab.MakeIteration(g); .)
| SemText<out pos> (. Node p = tab.NewNode(Node.sem, null, 0);
p.pos = pos;
g = new Graph(p);
.)
| "ANY" (. Node p = tab.NewNode(Node.any, null, t.line); // p.set is set in tab.SetupAnys
g = new Graph(p);
.)
| "SYNC" (. Node p = tab.NewNode(Node.sync, null, 0);
g = new Graph(p);
.)
) (. if (g == null) // invalid start of Factor
g = new Graph(tab.NewNode(Node.eps, null, 0));
.)
.
/*------------------------------------------------------------------------------------*/
Resolver<out Position pos>
=
"IF" "(" (. int beg = la.pos; int col = la.col; .)
Condition (. pos = new Position(beg, t.pos, col); .)
.
/*------------------------------------------------------------------------------------*/
Condition = { "(" Condition | ANY } ")" .
/*------------------------------------------------------------------------------------*/
TokenExpr<out Graph g> (. Graph g2; .)
=
TokenTerm<out g> (. boolean first = true; .)
{ WEAK '|'
TokenTerm<out g2> (. if (first) { tab.MakeFirstAlt(g); first = false; }
tab.MakeAlternative(g, g2);
.)
}
.
/*------------------------------------------------------------------------------------*/
TokenTerm<out Graph g> (. Graph g2; .)
=
TokenFactor<out g>
{ TokenFactor<out g2> (. tab.MakeSequence(g, g2); .)
}
[ "CONTEXT"
'(' TokenExpr<out g2> (. tab.SetContextTrans(g2.l); dfa.hasCtxMoves = true;
tab.MakeSequence(g, g2); .)
')'
]
.
/*------------------------------------------------------------------------------------*/
TokenFactor<out Graph g> (. SymInfo s; .)
=
(. g = null; .)
( Sym<out s> (. if (s.kind == id) {
CharClass c = tab.FindCharClass(s.name);
if (c == null) {
SemErr("undefined name");
c = tab.NewCharClass(s.name, new CharSet());
}
Node p = tab.NewNode(Node.clas, null, 0); p.val = c.n;
g = new Graph(p);
tokenString = noString;
} else { // str
g = tab.StrToGraph(s.name);
if (tokenString == null) tokenString = s.name;
else tokenString = noString;
}
.)
| '(' TokenExpr<out g> ')'
| '[' TokenExpr<out g> ']' (. tab.MakeOption(g); tokenString = noString; .)
| '{' TokenExpr<out g> '}' (. tab.MakeIteration(g); tokenString = noString; .)
) (. if (g == null) // invalid start of TokenFactor
g = new Graph(tab.NewNode(Node.eps, null, 0)); .)
.
/*------------------------------------------------------------------------------------*/
Sym<out SymInfo s>
= (. s = new SymInfo(); s.name = "???"; s.kind = id; .)
( ident (. s.kind = id; s.name = t.val; .)
| (string (. s.name = t.val; .)
| char (. s.name = "\"" + t.val.substring(1, t.val.length()-1) + "\""; .)
) (. s.kind = str;
if (dfa.ignoreCase) s.name = s.name.toLowerCase();
if (s.name.indexOf(' ') >= 0)
SemErr("literal tokens must not contain blanks"); .)
)
.
/*------------------------------------------------------------------------------------*/
Attribs<Node n> (. int beg, col; .)
=
'<' // attributes denoted by < ... >
( ('^' | "out") (. beg = la.pos; .)
{ ANY
| Bracketed
| badString (. SemErr("bad string in attributes"); .)
} (. n.retVar = scanner.buffer.GetString(beg, la.pos); .)
( '>'
| ',' (. beg = la.pos; col = la.col; .)
{ ANY
| badString (. SemErr("bad string in attributes"); .)
} '>' (. if (t.pos > beg) n.pos = new Position(beg, t.pos, col); .)
)
| (. beg = la.pos; col = la.col; .)
[ ( ANY
| badString (. SemErr("bad string in attributes"); .)
)
{ ANY
| badString (. SemErr("bad string in attributes"); .)
}
] '>' (. if (t.pos > beg) n.pos = new Position(beg, t.pos, col); .)
)
|
"<." // attributes denoted by <. ... .>
( ('^' | "out") (. beg = la.pos; .)
{ ANY
| Bracketed
| badString (. SemErr("bad string in attributes"); .)
} (. n.retVar = scanner.buffer.GetString(beg, la.pos); .)
( ".>"
| ',' (. beg = la.pos; col = la.col; .)
{ ANY
| badString (. SemErr("bad string in attributes"); .)
} ".>" (. if (t.pos > beg) n.pos = new Position(beg, t.pos, col); .)
)
| (. beg = la.pos; col = la.col; .)
[ ( ANY
| badString (. SemErr("bad string in attributes"); .)
)
{ ANY
| badString (. SemErr("bad string in attributes"); .)
}
] ".>" (. if (t.pos > beg) n.pos = new Position(beg, t.pos, col); .)
)
.
/*------------------------------------------------------------------------------------*/
// skip commas in brackets such as in <out a[i, j], b> or <out a[foo(x, y)], z>
Bracketed
= '(' {Bracketed | ANY} ')' | '[' {Bracketed | ANY} ']'.
/*------------------------------------------------------------------------------------*/
SemText<out Position pos>
=
"(." (. int beg = la.pos; int col = la.col; .)
{ ANY
| badString (. SemErr("bad string in semantic action"); .)
| "(." (. SemErr("missing end of previous semantic action"); .)
}
".)" (. pos = new Position(beg, t.pos, col); .)
.
END Coco.