/
base.dic
159 lines (151 loc) · 3.25 KB
/
base.dic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
/**
* モデルの重みとバイアスを1次元配列に読み込む
*/
Reversi.AI.ImproveEvaluate.initialize {
// 既にモデルを読み込んでいるなら飛ばす
if ARRAYSIZE(layer1) > 0 && ARRAYSIZE(layer2) > 0 && ARRAYSIZE(layer3) > 0 {
return
}
_ = FOPEN(C.model, 'r')
// linear(128->128)
layer1 = IARRAY
_w = IARRAY
for _i = 0; _i < 128 * 128; _i++ {
_s = FREAD(C.model)
_w ,= TOREAL(_s)
}
for _i = 0; _i < 128; _i++ {
for _j = 0; _j < 128; _j++ {
layer1 ,= _w[_i * 128 + _j]
}
_s = FREAD(C.model)
layer1 ,= TOREAL(_s)
}
// linear(128->64)
layer2 = IARRAY
_w = IARRAY
for _i = 0; _i < 64 * 128; _i++ {
_s = FREAD(C.model)
_w ,= TOREAL(_s)
}
for _i = 0; _i < 64; _i++ {
for _j = 0; _j < 128; _j++ {
layer2 ,= _w[_i * 128 + _j]
}
_s = FREAD(C.model)
layer2 ,= TOREAL(_s)
}
// linear(64->1)
layer3 = IARRAY
for _i = 0; _i < 64 + 1; _i++ {
_s = FREAD(C.model)
layer3 ,= TOREAL(_s)
}
_ = FCLOSE(C.model)
LOGGING("load successful")
}
Reversi.AI.ImproveEvaluate.destroy {
ERASEVAR("layer1", "layer2", "layer3")
}
Reversi.AI.ImproveEvaluate.think {
_v = Reversi.AI.ImproveEvaluate.NegaAlpha(C.depth)
_v
return
}
/**
* LeakyReLU関数
*/
Reversi.AI.ImproveEvaluate.LeakyReLU {
_x = _argv[0]
if _x >= 0 {
_x
}
else {
0.01 * _x
}
return
}
/**
* tanhを使用したSigmoid関数
*/
Reversi.AI.ImproveEvaluate.Sigmoid {
_x = _argv[0]
(TANH(_x / 2) + 1) / 2
return
}
/**
* 順方向伝播
*/
Reversi.AI.ImproveEvaluate.forward {
// layer1
_x = _argv
// bias
_x ,= 1
_y = IARRAY
for _n = 0; _n < 128; _n++ {
_sum = 0
for _m = 0; _m < 128 + 1; _m++ {
_sum += layer1[_n * (128 + 1) + _m] * _x[_m]
}
_y ,= _sum
}
_x = _y
_y = IARRAY
for _i = 0; _i < 128; _i++ {
_y ,= Reversi.AI.ImproveEvaluate.LeakyReLU(_x[_i])
}
// layer2
_x = _y
// bias
_x ,= 1
_y = IARRAY
for _n = 0; _n < 64; _n++ {
_sum = 0
for _m = 0; _m < 128 + 1; _m++ {
_sum += layer2[_n * (128 + 1) + _m] * _x[_m]
}
_y ,= _sum
}
_x = _y
_y = IARRAY
for _i = 0; _i < 64; _i++ {
_y ,= Reversi.AI.ImproveEvaluate.LeakyReLU(_x[_i])
}
// layer3
_x = _y
// bias
_x ,= 1
_y = IARRAY
_sum = 0
for _m = 0; _m < 64 + 1; _m++ {
_sum += layer3[_m] * _x[_m]
}
_y = _sum
_x = _y
_y = Reversi.AI.ImproveEvaluate.Sigmoid(_x)
_y
return
}
/**
* モデルによる評価値の計算
*/
Reversi.AI.ImproveEvaluate.evaluate {
_tensor = IARRAY
for _i = 0; _i < ARRAYSIZE(board); _i++ {
if board[_i] == 0 {
_tensor ,= 0
_tensor ,= 0
}
elseif board[_i] == color {
_tensor ,= 1
_tensor ,= 0
}
else {
_tensor ,= 0
_tensor ,= 1
}
}
_rate = Reversi.AI.ImproveEvaluate.forward(_tensor)
_rate
return
}