-
Notifications
You must be signed in to change notification settings - Fork 460
/
SlicerCPack.cmake
219 lines (188 loc) · 9.34 KB
/
SlicerCPack.cmake
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
if(Slicer_USE_PYTHONQT)
# Python install rules are common to both 'bundled' and 'regular' package
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallPython.cmake)
endif()
if(Slicer_USE_PYTHONQT_WITH_TCL)
# Tcl install rules are common to both 'bundled' and 'regular' package
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallTcl.cmake)
endif()
set(SlicerBlockInstallQtPlugins_subdirectories imageformats sqldrivers)
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallQtPlugins.cmake)
if(Slicer_BUILD_DICOM_SUPPORT)
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallDCMTKApps.cmake)
endif()
set(CPACK_INSTALL_CMAKE_PROJECTS)
# Install CTK Apps and Plugins (PythonQt modules, QtDesigner plugins ...)
if(NOT "${CTK_DIR}" STREQUAL "" AND EXISTS "${CTK_DIR}/CTK-build/CMakeCache.txt")
set(CPACK_INSTALL_CMAKE_PROJECTS "${CPACK_INSTALL_CMAKE_PROJECTS};${CTK_DIR}/CTK-build;CTK;RuntimeApplications;/")
set(CPACK_INSTALL_CMAKE_PROJECTS "${CPACK_INSTALL_CMAKE_PROJECTS};${CTK_DIR}/CTK-build;CTK;RuntimePlugins;/")
endif()
if(NOT APPLE)
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallQt.cmake)
if(Slicer_BUILD_DICOM_SUPPORT)
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallDCMTKLibs.cmake)
endif()
if(Slicer_USE_PYTHONQT)
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallPythonQt.cmake)
endif()
if(Slicer_USE_PYTHONQT_WITH_OPENSSL)
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallOpenSSL.cmake)
endif()
if(Slicer_USE_QtTesting)
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallQtTesting.cmake)
endif()
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallLibArchive.cmake)
include(InstallRequiredSystemLibraries)
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallCMakeProjects.cmake)
# Remove development files installed by teem. Ideally, teem project itself should be updated.
# See http://na-mic.org/Mantis/view.php?id=3455
set(dollar "$")
install(CODE "execute_process(COMMAND \"@CMAKE_COMMAND@\" -E remove_directory \"${dollar}{CMAKE_INSTALL_PREFIX}/${Slicer_INSTALL_ROOT}include/teem\")")
foreach(file
lib/Teem-1.10.0/TeemBuildSettings.cmake
lib/Teem-1.10.0/TeemConfig.cmake
lib/Teem-1.10.0/TeemLibraryDepends.cmake
lib/Teem-1.10.0/TeemUse.cmake
)
install(CODE "execute_process(COMMAND \"@CMAKE_COMMAND@\" -E remove \"${dollar}{CMAKE_INSTALL_PREFIX}/${Slicer_INSTALL_ROOT}${file}\")")
endforeach()
else()
set(CMAKE_INSTALL_NAME_TOOL "" CACHE FILEPATH "" FORCE)
if(Slicer_USE_PYTHONQT)
include(${Slicer_CMAKE_DIR}/SlicerBlockInstallExternalPythonModules.cmake)
endif()
# Generate qt.conf
file(WRITE ${Slicer_BINARY_DIR}/CMake/qt.conf-to-install
"[Paths]
Plugins = ${Slicer_QtPlugins_DIR}
")
# .. and install
install(FILES ${Slicer_BINARY_DIR}/CMake/qt.conf-to-install
DESTINATION ${Slicer_INSTALL_ROOT}Resources
COMPONENT Runtime
RENAME qt.conf)
set(fixup_path @rpath)
set(slicer_cpack_bundle_fixup_directory ${Slicer_BINARY_DIR}/CMake/SlicerCPackBundleFixup)
configure_file(
"${Slicer_SOURCE_DIR}/CMake/SlicerCPackBundleFixup.cmake.in"
"${slicer_cpack_bundle_fixup_directory}/SlicerCPackBundleFixup.cmake"
@ONLY)
# HACK - For a given directory, "install(SCRIPT ...)" rule will be evaluated first,
# let's make sure the following install rule is evaluated within its own directory.
# Otherwise, the associated script will be executed before any other relevant install rules.
file(WRITE ${slicer_cpack_bundle_fixup_directory}/CMakeLists.txt
"install(SCRIPT \"${slicer_cpack_bundle_fixup_directory}/SlicerCPackBundleFixup.cmake\")")
add_subdirectory(${slicer_cpack_bundle_fixup_directory} ${slicer_cpack_bundle_fixup_directory}-binary)
endif()
# Install additional projects if any, but also do a find_package to load CPACK
# variables of the Slicer_MAIN_PROJECT if different from SlicerApp
set(additional_projects ${Slicer_ADDITIONAL_DEPENDENCIES} ${Slicer_ADDITIONAL_PROJECTS})
foreach(additional_project ${additional_projects})
find_package(${additional_project})
if (${additional_project}_FOUND)
if (${additional_project}_USE_FILE)
include(${${additional_project}_USE_FILE})
endif()
if(NOT APPLE)
if (DEFINED ${additional_project}_CPACK_INSTALL_CMAKE_PROJECTS)
set(CPACK_INSTALL_CMAKE_PROJECTS
"${CPACK_INSTALL_CMAKE_PROJECTS};${${additional_project}_CPACK_INSTALL_CMAKE_PROJECTS}")
endif()
endif()
endif()
endforeach()
# Install Slicer
set(CPACK_INSTALL_CMAKE_PROJECTS "${CPACK_INSTALL_CMAKE_PROJECTS};${Slicer_BINARY_DIR};Slicer;ALL;/")
# -------------------------------------------------------------------------
# Package properties
# -------------------------------------------------------------------------
set(CPACK_MONOLITHIC_INSTALL ON)
set(Slicer_CPACK_PACKAGE_NAME ${SlicerApp_APPLICATION_NAME})
set(Slicer_CPACK_PACKAGE_VENDOR "NA-MIC")
set(Slicer_CPACK_PACKAGE_DESCRIPTION_FILE "${Slicer_SOURCE_DIR}/README.txt")
set(Slicer_CPACK_PACKAGE_DESCRIPTION_SUMMARY
"Medical Visualization and Processing Environment for Research")
set(Slicer_CPACK_RESOURCE_FILE_LICENSE "${Slicer_SOURCE_DIR}/License.txt")
set(Slicer_CPACK_PACKAGE_VERSION_MAJOR "${Slicer_VERSION_MAJOR}")
set(Slicer_CPACK_PACKAGE_VERSION_MINOR "${Slicer_VERSION_MINOR}")
set(Slicer_CPACK_PACKAGE_VERSION_PATCH "${Slicer_VERSION_PATCH}")
set(Slicer_CPACK_PACKAGE_VERSION "${Slicer_VERSION_FULL}")
set(Slicer_CPACK_PACKAGE_ICON "${Slicer_SOURCE_DIR}/Resources/Slicer.icns")
set(project ${${Slicer_MAIN_PROJECT}_APPLICATION_NAME})
set(CPACK_PACKAGE_NAME ${${project}_CPACK_PACKAGE_NAME})
set(CPACK_PACKAGE_VENDOR ${${project}_CPACK_PACKAGE_VENDOR})
set(CPACK_PACKAGE_DESCRIPTION_SUMMARY ${${project}_CPACK_PACKAGE_DESCRIPTION_SUMMARY})
set(CPACK_PACKAGE_DESCRIPTION_FILE ${${project}_CPACK_PACKAGE_DESCRIPTION_FILE})
set(CPACK_RESOURCE_FILE_LICENSE ${${project}_CPACK_RESOURCE_FILE_LICENSE})
set(CPACK_PACKAGE_VERSION_MAJOR ${${project}_CPACK_PACKAGE_VERSION_MAJOR})
set(CPACK_PACKAGE_VERSION_MINOR ${${project}_CPACK_PACKAGE_VERSION_MINOR})
set(CPACK_PACKAGE_VERSION_PATCH ${${project}_CPACK_PACKAGE_VERSION_PATCH})
set(CPACK_PACKAGE_VERSION ${${project}_CPACK_PACKAGE_VERSION})
set(CPACK_SYSTEM_NAME "${Slicer_OS}-${Slicer_ARCHITECTURE}")
if(APPLE)
set(CPACK_PACKAGE_ICON ${${project}_CPACK_PACKAGE_ICON})
endif()
set(CPACK_PACKAGE_INSTALL_DIRECTORY "${CPACK_PACKAGE_NAME} ${CPACK_PACKAGE_VERSION}")
# Installers for 32- vs. 64-bit CMake:
# - Root install directory (displayed to end user at installer-run time)
# - "NSIS package/display name" (text used in the installer GUI)
# - Registry key used to store info about the installation
if(CMAKE_CL_64)
set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_INSTALL_DIRECTORY} (Win64)")
set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "${CPACK_PACKAGE_NAME} ${CPACK_PACKAGE_VERSION} (Win64)")
else()
set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES")
set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_INSTALL_DIRECTORY}")
set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "${CPACK_PACKAGE_NAME} ${CPACK_PACKAGE_VERSION}")
endif()
# Slicer does *NOT* require setting the windows path
set(CPACK_NSIS_MODIFY_PATH OFF)
set(APPLICATION_NAME "${Slicer_MAIN_PROJECT_APPLICATION_NAME}")
set(EXECUTABLE_NAME "${Slicer_MAIN_PROJECT_APPLICATION_NAME}")
set(CPACK_PACKAGE_EXECUTABLES "..\\\\${EXECUTABLE_NAME}" "${APPLICATION_NAME}")
# -------------------------------------------------------------------------
# File extensions
# -------------------------------------------------------------------------
set(FILE_EXTENSIONS .mrml .xcat .mrb)
if(FILE_EXTENSIONS)
# For NSIS (Win32) now, we will add MacOSX support later (get back to Wes)
if(WIN32 AND NOT UNIX)
set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS)
set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS)
foreach(ext ${FILE_EXTENSIONS})
string(LENGTH "${ext}" len)
math(EXPR len_m1 "${len} - 1")
string(SUBSTRING "${ext}" 1 ${len_m1} ext_wo_dot)
set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
"${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}
WriteRegStr HKCR \\\"${APPLICATION_NAME}\\\" \\\"\\\" \\\"${APPLICATION_NAME} supported file\\\"
WriteRegStr HKCR \\\"${APPLICATION_NAME}\\\\shell\\\\open\\\\command\\\" \\\"\\\" \\\"$\\\\\\\"$INSTDIR\\\\${EXECUTABLE_NAME}.exe$\\\\\\\" $\\\\\\\"%1$\\\\\\\"\\\"
WriteRegStr HKCR \\\"${ext}\\\" \\\"\\\" \\\"${APPLICATION_NAME}\\\"
WriteRegStr HKCR \\\"${ext}\\\" \\\"Content Type\\\" \\\"application/x-${ext_wo_dot}\\\"
")
set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS "${CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS}
DeleteRegKey HKCR \\\" ${APPLICATION_NAME}\\\"
DeleteRegKey HKCR \\\"${ext}\\\"
")
endforeach()
endif()
endif()
# -------------------------------------------------------------------------
# Disable source generator enabled by default
# -------------------------------------------------------------------------
set(CPACK_SOURCE_TBZ2 OFF CACHE BOOL "Enable to build TBZ2 source packages" FORCE)
set(CPACK_SOURCE_TGZ OFF CACHE BOOL "Enable to build TGZ source packages" FORCE)
set(CPACK_SOURCE_TZ OFF CACHE BOOL "Enable to build TZ source packages" FORCE)
# -------------------------------------------------------------------------
# Enable generator
# -------------------------------------------------------------------------
if(UNIX)
set(CPACK_GENERATOR "TGZ")
if(APPLE)
set(CPACK_GENERATOR "DragNDrop")
endif()
elseif(WIN32)
set(CPACK_GENERATOR "NSIS")
endif()
include(CPack)