-
Notifications
You must be signed in to change notification settings - Fork 2
/
uFileUtils.pas
103 lines (88 loc) · 2.96 KB
/
uFileUtils.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
unit uFileUtils;
interface
uses
System.Classes, Winapi.ShellAPI, Winapi.Windows;
function FileNameHasExecutableExtension(const AFileName: string): Boolean;
function FileTimeToDateTime(AFileTime: TFileTime): TDateTime;
procedure FindExecutableFiles(ASourceFiles: TStrings; ADestFiles: TStrings);
function GetFileInfo(const AFileName: string): SHFILEINFO;
function GetFileTypeName(const AFileName: string): string;
implementation
uses
System.SysUtils, System.IOUtils, System.Types;
// ----------------------------------------------------------------------------
function FileNameHasExecutableExtension(const AFileName: string): Boolean;
const
EXECUTABLE_FILE_EXTENSIONS = '|.exe|.dll|.ocx|.bpl|.cpl|.scr|';
begin
Result := AnsiPos('|' + LowerCase(ExtractFileExt(AFileName)) + '|', EXECUTABLE_FILE_EXTENSIONS) > 0;
end;
// ----------------------------------------------------------------------------
function FileTimeToDateTime(AFileTime: TFileTime): TDateTime;
var
LModifiedTime: TFileTime;
LSystemTime: TSystemTime;
begin
Result := 0;
if (AFileTime.dwLowDateTime = 0) and (AFileTime.dwHighDateTime = 0) then
Exit;
try
FileTimeToLocalFileTime(AFileTime, LModifiedTime);
FileTimeToSystemTime(LModifiedTime, LSystemTime);
Result := SystemTimeToDateTime(LSystemTime);
except
Result := Now;
end;
end;
// ----------------------------------------------------------------------------
procedure FindExecutableFiles(ASourceFiles: TStrings; ADestFiles: TStrings);
procedure CheckForExecutable(const AFileName: string);
begin
if FileNameHasExecutableExtension(AFileName) then
ADestFiles.Add(AFileName);
end;
var
i: Integer;
LSourceFile: string;
LDiscoveredFiles: TStringDynArray;
LFileAttributes: TFileAttributes;
begin
ADestFiles.Clear;
for LSourceFile in ASourceFiles do
begin
try
LFileAttributes := TPath.GetAttributes(LSourceFile);
if (TFileAttribute.faDirectory in LFileAttributes) then
begin
LDiscoveredFiles := TDirectory.GetFiles(LSourceFile, '*', TSearchOption.soAllDirectories);
for i := 0 to Length(LDiscoveredFiles) - 1 do
CheckForExecutable(LDiscoveredFiles[i]);
end
else
CheckForExecutable(LSourceFile);
except
end;
end;
end;
// ----------------------------------------------------------------------------
function GetFileInfo(const AFileName: string): SHFILEINFO;
var
LFileExtension: string;
begin
LFileExtension := '*' + ExtractFileExt(AFileName);
SHGetFileInfo(PChar(LFileExtension),
FILE_ATTRIBUTE_NORMAL,
Result,
SizeOf(Result),
SHGFI_TYPENAME or SHGFI_USEFILEATTRIBUTES
);
end;
// ----------------------------------------------------------------------------
function GetFileTypeName(const AFileName: string): string;
var
LFileInfo: SHFILEINFO;
begin
LFileInfo := GetFileInfo(AFileName);
Result := LFileInfo.szTypeName;
end;
end.