-
Notifications
You must be signed in to change notification settings - Fork 25
/
context_implementations.jl
665 lines (592 loc) · 22.9 KB
/
context_implementations.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
using Distributions:
UnivariateDistribution, MultivariateDistribution, MatrixDistribution, Distribution
const AMBIGUITY_MSG =
"Ambiguous `LHS .~ RHS` or `@. LHS ~ RHS` syntax. The broadcasting " *
"can either be column-wise following the convention of Distributions.jl or " *
"element-wise following Julia's general broadcasting semantics. Please make sure " *
"that the element type of `LHS` is not a supertype of the support type of " *
"`AbstractVector` to eliminate ambiguity."
alg_str(spl::Sampler) = string(nameof(typeof(spl.alg)))
# utility funcs for querying sampler information
require_gradient(spl::Sampler) = false
require_particles(spl::Sampler) = false
# Allows samplers, etc. to hook into the final logp accumulation in the tilde-pipeline.
function acclogp_assume!!(context::AbstractContext, vi::AbstractVarInfo, logp)
return acclogp!!(context, vi, logp)
end
function acclogp_observe!!(context::AbstractContext, vi::AbstractVarInfo, logp)
return acclogp!!(context, vi, logp)
end
# assume
"""
tilde_assume(context::SamplingContext, right, vn, vi)
Handle assumed variables, e.g., `x ~ Normal()` (where `x` does occur in the model inputs),
accumulate the log probability, and return the sampled value with a context associated
with a sampler.
Falls back to
```julia
tilde_assume(context.rng, context.context, context.sampler, right, vn, vi)
```
"""
function tilde_assume(context::SamplingContext, right, vn, vi)
return tilde_assume(context.rng, context.context, context.sampler, right, vn, vi)
end
# Leaf contexts
function tilde_assume(context::AbstractContext, args...)
return tilde_assume(NodeTrait(tilde_assume, context), context, args...)
end
function tilde_assume(::IsLeaf, context::AbstractContext, right, vn, vi)
return assume(right, vn, vi)
end
function tilde_assume(::IsParent, context::AbstractContext, args...)
return tilde_assume(childcontext(context), args...)
end
function tilde_assume(rng, context::AbstractContext, args...)
return tilde_assume(NodeTrait(tilde_assume, context), rng, context, args...)
end
function tilde_assume(::IsLeaf, rng, context::AbstractContext, sampler, right, vn, vi)
return assume(rng, sampler, right, vn, vi)
end
function tilde_assume(::IsParent, rng, context::AbstractContext, args...)
return tilde_assume(rng, childcontext(context), args...)
end
function tilde_assume(context::PriorContext{<:NamedTuple}, right, vn, vi)
if haskey(context.vars, getsym(vn))
vi = setindex!!(vi, vectorize(right, get(context.vars, vn)), vn)
settrans!!(vi, false, vn)
end
return tilde_assume(PriorContext(), right, vn, vi)
end
function tilde_assume(
rng::Random.AbstractRNG, context::PriorContext{<:NamedTuple}, sampler, right, vn, vi
)
if haskey(context.vars, getsym(vn))
vi = setindex!!(vi, vectorize(right, get(context.vars, vn)), vn)
settrans!!(vi, false, vn)
end
return tilde_assume(rng, PriorContext(), sampler, right, vn, vi)
end
function tilde_assume(context::LikelihoodContext{<:NamedTuple}, right, vn, vi)
if haskey(context.vars, getsym(vn))
vi = setindex!!(vi, vectorize(right, get(context.vars, vn)), vn)
settrans!!(vi, false, vn)
end
return tilde_assume(LikelihoodContext(), right, vn, vi)
end
function tilde_assume(
rng::Random.AbstractRNG,
context::LikelihoodContext{<:NamedTuple},
sampler,
right,
vn,
vi,
)
if haskey(context.vars, getsym(vn))
vi = setindex!!(vi, vectorize(right, get(context.vars, vn)), vn)
settrans!!(vi, false, vn)
end
return tilde_assume(rng, LikelihoodContext(), sampler, right, vn, vi)
end
function tilde_assume(::LikelihoodContext, right, vn, vi)
return assume(NoDist(right), vn, vi)
end
function tilde_assume(rng::Random.AbstractRNG, ::LikelihoodContext, sampler, right, vn, vi)
return assume(rng, sampler, NoDist(right), vn, vi)
end
function tilde_assume(context::PrefixContext, right, vn, vi)
return tilde_assume(context.context, right, prefix(context, vn), vi)
end
function tilde_assume(rng, context::PrefixContext, sampler, right, vn, vi)
return tilde_assume(rng, context.context, sampler, right, prefix(context, vn), vi)
end
"""
tilde_assume!!(context, right, vn, vi)
Handle assumed variables, e.g., `x ~ Normal()` (where `x` does occur in the model inputs),
accumulate the log probability, and return the sampled value and updated `vi`.
By default, calls `tilde_assume(context, right, vn, vi)` and accumulates the log
probability of `vi` with the returned value.
"""
function tilde_assume!!(context, right, vn, vi)
value, logp, vi = tilde_assume(context, right, vn, vi)
return value, acclogp_assume!!(context, vi, logp)
end
# observe
"""
tilde_observe(context::SamplingContext, right, left, vi)
Handle observed constants with a `context` associated with a sampler.
Falls back to `tilde_observe(context.context, context.sampler, right, left, vi)`.
"""
function tilde_observe(context::SamplingContext, right, left, vi)
return tilde_observe(context.context, context.sampler, right, left, vi)
end
# Leaf contexts
function tilde_observe(context::AbstractContext, args...)
return tilde_observe(NodeTrait(tilde_observe, context), context, args...)
end
tilde_observe(::IsLeaf, context::AbstractContext, args...) = observe(args...)
function tilde_observe(::IsParent, context::AbstractContext, args...)
return tilde_observe(childcontext(context), args...)
end
tilde_observe(::PriorContext, right, left, vi) = 0, vi
tilde_observe(::PriorContext, sampler, right, left, vi) = 0, vi
# `MiniBatchContext`
function tilde_observe(context::MiniBatchContext, right, left, vi)
logp, vi = tilde_observe(context.context, right, left, vi)
return context.loglike_scalar * logp, vi
end
function tilde_observe(context::MiniBatchContext, sampler, right, left, vi)
logp, vi = tilde_observe(context.context, sampler, right, left, vi)
return context.loglike_scalar * logp, vi
end
# `PrefixContext`
function tilde_observe(context::PrefixContext, right, left, vi)
return tilde_observe(context.context, right, left, vi)
end
"""
tilde_observe!!(context, right, left, vname, vi)
Handle observed variables, e.g., `x ~ Normal()` (where `x` does occur in the model inputs),
accumulate the log probability, and return the observed value and updated `vi`.
Falls back to `tilde_observe!!(context, right, left, vi)` ignoring the information about variable name
and indices; if needed, these can be accessed through this function, though.
"""
function tilde_observe!!(context, right, left, vname, vi)
return tilde_observe!!(context, right, left, vi)
end
"""
tilde_observe(context, right, left, vi)
Handle observed constants, e.g., `1.0 ~ Normal()`, accumulate the log probability, and
return the observed value.
By default, calls `tilde_observe(context, right, left, vi)` and accumulates the log
probability of `vi` with the returned value.
"""
function tilde_observe!!(context, right, left, vi)
logp, vi = tilde_observe(context, right, left, vi)
return left, acclogp_observe!!(context, vi, logp)
end
function assume(rng, spl::Sampler, dist)
return error("DynamicPPL.assume: unmanaged inference algorithm: $(typeof(spl))")
end
function observe(spl::Sampler, weight)
return error("DynamicPPL.observe: unmanaged inference algorithm: $(typeof(spl))")
end
# fallback without sampler
function assume(dist::Distribution, vn::VarName, vi)
r, logp = invlink_with_logpdf(vi, vn, dist)
return r, logp, vi
end
# SampleFromPrior and SampleFromUniform
function assume(
rng::Random.AbstractRNG,
sampler::Union{SampleFromPrior,SampleFromUniform},
dist::Distribution,
vn::VarName,
vi::VarInfoOrThreadSafeVarInfo,
)
if haskey(vi, vn)
# Always overwrite the parameters with new ones for `SampleFromUniform`.
if sampler isa SampleFromUniform || is_flagged(vi, vn, "del")
unset_flag!(vi, vn, "del")
r = init(rng, dist, sampler)
BangBang.setindex!!(
vi, vectorize(dist, maybe_reconstruct_and_link(vi, vn, dist, r)), vn
)
setorder!(vi, vn, get_num_produce(vi))
else
# Otherwise we just extract it.
r = vi[vn, dist]
end
else
r = init(rng, dist, sampler)
if istrans(vi)
push!!(vi, vn, reconstruct_and_link(dist, r), dist, sampler)
# By default `push!!` sets the transformed flag to `false`.
settrans!!(vi, true, vn)
else
push!!(vi, vn, r, dist, sampler)
end
end
# HACK: The above code might involve an `invlink` somewhere, etc. so we need to correct.
logjac = logabsdetjac(istrans(vi, vn) ? link_transform(dist) : identity, r)
return r, logpdf(dist, r) - logjac, vi
end
# default fallback (used e.g. by `SampleFromPrior` and `SampleUniform`)
observe(sampler::AbstractSampler, right, left, vi) = observe(right, left, vi)
function observe(right::Distribution, left, vi)
increment_num_produce!(vi)
return Distributions.loglikelihood(right, left), vi
end
# .~ functions
# assume
"""
dot_tilde_assume(context::SamplingContext, right, left, vn, vi)
Handle broadcasted assumed variables, e.g., `x .~ MvNormal()` (where `x` does not occur in the
model inputs), accumulate the log probability, and return the sampled value for a context
associated with a sampler.
Falls back to
```julia
dot_tilde_assume(context.rng, context.context, context.sampler, right, left, vn, vi)
```
"""
function dot_tilde_assume(context::SamplingContext, right, left, vn, vi)
return dot_tilde_assume(
context.rng, context.context, context.sampler, right, left, vn, vi
)
end
# `DefaultContext`
function dot_tilde_assume(context::AbstractContext, args...)
return dot_tilde_assume(NodeTrait(dot_tilde_assume, context), context, args...)
end
function dot_tilde_assume(rng, context::AbstractContext, args...)
return dot_tilde_assume(rng, NodeTrait(dot_tilde_assume, context), context, args...)
end
function dot_tilde_assume(::IsLeaf, ::AbstractContext, right, left, vns, vi)
return dot_assume(right, left, vns, vi)
end
function dot_tilde_assume(::IsLeaf, rng, ::AbstractContext, sampler, right, left, vns, vi)
return dot_assume(rng, sampler, right, vns, left, vi)
end
function dot_tilde_assume(::IsParent, context::AbstractContext, args...)
return dot_tilde_assume(childcontext(context), args...)
end
function dot_tilde_assume(rng, ::IsParent, context::AbstractContext, args...)
return dot_tilde_assume(rng, childcontext(context), args...)
end
function dot_tilde_assume(rng, ::DefaultContext, sampler, right, left, vns, vi)
return dot_assume(rng, sampler, right, vns, left, vi)
end
# `LikelihoodContext`
function dot_tilde_assume(context::LikelihoodContext{<:NamedTuple}, right, left, vn, vi)
return if haskey(context.vars, getsym(vn))
var = get(context.vars, vn)
_right, _left, _vns = unwrap_right_left_vns(right, var, vn)
set_val!(vi, _vns, _right, _left)
settrans!!.((vi,), false, _vns)
dot_tilde_assume(LikelihoodContext(), _right, _left, _vns, vi)
else
dot_tilde_assume(LikelihoodContext(), right, left, vn, vi)
end
end
function dot_tilde_assume(
rng::Random.AbstractRNG,
context::LikelihoodContext{<:NamedTuple},
sampler,
right,
left,
vn,
vi,
)
return if haskey(context.vars, getsym(vn))
var = get(context.vars, vn)
_right, _left, _vns = unwrap_right_left_vns(right, var, vn)
set_val!(vi, _vns, _right, _left)
settrans!!.((vi,), false, _vns)
dot_tilde_assume(rng, LikelihoodContext(), sampler, _right, _left, _vns, vi)
else
dot_tilde_assume(rng, LikelihoodContext(), sampler, right, left, vn, vi)
end
end
function dot_tilde_assume(context::LikelihoodContext, right, left, vn, vi)
return dot_assume(nodist(right), left, vn, vi)
end
function dot_tilde_assume(
rng::Random.AbstractRNG, context::LikelihoodContext, sampler, right, left, vn, vi
)
return dot_assume(rng, sampler, nodist(right), vn, left, vi)
end
# `PriorContext`
function dot_tilde_assume(context::PriorContext{<:NamedTuple}, right, left, vn, vi)
return if haskey(context.vars, getsym(vn))
var = get(context.vars, vn)
_right, _left, _vns = unwrap_right_left_vns(right, var, vn)
set_val!(vi, _vns, _right, _left)
settrans!!.((vi,), false, _vns)
dot_tilde_assume(PriorContext(), _right, _left, _vns, vi)
else
dot_tilde_assume(PriorContext(), right, left, vn, vi)
end
end
function dot_tilde_assume(
rng::Random.AbstractRNG,
context::PriorContext{<:NamedTuple},
sampler,
right,
left,
vn,
vi,
)
return if haskey(context.vars, getsym(vn))
var = get(context.vars, vn)
_right, _left, _vns = unwrap_right_left_vns(right, var, vn)
set_val!(vi, _vns, _right, _left)
settrans!!.((vi,), false, _vns)
dot_tilde_assume(rng, PriorContext(), sampler, _right, _left, _vns, vi)
else
dot_tilde_assume(rng, PriorContext(), sampler, right, left, vn, vi)
end
end
# `PrefixContext`
function dot_tilde_assume(context::PrefixContext, right, left, vn, vi)
return dot_tilde_assume(context.context, right, prefix.(Ref(context), vn), vi)
end
function dot_tilde_assume(rng, context::PrefixContext, sampler, right, left, vn, vi)
return dot_tilde_assume(
rng, context.context, sampler, right, prefix.(Ref(context), vn), vi
)
end
"""
dot_tilde_assume!!(context, right, left, vn, vi)
Handle broadcasted assumed variables, e.g., `x .~ MvNormal()` (where `x` does not occur in the
model inputs), accumulate the log probability, and return the sampled value and updated `vi`.
Falls back to `dot_tilde_assume(context, right, left, vn, vi)`.
"""
function dot_tilde_assume!!(context, right, left, vn, vi)
value, logp, vi = dot_tilde_assume(context, right, left, vn, vi)
return value, acclogp_assume!!(context, vi, logp), vi
end
# `dot_assume`
function dot_assume(
dist::MultivariateDistribution,
var::AbstractMatrix,
vns::AbstractVector{<:VarName},
vi::AbstractVarInfo,
)
@assert length(dist) == size(var, 1) "dimensionality of `var` ($(size(var, 1))) is incompatible with dimensionality of `dist` $(length(dist))"
# NOTE: We cannot work with `var` here because we might have a model of the form
#
# m = Vector{Float64}(undef, n)
# m .~ Normal()
#
# in which case `var` will have `undef` elements, even if `m` is present in `vi`.
r = vi[vns, dist]
lp = sum(zip(vns, eachcol(r))) do (vn, ri)
return Bijectors.logpdf_with_trans(dist, ri, istrans(vi, vn))
end
return r, lp, vi
end
function dot_assume(
rng,
spl::Union{SampleFromPrior,SampleFromUniform},
dist::MultivariateDistribution,
vns::AbstractVector{<:VarName},
var::AbstractMatrix,
vi::AbstractVarInfo,
)
@assert length(dist) == size(var, 1)
r = get_and_set_val!(rng, vi, vns, dist, spl)
lp = sum(Bijectors.logpdf_with_trans(dist, r, istrans(vi, vns[1])))
return r, lp, vi
end
function dot_assume(
dist::Distribution, var::AbstractArray, vns::AbstractArray{<:VarName}, vi
)
r = getindex.((vi,), vns, (dist,))
lp = sum(Bijectors.logpdf_with_trans.((dist,), r, istrans.((vi,), vns)))
return r, lp, vi
end
function dot_assume(
dists::AbstractArray{<:Distribution},
var::AbstractArray,
vns::AbstractArray{<:VarName},
vi,
)
r = getindex.((vi,), vns, dists)
lp = sum(Bijectors.logpdf_with_trans.(dists, r, istrans.((vi,), vns)))
return r, lp, vi
end
function dot_assume(
rng,
spl::Union{SampleFromPrior,SampleFromUniform},
dists::Union{Distribution,AbstractArray{<:Distribution}},
vns::AbstractArray{<:VarName},
var::AbstractArray,
vi::AbstractVarInfo,
)
r = get_and_set_val!(rng, vi, vns, dists, spl)
# Make sure `r` is not a matrix for multivariate distributions
lp = sum(Bijectors.logpdf_with_trans.(dists, r, istrans.((vi,), vns)))
return r, lp, vi
end
function dot_assume(rng, spl::Sampler, ::Any, ::AbstractArray{<:VarName}, ::Any, ::Any)
return error(
"[DynamicPPL] $(alg_str(spl)) doesn't support vectorizing assume statement"
)
end
function get_and_set_val!(
rng,
vi::VarInfoOrThreadSafeVarInfo,
vns::AbstractVector{<:VarName},
dist::MultivariateDistribution,
spl::Union{SampleFromPrior,SampleFromUniform},
)
n = length(vns)
if haskey(vi, vns[1])
# Always overwrite the parameters with new ones for `SampleFromUniform`.
if spl isa SampleFromUniform || is_flagged(vi, vns[1], "del")
unset_flag!(vi, vns[1], "del")
r = init(rng, dist, spl, n)
for i in 1:n
vn = vns[i]
setindex!!(
vi,
vectorize(dist, maybe_reconstruct_and_link(vi, vn, dist, r[:, i])),
vn,
)
setorder!(vi, vn, get_num_produce(vi))
end
else
r = vi[vns, dist]
end
else
r = init(rng, dist, spl, n)
for i in 1:n
vn = vns[i]
if istrans(vi)
push!!(vi, vn, Bijectors.link(dist, r[:, i]), dist, spl)
# `push!!` sets the trans-flag to `false` by default.
settrans!!(vi, true, vn)
else
push!!(vi, vn, r[:, i], dist, spl)
end
end
end
return r
end
function get_and_set_val!(
rng,
vi::VarInfoOrThreadSafeVarInfo,
vns::AbstractArray{<:VarName},
dists::Union{Distribution,AbstractArray{<:Distribution}},
spl::Union{SampleFromPrior,SampleFromUniform},
)
if haskey(vi, vns[1])
# Always overwrite the parameters with new ones for `SampleFromUniform`.
if spl isa SampleFromUniform || is_flagged(vi, vns[1], "del")
unset_flag!(vi, vns[1], "del")
f = (vn, dist) -> init(rng, dist, spl)
r = f.(vns, dists)
for i in eachindex(vns)
vn = vns[i]
dist = dists isa AbstractArray ? dists[i] : dists
setindex!!(
vi, vectorize(dist, maybe_reconstruct_and_link(vi, vn, dist, r[i])), vn
)
setorder!(vi, vn, get_num_produce(vi))
end
else
# r = reshape(vi[vec(vns)], size(vns))
# FIXME: Remove `reconstruct` in `getindex_raw(::VarInfo, ...)`
# and fix the lines below.
r_raw = getindex_raw(vi, vec(vns))
r = maybe_invlink_and_reconstruct.((vi,), vns, dists, reshape(r_raw, size(vns)))
end
else
f = (vn, dist) -> init(rng, dist, spl)
r = f.(vns, dists)
# TODO: This will inefficient since it will allocate an entire vector.
# We could either:
# 1. Figure out the broadcast size and use a `foreach`.
# 2. Define an anonymous function which returns `nothing`, which
# we then broadcast. This will allocate a vector of `nothing` though.
if istrans(vi)
push!!.((vi,), vns, reconstruct_and_link.((vi,), vns, dists, r), dists, (spl,))
# NOTE: Need to add the correction.
# FIXME: This is not great.
acclogp_assume!!(vi, sum(logabsdetjac.(bijector.(dists), r)))
# `push!!` sets the trans-flag to `false` by default.
settrans!!.((vi,), true, vns)
else
push!!.((vi,), vns, r, dists, (spl,))
end
end
return r
end
function set_val!(
vi::VarInfoOrThreadSafeVarInfo,
vns::AbstractVector{<:VarName},
dist::MultivariateDistribution,
val::AbstractMatrix,
)
@assert size(val, 2) == length(vns)
foreach(enumerate(vns)) do (i, vn)
setindex!!(vi, val[:, i], vn)
end
return val
end
function set_val!(
vi::VarInfoOrThreadSafeVarInfo,
vns::AbstractArray{<:VarName},
dists::Union{Distribution,AbstractArray{<:Distribution}},
val::AbstractArray,
)
@assert size(val) == size(vns)
foreach(CartesianIndices(val)) do ind
dist = dists isa AbstractArray ? dists[ind] : dists
setindex!!(vi, vectorize(dist, val[ind]), vns[ind])
end
return val
end
# observe
"""
dot_tilde_observe(context::SamplingContext, right, left, vi)
Handle broadcasted observed constants, e.g., `[1.0] .~ MvNormal()`, accumulate the log
probability, and return the observed value for a context associated with a sampler.
Falls back to `dot_tilde_observe(context.context, context.sampler, right, left, vi)`.
"""
function dot_tilde_observe(context::SamplingContext, right, left, vi)
return dot_tilde_observe(context.context, context.sampler, right, left, vi)
end
# Leaf contexts
function dot_tilde_observe(context::AbstractContext, args...)
return dot_tilde_observe(NodeTrait(tilde_observe, context), context, args...)
end
dot_tilde_observe(::IsLeaf, ::AbstractContext, args...) = dot_observe(args...)
function dot_tilde_observe(::IsParent, context::AbstractContext, args...)
return dot_tilde_observe(childcontext(context), args...)
end
dot_tilde_observe(::PriorContext, right, left, vi) = 0, vi
dot_tilde_observe(::PriorContext, sampler, right, left, vi) = 0, vi
# `MiniBatchContext`
function dot_tilde_observe(context::MiniBatchContext, right, left, vi)
logp, vi = dot_tilde_observe(context.context, right, left, vi)
return context.loglike_scalar * logp, vi
end
# `PrefixContext`
function dot_tilde_observe(context::PrefixContext, right, left, vi)
return dot_tilde_observe(context.context, right, left, vi)
end
"""
dot_tilde_observe!!(context, right, left, vname, vi)
Handle broadcasted observed values, e.g., `x .~ MvNormal()` (where `x` does occur in the model inputs),
accumulate the log probability, and return the observed value and updated `vi`.
Falls back to `dot_tilde_observe!!(context, right, left, vi)` ignoring the information about variable
name and indices; if needed, these can be accessed through this function, though.
"""
function dot_tilde_observe!!(context, right, left, vn, vi)
return dot_tilde_observe!!(context, right, left, vi)
end
"""
dot_tilde_observe!!(context, right, left, vi)
Handle broadcasted observed constants, e.g., `[1.0] .~ MvNormal()`, accumulate the log
probability, and return the observed value and updated `vi`.
Falls back to `dot_tilde_observe(context, right, left, vi)`.
"""
function dot_tilde_observe!!(context, right, left, vi)
logp, vi = dot_tilde_observe(context, right, left, vi)
return left, acclogp_observe!!(context, vi, logp)
end
# Falls back to non-sampler definition.
function dot_observe(::AbstractSampler, dist, value, vi)
return dot_observe(dist, value, vi)
end
function dot_observe(dist::MultivariateDistribution, value::AbstractMatrix, vi)
increment_num_produce!(vi)
return Distributions.loglikelihood(dist, value), vi
end
function dot_observe(dists::Distribution, value::AbstractArray, vi)
increment_num_produce!(vi)
return Distributions.loglikelihood(dists, value), vi
end
function dot_observe(dists::AbstractArray{<:Distribution}, value::AbstractArray, vi)
increment_num_produce!(vi)
return sum(Distributions.loglikelihood.(dists, value)), vi
end