-
Notifications
You must be signed in to change notification settings - Fork 53
/
kernels.jl
252 lines (227 loc) · 8.83 KB
/
kernels.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
module TestKernels
using GaussianProcesses, Calculus
using Test, LinearAlgebra, Statistics, Random
using ForwardDiff
using GaussianProcesses: EmptyData, update_target_and_dtarget!,
cov_ij, dKij_dθp, dKij_dθ!,
get_params, set_params!, num_params, StationaryARD, WeightedEuclidean
import Calculus: gradient
Random.seed!(1)
const d, n, n2 = 3, 6, 3
function testkernel(kern::Kernel)
X = randn(d, n)
X2 = randn(d, n2)
y = randn(n)
# Random columns
i, j = rand(1:n), rand(1:n2)
Xi = view(X, :, i)
Xj = view(X, :, j) # works since n2 < n
X2j = view(X2, :, j)
# Preallocate some matrices
cK = zeros(n, n)
cK2 = zeros(n, n2)
@test length(GaussianProcesses.get_param_names(kern)) ==
length(get_params(kern)) ==
num_params(kern)
@testset "get and set params" begin
kcopy = deepcopy(kern)
params_1 = randn(num_params(kcopy))
set_params!(kcopy, params_1)
params_2 = get_params(kcopy)
@test params_1 ≈ params_2
end
@testset "Variance" begin
spec = cov(kern, X)
@test spec ≈ invoke(cov, Tuple{Kernel, Matrix{Float64}}, kern, X)
@test spec[i, j] ≈ cov(kern, Xi, Xj)
key = GaussianProcesses.kernel_data_key(kern, X, X)
@test typeof(key) == String
# check we've overwritten the default if necessary
kdata = GaussianProcesses.KernelData(kern, X, X)
if typeof(kdata) != EmptyData
@test key != "EmptyData"
end
end
data = GaussianProcesses.KernelData(kern, X, X)
data12 = GaussianProcesses.KernelData(kern, X, X2)
@testset "Covariance" begin
spec = cov(kern, X, X2)
@test spec[i,j] ≈ cov(kern, Xi, X2j)
spec = cov(kern, X, X2, data12)
@test spec[i,j] ≈ cov(kern, Xi, X2j)
end
@testset "Gradient" begin
nparams = num_params(kern)
init_params = Vector(get_params(kern))
dK = zeros(nparams)
i, j = 3, 5
dKij_dθ!(dK, kern, X, X, data, i, j, d, nparams)
dK1 = copy(dK)
dKij_dθ!(dK, kern, X, X, EmptyData(), i, j, d, nparams)
dK2 = copy(dK)
@test dK1 ≈ dK2
for p in 1:nparams
@test dK[p] ≈ dKij_dθp(kern, X, X, data, i, j, p, d)
@test dK[p] ≈ dKij_dθp(kern, X, X, EmptyData(), i, j, p, d)
try
dkp = dKij_dθp(kern, X, X, i, j, p, d)
@test dkp == dK[p]
catch
# that's OK too
continue
end
end
if nparams > 0
numer_grad = Calculus.gradient(init_params) do params
set_params!(kern, params)
t = cov_ij(kern, X, X, data, i, j, d)
set_params!(kern, init_params)
t
end
theor_grad = dK
@test numer_grad ≈ theor_grad rtol=1e-3 atol=1e-3
end
end
@testset "Gradient stack X1 ≠ X2" begin
nparams = num_params(kern)
init_params = Vector(get_params(kern))
stack1 = Array{Float64}(undef, n, n2, nparams)
stack2 = Array{Float64}(undef, n, n2, nparams)
GaussianProcesses.grad_stack!(stack1, kern, X, X2, data12)
theor_grad = vec(sum(stack1; dims=[1,2]))
if nparams > 0
numer_grad = Calculus.gradient(init_params) do params
set_params!(kern, params)
t = sum(cov(kern, X, X2, data12))
set_params!(kern, init_params)
t
end
@test theor_grad ≈ numer_grad rtol=1e-2 atol=1e-2
end
GaussianProcesses.grad_stack!(stack2, kern, X, X2, EmptyData())
# invoke(GaussianProcesses.grad_stack!,
# Tuple{AbstractArray, Kernel, Matrix{Float64}, Matrix{Float64},
# EmptyData},
# stack2, kern, X, X2, EmptyData())
@test stack1 ≈ stack2 rtol=1e-3 atol=1e-3
end
@testset "Gradient stack" begin
nparams = num_params(kern)
init_params = Vector(get_params(kern))
stack1 = Array{Float64}(undef, n, n, nparams)
stack2 = Array{Float64}(undef, n, n, nparams)
GaussianProcesses.grad_stack!(stack1, kern, X, X, data)
invoke(GaussianProcesses.grad_stack!,
Tuple{AbstractArray, Kernel, Matrix{Float64}, Matrix{Float64},
EmptyData},
stack2, kern, X, X, EmptyData())
@test stack1 ≈ stack2
theor_grad = vec(sum(stack1; dims=[1,2]))
if nparams > 0
numer_grad = Calculus.gradient(init_params) do params
set_params!(kern, params)
t = sum(cov(kern, X))
set_params!(kern, init_params)
t
end
@test theor_grad ≈ numer_grad rtol=1e-1 atol=1e-2
end
end
@testset "dtarget" begin
nparams = num_params(kern)
gp = GPE(X, y, MeanConst(0.0), kern, -3.0)
init_params = Vector(get_params(gp))
update_target_and_dtarget!(gp)
theor_grad = copy(gp.dtarget)
if nparams > 0
numer_grad = Calculus.gradient(init_params) do params
set_params!(gp, params)
update_target!(gp)
t = gp.target
set_params!(gp, init_params)
t
end
@test theor_grad ≈ numer_grad rtol=1e-3 atol=1e-3
end
end
@testset "EmptyData" begin
gp = GPE(X, y, MeanConst(0.0), kern, -3.0)
gp_empty = GPE(X, y, MeanConst(0.0), kern, -3.0, EmptyData())
update_target_and_dtarget!(gp_empty)
update_target_and_dtarget!(gp)
@test gp.dmll ≈ gp_empty.dmll rtol=1e-6 atol=1e-6
end
@testset "predict gradient" begin
gp = GPE(X, y, MeanConst(0.0), kern, -3.0)
f = x -> sum(predict_y(gp, reshape(x, :, 1)))[1]
z = rand(d)
autodiff_grad = ForwardDiff.gradient(f, z)
numer_grad = Calculus.gradient(f, z)
@test autodiff_grad ≈ numer_grad rtol = 1e-3 atol = 1e-3
end
end
@testset "kernel shortcuts" begin
x1 = [0.1, 0.2]
x2 = [1.1, 1.0]
for pairs in [
(SEIso(1.0, 1.2), SE(1.0, 1.2)),
(SEArd([1.0, 1.5], 1.3), SE([1.0, 1.5], 1.3)),
(RQIso(1.0, 1.2, 0.5), RQ(1.0, 1.2, 0.5)),
(RQArd([1.0, 1.5], 1.3, 0.5), RQ([1.0, 1.5], 1.3, 0.5)),
(Matern(1/2, 1.0, 1.2), Mat12Iso(1.0, 1.2)),
(Matern(3/2, 1.0, 1.2), Mat32Iso(1.0, 1.2)),
(Matern(5/2, 1.0, 1.2), Mat52Iso(1.0, 1.2)),
(Matern(1/2, [1.0, 1.5], 1.2), Mat12Ard([1.0, 1.5], 1.2)),
(Matern(3/2, [1.0, 1.5], 1.2), Mat32Ard([1.0, 1.5], 1.2)),
(Matern(5/2, [1.0, 1.5], 1.2), Mat52Ard([1.0, 1.5], 1.2)),
(Lin(1.0), LinIso(1.0)),
(Lin([1.0, 1.5]), LinArd([1.0, 1.5])),
]
@test cov(pairs[1], x1, x2) == cov(pairs[2], x1, x2)
end
end
@testset "Kernels" begin
ll = rand(d)
kernels = [# Isotropic kernels
SEIso(1.0, 1.0), Mat12Iso(1.0,1.0), Mat32Iso(1.0,1.0), Mat52Iso(1.0,1.0),
RQIso(1.0, 1.0, 1.0), Periodic(1.0, 1.0, 2π),
# Non-isotropic
Lin(1.0), Poly(0.0, 0.0, 2), Noise(1.0),
# Constant kernel
Const(1.0),
# ARD kernels
SEArd(ll, 1.0), Mat12Ard(ll, 1.0), Mat32Ard(ll, 1.0), Mat52Ard(ll, 1.0),
RQArd(ll, 0.0, 2.0), LinArd(ll),
# Composite kernels
SEIso(1.0, 1.0) + Mat12Iso(1.0, 1.0),
(SEIso(1.0, 1.0) + Mat12Iso(1.0, 1.0)) + Lin(1.0),
SEIso(1.0, 1.0) * Mat12Iso(1.0, 1.0),
(SEIso(1.0, 1.0) * Mat12Iso(1.0, 1.0)) * Lin(1.0),
# Fixed Kernel
fix(RQIso(1.0, 1.0, 1.0), :lσ),
fix(RQIso(1.0, 1.0, 1.0)),
# Sum and Product and Fix
SEIso(1.0, 1.0) * Mat12Iso(1.0, 1.0) +
Lin(1.0) * fix(RQIso(1.0, 1.0, 1.0), :lσ)]
@testset for kern in kernels
println("\tTesting ", nameof(typeof(kern)), "...")
testkernel(kern)
end
@testset "Masked" for kernel in kernels
println("\tTesting masked", nameof(typeof(kernel)), "...")
if isa(kernel, LinArd) || isa(kernel, GaussianProcesses.StationaryARD)
par = get_params(kernel)
k_masked = typeof(kernel).name.wrapper([par[1]], par[d+1:end]...)
kern = Masked(k_masked, [1])
else
kern = Masked(kernel, [1])
end
println("\tTesting masked ", nameof(typeof(kern)), "...")
testkernel(kern)
end
@testset "autodiff" for kernel in kernels[1:end-1]
println("\tTesting autodiff ", nameof(typeof(kernel)), "...")
testkernel(autodiff(kernel))
end
end # testset
end # module