-
Notifications
You must be signed in to change notification settings - Fork 19
/
Meshes.pas
2201 lines (1909 loc) · 62.5 KB
/
Meshes.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{Copyright (c) 2008 Ville Krumlinde
Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:
The above copyright notice and this permission notice shall be included in
all copies or substantial portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
THE SOFTWARE.}
//Meshes and models
unit Meshes;
{$include zzdc_globalopt.inc}
interface
uses ZClasses, ZBitmap, ZExpressions, ZOpenGL;
type
PMeshVertexIndex = ^TMeshVertexIndex;
TMeshVertexIndex = {$ifdef Android}word{$else}integer{$endif}; //word,integer
PIndicesArray = ^TIndicesArray;
TIndicesArray = array[0..10000] of TMeshVertexIndex;
PMeshVertexColor = ^TMeshVertexColor;
TMeshVertexColor = integer;
PMeshColorArray = ^TMeshColorArray;
TMeshColorArray = array[0..10000] of TMeshVertexColor;
TMesh = class(TContent)
private
procedure FreeData;
protected
procedure Transform(const Matrix,NormalMatrix : TZMatrix4f);
procedure CopyAndDestroy(Source : TContent); override;
procedure DefineProperties(List: TZPropertyList); override;
{$ifndef minimal}
procedure UpdateBounds;
{$endif}
public
//Note: keep fields in sync with CopyAndDestroy-method
Vertices : PZVector3Array;
VerticesCount : TMeshVertexIndex;
Indices : PIndicesArray;
IndicesCount : integer;
Normals : PZVector3Array;
TexCoords : PZVector2Array;
Colors : PMeshColorArray;
CurrentRecursion : integer;
{$ifndef minimal}
BoundSphere :
record
Center : TZVector3f;
Radius : single;
end;
{$endif}
IsDynamic : boolean; //True if vertices can be changed in runtime
VboHandles: array[0..1] of GLuint;
VboOffsets : array[0..2] of integer;
procedure ComputeNormals;
procedure CreateData(VQuantity, TQuantity: integer; WithTexCoords : boolean = False; WithColors : boolean = False);
procedure MakeNet(XCount, YCount: integer);
procedure Scale(const V: TZVector3f);
procedure BeforeRender;
destructor Destroy; override;
procedure ResetGpuResources; override;
{$ifndef minimal}
procedure DesignerCopyFrom(M: TMesh);
{$endif}
end;
TMeshProducer = class(TContentProducer)
protected
procedure DefineProperties(List: TZPropertyList); override;
public
Scale : TZVector3f;
end;
TMeshBox = class(TMeshProducer)
protected
procedure ProduceOutput(Content : TContent; Stack : TZArrayList); override;
procedure DefineProperties(List: TZPropertyList); override;
public
Grid2DOnly : boolean;
XCount,YCount : integer;
end;
TMeshSphere = class(TMeshProducer)
protected
procedure ProduceOutput(Content : TContent; Stack : TZArrayList); override;
procedure DefineProperties(List: TZPropertyList); override;
public
ZSamples,RadialSamples : integer;
end;
//Add noise to vertices
TMeshNoise = class(TMeshProducer)
protected
procedure ProduceOutput(Content : TContent; Stack : TZArrayList); override;
procedure DefineProperties(List: TZPropertyList); override;
public
NoiseSpeed : TZVector3f;
NoiseScale : TZVector3f;
SymmetryX,SymmetryY,SymmetryZ : boolean;
end;
//Change vertices using a zexpression
TMeshExpression = class(TMeshProducer)
strict private
type
PVertexTask = ^TVertexTask;
TVertexTask = record
PVert,PNorm : PZVector3f;
PColor : PMeshVertexColor;
PTex : PZVector2f;
Count : integer;
end;
procedure VertexTask(Task : pointer);
protected
procedure DefineProperties(List: TZPropertyList); override;
procedure ProduceOutput(Content : TContent; Stack: TZArrayList); override;
public
Expression : TZExpressionPropValue;
AutoNormals,VertexColors,HasTexCoords : boolean;
end;
//Created by 3ds-import
TMeshImport = class(TMeshProducer)
public type
TMeshTexCoordFormat = (mtcNone, mtcDeltaS16, mtcFloat);
TMeshIndicesFormat = (mifWord, mifInteger);
TMeshNormalsFormat = (mnfNone, mnfFloat);
protected
procedure DefineProperties(List: TZPropertyList); override;
procedure ProduceOutput(Content : TContent; Stack: TZArrayList); override;
public
HasVertexColors : boolean;
HasTextureCoords : TMeshTexCoordFormat;
IndicesFormat : TMeshIndicesFormat;
NormalsFormat : TMeshNormalsFormat;
MeshData : TZBinaryPropValue;
end;
//Combine the vertexes of two meshes
TMeshCombine = class(TMeshProducer)
protected
{$ifndef minimal}
procedure DefineProperties(List: TZPropertyList); override;
{$endif}
procedure ProduceOutput(Content : TContent; Stack: TZArrayList); override;
public
end;
//Loads a copy of another mesh onto the stack
TMeshLoad = class(TMeshProducer)
protected
procedure DefineProperties(List: TZPropertyList); override;
procedure ProduceOutput(Content : TContent; Stack: TZArrayList); override;
public
Mesh : TMesh;
{$ifndef minimal}function GetDisplayName: AnsiString; override;{$endif}
end;
//Transforms the vertices of the incoming mesh
TMeshTransform = class(TMeshProducer)
protected
Matrix,NormalMatrix : TZMatrix4f;
procedure DefineProperties(List: TZPropertyList); override;
procedure ProduceOutput(Content : TContent; Stack: TZArrayList); override;
public
Position : TZVector3f;
Rotation : TZVector3f;
Accumulate : boolean;
end;
TMeshLoop = class(TMeshProducer)
protected
procedure ProduceOutput(Content : TContent; Stack: TZArrayList); override;
procedure DefineProperties(List: TZPropertyList); override;
public
Count : integer;
OnIteration : TZComponentList;
Iteration : integer;
Position : TZVector3f;
Rotation : TZVector3f;
RecursionCount : integer;
end;
//State for models
TModelState = class(TStateBase)
protected
procedure DefineProperties(List: TZPropertyList); override;
public
OnCollision : TZComponentList;
end;
TSetModelState = class(TCommand)
protected
procedure DefineProperties(List: TZPropertyList); override;
public
State : TModelState;
procedure Execute; override;
{$ifndef minimal}
function GetDisplayName: AnsiString; override;
{$endif}
end;
TCollisionStyle = (csRect2D,csSphere3D,csBox3D,csRect2D_OBB,csCircle2D);
PCollisionCoordinates = ^TCollisionCoordinates;
TCollisionCoordinates =
record
case Integer of
0 : (Rect : TZRectf);
1 : (Box : TZBox3D);
2 : (OBB : TOBB_2D);
end;
TModel = class(TZComponent)
private
CurrentState : TModelState;
protected
ChildModelRefs : TZArrayList; //referenser till models som denna har spawnat
ParentModel : TModel;
procedure DefineProperties(List: TZPropertyList); override;
public
BaseModel : TModel;
Definitions : TZComponentList;
OnRender : TZComponentList;
OnUpdate : TZComponentList; //uppdateringslogik
OnSpawn : TZComponentList;
OnRemove : TZComponentList;
OnCollision : TZComponentList;
CollisionStyle : TCollisionStyle;
States : TZComponentList;
Position : TZVector3f;
Rotation : TZVector3f;
Velocity : TZVector3f;
Scale : TZVector3f;
RotationVelocity : TZVector3f;
Category : byte;
CollisionBounds : TZRectf;
CollisionOffset : TZVector3f;
IsSpawnedAsReference : boolean;
Active : boolean;
Personality : single; //Varje instans har egen random "personlighet", som kan användas i expressions.
LastPosition : TZVector3f; //Används i collision
CollisionCoordinates : TCollisionCoordinates;
CollisionCoordinatesUpdatedTime : single;
RenderOrder : (roNormal,roDepthsorted);
SortKey : single; //Used when depthsorting models
ModelClassId : integer;
CollidedWith : TModel;
procedure Update; override; //anropas ej ifall active=false
procedure UpdateCollisionCoordinates;
procedure Collision(Hit : TModel);
procedure AddToScene(App : pointer);
{$ifndef minimal}
procedure DesignerUpdate;
{$endif}
procedure RunRenderCommands;
function CloneModel : TModel;
constructor Create(OwnerList: TZComponentList); override;
destructor Destroy; override;
end;
//Models-list owned by application
//Models are divided into collision categories
TModels = class
private
RemoveList : TZArrayList;
procedure ClearAll;
public
Cats : TZArrayList;
App : pointer;
constructor Create;
destructor Destroy; override;
procedure Update;
procedure RegisterCat(Cat : integer);
function Get(Cat : integer) : TZArrayList;
procedure Add(M : TModel);
procedure Remove(M : TModel);
procedure RemoveAll;
procedure FlushRemoveList;
end;
TSpawnModel = class(TCommand)
protected
procedure DefineProperties(List: TZPropertyList); override;
public
Model : TModel;
Position : TZVector3f;
Rotation : TZVector3f;
Scale : TZVector3f;
SpawnStyle : (ssClone,ssReference);
UseSpawnerPosition : boolean;
SpawnerIsParent : boolean; //Spawned model becomes child to currentmodel
procedure Execute; override;
{$ifndef minimal}function GetDisplayName: AnsiString; override;{$endif}
end;
TRemoveModel = class(TCommand)
protected
procedure DefineProperties(List: TZPropertyList); override;
public
Model : TModel;
procedure Execute; override;
{$ifndef minimal}function GetDisplayName: AnsiString; override;{$endif}
end;
TRemoveAllModels = class(TCommand)
protected
procedure DefineProperties(List: TZPropertyList); override;
public
OfType : TModel;
procedure Execute; override;
{$ifndef minimal}function GetDisplayName: AnsiString; override;{$endif}
end;
var
CurrentModel : TModel; //Set to the model that is currently updated
{$ifndef minimal}
const
CollisionStyleNames : array[0..4] of string =
('Rect2D','Sphere3D','Box3D','Rect2D_OBB','Circle2D');
{$endif}
implementation
uses ZMath, ZApplication
{$ifndef minimal}, Animators, Renderer{$endif}
{$ifdef zdebug}, ZLog, Sysutils{$endif}
;
var
//Declare as "class var" in TModel when fpc supports static class variables
_NextModelClassId : integer;
type
TModelsHelper = class helper for TModels
public
function ZApp : TZApplication;
end;
procedure ExecuteWithCurrentModel(M : TModel; CommandList : TZComponentList);
var
SaveCurrent : TModel;
begin
SaveCurrent := CurrentModel;
CurrentModel := M;
CommandList.ExecuteCommands;
CurrentModel := SaveCurrent;
end;
{ TMesh }
procedure TMesh.ComputeNormals;
var
C : array[0..2] of TZVector3f;
ax,ay,az,bx,by,bz,nx,ny,nz : single;
I,I1,I2,I3 : integer;
begin
//One normal for each vertex
// GetMem(Normals,SizeOf(TZVector3f) * VerticesCount);
FillChar(Normals^,SizeOf(TZVector3f) * VerticesCount,0);
for I := 0 to (IndicesCount div 3)-1 do
begin
I1 := Indices^[(I*3)];
I2 := Indices^[(I*3)+1];
I3 := Indices^[(I*3)+2];
C[0] := Vertices^[ I1 ];
C[1] := Vertices^[ I2 ];
C[2] := Vertices^[ I3 ];
//Calc normal vector
//http://www.tjhsst.edu/~dhyatt/supercomp/n310.html
ax:=c[1][0] - c[0][0];
ay:=c[1][1] - c[0][1];
az:=c[1][2] - c[0][2];
bx:=c[2][0] - c[1][0];
by:=c[2][1] - c[1][1];
bz:=c[2][2] - c[1][2];
nx:=ay * bz - az * by;
ny:=az * bx - ax * bz;
nz:=ax * by - ay * bx;
//Add normals for each face
Normals^[ I1 ][0] := Normals^[ I1 ][0] + NX;
Normals^[ I1 ][1] := Normals^[ I1 ][1] + NY;
Normals^[ I1 ][2] := Normals^[ I1 ][2] + NZ;
Normals^[ I2 ][0] := Normals^[ I2 ][0] + NX;
Normals^[ I2 ][1] := Normals^[ I2 ][1] + NY;
Normals^[ I2 ][2] := Normals^[ I2 ][2] + NZ;
Normals^[ I3 ][0] := Normals^[ I3 ][0] + NX;
Normals^[ I3 ][1] := Normals^[ I3 ][1] + NY;
Normals^[ I3 ][2] := Normals^[ I3 ][2] + NZ;
end;
//Normalize
for I := 0 to VerticesCount-1 do
VecNormalize3(Normals^[I]);
end;
procedure TMesh.Transform(const Matrix,NormalMatrix : TZMatrix4f);
var
I : integer;
V : TZVector3f;
begin
for I := 0 to Self.VerticesCount-1 do
begin
VecCopy3(Self.Vertices^[I],V);
VectorTransform(V,Matrix,Self.Vertices^[I]);
VecCopy3(Self.Normals^[I],V);
VectorTransform(V,NormalMatrix,Self.Normals^[I]);
end;
end;
procedure TMesh.CopyAndDestroy(Source: TContent);
var
M : TMesh;
begin
{$ifndef minimal}
if Source=nil then Exit;
{$endif}
FreeData;
M := TMesh(Source);
Vertices := M.Vertices;
VerticesCount := M.VerticesCount;
Indices := M.Indices;
IndicesCount := M.IndicesCount;
Normals := M.Normals;
TexCoords := M.TexCoords;
Colors := M.Colors;
IsDynamic := M.IsDynamic;
M.Vertices :=nil;
M.Indices :=nil;
M.Normals :=nil;
M.TexCoords :=nil;
M.Colors :=nil;
M.Free;
{$if (not defined(minimal)) and (not defined(zgeviz))}
if CurrentRecursion=0 then
begin
if VerticesCount>=High(TMeshVertexIndex) then
ZLog.GetLog(Self.ClassName).Error('Too many vertices: ' + IntToStr(Self.VerticesCount) )
else if (not ZApp.DesignerIsRunning) then
ZLog.GetLog(Self.ClassName).Write('Triangles ' + IntToStr(Self.IndicesCount div 3) );
end;
{$endif}
end;
{$ifndef minimal}
procedure TMesh.DesignerCopyFrom(M : TMesh);
begin
FreeData;
CreateData(M.VerticesCount,M.IndicesCount div 3,M.TexCoords<>nil,M.Colors<>nil);
Move(M.Vertices^,Self.Vertices^,SizeOf(TZVector3f) * VerticesCount);
Move(M.Indices^,Self.Indices^,SizeOf(TMeshVertexIndex) * IndicesCount);
Move(M.Normals^,Self.Normals^,SizeOf(TZVector3f) * VerticesCount);
if M.TexCoords<>nil then
Move(M.TexCoords^,Self.TexCoords^,SizeOf(TZVector2f) * VerticesCount);
if M.Colors<>nil then
Move(M.Colors^,Self.Colors^,SizeOf(TMeshVertexColor) * VerticesCount);
IsChanged := False;
Producers.IsChanged := False;
end;
{$endif}
procedure TMesh.CreateData(VQuantity, TQuantity: integer; WithTexCoords : boolean = False;
WithColors : boolean = False);
begin
if (Vertices<>nil) then
begin
//Already allocated
if (VerticesCount=VQuantity) then
Exit; //Same count, just exit
FreeData; //Otherwise dealloc old
end;
VerticesCount := VQuantity;
IndicesCount := 3*TQuantity;
GetMem(Vertices, SizeOf(TZVector3f) * VerticesCount);
//New memory can contain junk, normals must be zeroed out
GetMem(Normals,SizeOf(TZVector3f) * VerticesCount);
FillChar(Normals^,SizeOf(TZVector3f) * VerticesCount,0);
GetMem(Indices, SizeOf(TMeshVertexIndex) * IndicesCount);
if WithTexCoords then
GetMem(TexCoords, SizeOf(TZVector2f) * VerticesCount);
if WithColors then
GetMem(Colors, SizeOf(TMeshVertexColor) * VerticesCount);
//Always use VBOs
IsDynamic := False;
end;
procedure TMesh.FreeData;
begin
if Vertices<>nil then
FreeMem(Vertices);
if Indices<>nil then
FreeMem(Indices);
if Normals<>nil then
FreeMem(Normals);
if TexCoords<>nil then
FreeMem(TexCoords);
if Colors<>nil then
FreeMem(Colors);
VerticesCount := 0;
IndicesCount := 0;
Vertices := nil;
Normals := nil;
TexCoords := nil;
Colors := nil;
if ZOpenGL.VbosSupported and (VboHandles[0]<>0) then
begin
glDeleteBuffers(2, @VboHandles);
VboHandles[0]:=0;
end;
end;
procedure TMesh.ResetGpuResources;
begin
if ZOpenGL.VbosSupported and (VboHandles[0]<>0) then
begin
glDeleteBuffers(2, @VboHandles);
VboHandles[0]:=0;
end;
inherited;
end;
destructor TMesh.Destroy;
begin
FreeData;
inherited;
end;
procedure TMesh.BeforeRender;
var
VertSize,NormSize,ColsSize,TexSize : integer;
begin
if (Vertices=nil) or (Producers.IsChanged) or (IsChanged) then
begin
RefreshFromProducers;
{$ifndef minimal}
UpdateBounds;
{$endif}
end;
if VbosSupported and (not Self.IsDynamic) then
begin
//Use vertex buffer objects
//prepare vbo
if Self.VboHandles[0]=0 then
begin
glGenBuffers(2, @Self.VboHandles);
VertSize := Self.VerticesCount * SizeOf(TZVector3f);
NormSize := VertSize;
if Self.Colors<>nil then
ColsSize:= Self.VerticesCount * SizeOf(TMeshVertexColor)
else
ColsSize:= 0;
if Self.TexCoords<>nil then
TexSize:= Self.VerticesCount * SizeOf(TZVector2f)
else
TexSize:= 0;
glBindBuffer(GL_ARRAY_BUFFER, Self.VboHandles[0]);
glBufferData(GL_ARRAY_BUFFER, VertSize + NormSize + ColsSize + TexSize, nil, STATIC_DRAW);
glBufferSubData(GL_ARRAY_BUFFER, 0, VertSize, Self.Vertices);
Self.VboOffsets[0] := VertSize;
glBufferSubData(GL_ARRAY_BUFFER, Self.VboOffsets[0], NormSize, Self.Normals);
Self.VboOffsets[1] := Self.VboOffsets[0] + NormSize;
if ColsSize>0 then
glBufferSubData(GL_ARRAY_BUFFER, Self.VboOffsets[1], ColsSize, Self.Colors);
Self.VboOffsets[2] := Self.VboOffsets[1] + ColsSize;
if TexSize>0 then
glBufferSubData(GL_ARRAY_BUFFER, Self.VboOffsets[2], TexSize, Self.TexCoords);
glBindBuffer(GL_ELEMENT_ARRAY_BUFFER, Self.VboHandles[1]);
glBufferData(GL_ELEMENT_ARRAY_BUFFER, Self.IndicesCount * SizeOf(TMeshVertexIndex), Self.Indices, STATIC_DRAW);
end;
end;
end;
procedure TMesh.Scale(const V: TZVector3f);
var
I : integer;
begin
if VecIsIdentity3(V) then
Exit;
for I := 0 to VerticesCount-1 do
VecMult3(Vertices^[I],V);
if Normals<>nil then
for I := 0 to VerticesCount-1 do
begin
VecMult3(Normals^[I],V);
VecNormalize3( Normals^[I] );
end;
end;
{$ifndef minimal}
procedure TMesh.UpdateBounds;
//http://www.mvps.org/directx/articles/using_bounding_spheres.htm
var
VertP : PZVector3f;
I : integer;
C,V : TZVector3f;
R,DistSq : single;
begin
// find center
VertP := pointer(Self.Vertices);
C := Vector3f(0,0,0);
for I := 0 to Self.VerticesCount - 1 do
begin
VecAdd3(C,VertP^,C);
Inc(VertP);
end;
VecDiv3(C,Self.VerticesCount,C);
Self.BoundSphere.Center := C;
// find farthest point in set
R := 0;
VertP := pointer(Self.Vertices);
for I := 0 to Self.VerticesCount - 1 do
begin
VecSub3(VertP^,C,V);
DistSq := ZMath.VecLengthSquared3(V);
if DistSq>R then
R := DistSq;
Inc(VertP);
end;
Self.BoundSphere.Radius := sqrt(R);
end;
{$endif}
procedure TMesh.DefineProperties(List: TZPropertyList);
begin
inherited;
{$ifndef minimal}
List.GetByName('Producers').SetChildClasses([TMeshProducer]);
{$endif}
List.AddProperty({$IFNDEF MINIMAL}'CurrentRecursion',{$ENDIF}(@CurrentRecursion), zptInteger);
List.GetLast.NeverPersist := True;
{$ifndef minimal}List.GetLast.IsReadOnly := True;{$endif}
end;
procedure TMesh.MakeNet(XCount, YCount: integer);
var
VertCount,TriCount : integer;
P : PZVector3f;
XStep,YStep,CurX,CurY : single;
Ind : PMeshVertexIndex;
Tex : PZVector2f;
CurI,X,Y : integer;
begin
VertCount := (2+XCount) * (2+YCount);
TriCount := 2*((XCount+1)*(YCount+1));
CreateData(VertCount,TriCount,True);
P := pointer(Vertices);
XStep := 1/(XCount+1);
YStep := 1/(YCount+1);
Tex := pointer(TexCoords);
//Generate vertices and texcoords
CurY := -0.5;
for Y := 0 to YCount+1 do
begin
CurX := -0.5;
for X := 0 to XCount+1 do
begin
//Vertex interval -0.5 .. 0.5
P^[0] := CurX;
P^[1] := CurY;
P^[2] := 0;
//Texcoords interval 1..0
Tex^[0] := CurX+0.5;
Tex^[1] := 1.0 - (0.5 - CurY);
CurX := CurX + XStep;
Inc(P);
Inc(Tex);
end;
CurY := CurY + YStep;
end;
//Generate two triangles for each quad in net
//CCW direction
CurI := 0;
Ind := PMeshVertexIndex(Indices);
for Y := 0 to YCount do
begin
for X := 0 to XCount do
begin
Ind^:= CurI; Inc(Ind);
Ind^:= CurI+1; Inc(Ind);
Ind^:= CurI+2+XCount; Inc(Ind);
Ind^:= CurI+1; Inc(Ind);
Ind^:= CurI+3+XCount; Inc(Ind);
Ind^:= CurI+2+XCount; Inc(Ind);
Inc(CurI);
end;
Inc(CurI);
end;
{
curx=0
xstep=1/xcount
while(cury<1)
while(curx<1)
addvertice(curx,cury)
skapa indices
tri1 är v1,v2,v3
tri2 är v2,v4,v3
}
ComputeNormals;
end;
{ TModel }
procedure TModel.AddToScene(App : pointer);
begin
Self.Active:=True;
Self._ZApp := App;
TZApplication(App).AddModel( Self );
ExecuteWithCurrentModel(Self,Self.OnSpawn);
{$ifndef minimal}
//Clones should not increase classid
if not IsSpawnedAsReference then
Dec(_NextModelClassId);
{$endif}
end;
function TModel.CloneModel: TModel;
var
Parent : TModel;
begin
if Self.BaseModel<>nil then
begin
//Create all parents first
{$ifndef minimal}
ZAssert(Self.BaseModel<>Self,'BaseModel cannot be set to itself');
{$endif}
Parent := Self.BaseModel;
Self.BaseModel := nil;
Result := TModel( Self.Clone(Parent.CloneModel) );
Self.BaseModel := Parent;
end
else
Result := TModel(Self.Clone);
end;
procedure TModel.Collision(Hit: TModel);
begin
Self.CollidedWith := Hit;
ExecuteWithCurrentModel(Self,Self.OnCollision);
if CurrentState<>nil then
ExecuteWithCurrentModel(Self,CurrentState.OnCollision);
end;
procedure TModel.DefineProperties(List: TZPropertyList);
begin
inherited;
List.AddProperty({$IFNDEF MINIMAL}'Definitions',{$ENDIF}(@Definitions), zptComponentList);
List.AddProperty({$IFNDEF MINIMAL}'States',{$ENDIF}(@States), zptComponentList);
{$ifndef minimal}List.GetLast.SetChildClasses([TModelState]);{$endif}
List.AddProperty({$IFNDEF MINIMAL}'OnSpawn',{$ENDIF}(@OnSpawn), zptComponentList);
List.AddProperty({$IFNDEF MINIMAL}'OnUpdate',{$ENDIF}(@OnUpdate), zptComponentList);
List.AddProperty({$IFNDEF MINIMAL}'OnCollision',{$ENDIF}(@OnCollision), zptComponentList);
List.AddProperty({$IFNDEF MINIMAL}'OnRender',{$ENDIF}(@OnRender), zptComponentList);
List.AddProperty({$IFNDEF MINIMAL}'OnRemove',{$ENDIF}(@OnRemove), zptComponentList);
{$ifndef minimal}{List.GetLast.SetChildClasses([TDefineVariable,TDefineConstant,TMesh,TModel,TZBitmap]);}{$endif}
List.AddProperty({$IFNDEF MINIMAL}'BaseModel',{$ENDIF}(@BaseModel), zptComponentRef);
{$ifndef minimal}List.GetLast.SetChildClasses([TModel]);{$endif}
{$ifndef minimal}List.GetLast.IsReadOnly := True;{$endif}
List.AddProperty({$IFNDEF MINIMAL}'Position',{$ENDIF}(@Position), zptVector3f);
List.AddProperty({$IFNDEF MINIMAL}'Rotation',{$ENDIF}(@Rotation), zptVector3f);
List.AddProperty({$IFNDEF MINIMAL}'Velocity',{$ENDIF}(@Velocity), zptVector3f);
List.AddProperty({$IFNDEF MINIMAL}'Scale',{$ENDIF}(@Scale), zptVector3f);
List.GetLast.DefaultValue.Vector3fValue := ZMath.UNIT_XYZ3;
List.AddProperty({$IFNDEF MINIMAL}'RotationVelocity',{$ENDIF}(@RotationVelocity), zptVector3f);
List.AddProperty({$IFNDEF MINIMAL}'Category',{$ENDIF}(@Category), zptByte);
List.AddProperty({$IFNDEF MINIMAL}'CollisionBounds',{$ENDIF}(@CollisionBounds), zptRectf);
List.AddProperty({$IFNDEF MINIMAL}'CollisionOffset',{$ENDIF}(@CollisionOffset), zptVector3f);
List.AddProperty({$IFNDEF MINIMAL}'CollisionStyle',{$ENDIF}(@CollisionStyle), zptByte);
{$ifndef minimal}List.GetLast.SetOptions(CollisionStyleNames);{$endif}
List.AddProperty({$IFNDEF MINIMAL}'RenderOrder',{$ENDIF}(@RenderOrder), zptByte);
{$ifndef minimal}List.GetLast.SetOptions(['Normal','Depthsorted']);{$endif}
List.AddProperty({$IFNDEF MINIMAL}'ClassId',{$ENDIF}(@ModelClassId), zptInteger);
List.GetLast.NeverPersist := True;
{$ifndef minimal}List.GetLast.IsReadOnly := True;{$endif}
List.AddProperty({$IFNDEF MINIMAL}'CollidedWith',{$ENDIF}(@CollidedWith), zptComponentRef);
List.GetLast.NeverPersist := True;
List.GetLast.DontClone := True;
{$ifndef minimal}List.GetLast.IsReadOnly := True;{$endif}
{$ifndef minimal}List.GetLast.SetChildClasses([TModel]);{$endif}
List.AddProperty({$IFNDEF MINIMAL}'Personality',{$ENDIF}(@Personality), zptFloat);
List.GetLast.NeverPersist := True;
List.GetLast.DontClone := True;
{$ifndef minimal}List.GetLast.IsReadOnly := True;{$endif}
end;
procedure TModel.UpdateCollisionCoordinates;
var
W,H,A,S,C : single;
Start : TZVector3f;
I : integer;
Result : PCollisionCoordinates;
begin
if Self.CollisionCoordinatesUpdatedTime=ZApp.Time then
Exit; //Only update once per frame
Self.CollisionCoordinatesUpdatedTime:=ZApp.Time;
Result := @Self.CollisionCoordinates;
VecAdd3(CollisionOffset,Position, Start);
case Self.CollisionStyle of
csRect2D:
begin
W := CollisionBounds.Area[0] * 0.5;
H := CollisionBounds.Area[1] * 0.5;
Result.Rect.Left := Start[0] - W;
Result.Rect.Right := Start[0] + W;
Result.Rect.Top := Start[1] - H;
Result.Rect.Bottom := Start[1] + H;
end;
csSphere3D:
begin
Result.Rect.Area[0] := Start[0];
Result.Rect.Area[1] := Start[1];
Result.Rect.Area[2] := Start[2];
Result.Rect.Area[3] := CollisionBounds.Area[0];
end;
csBox3D:
begin
VecSub3(Start,PZVector3f(@CollisionBounds.Area)^,Result.Box.Min);
VecAdd3(Start,PZVector3f(@CollisionBounds.Area)^,Result.Box.Max);
end;
csRect2D_OBB:
begin
for I := 0 to 1 do
begin
Result.OBB.C[I] := Start[I];
Result.OBB.E[I] := CollisionBounds.Area[I] * Scale[I] * 0.5;
end;
A := CycleToRad(Self.Rotation[2]);
S := Sin(A);
C := Cos(A);
Result.OBB.U[0][0] := C;
Result.OBB.U[0][1] := S;
Result.OBB.U[1][0] := -S;
Result.OBB.U[1][1] := C;
end;
csCircle2D :
begin
Result.Rect.Area[0] := Start[0];
Result.Rect.Area[1] := Start[1];
Result.Rect.Area[2] := CollisionBounds.Area[0] * Scale[0];
end;
end;
end;
procedure TModel.Update;
var
I : integer;
begin
if Active then
begin
//Update movement
VecCopy3(Position,Self.LastPosition);
if not VecIsNull3(Self.Velocity) then
begin
for I := 0 to 2 do
Position[I] := Position[I] + (Velocity[I] * ZApp.DeltaTime);
end;
//Update rotation
if not VecIsNull3(Self.RotationVelocity) then
for I := 0 to 2 do
Rotation[I] := Rotation[I] + (RotationVelocity[I] * ZApp.DeltaTime);
ExecuteWithCurrentModel(Self,OnUpdate);
//Update renderers: particlesystems, beams etc
OnRender.Update;
//Update current state
if CurrentState<>nil then
CurrentState.Update;
end;
end;
procedure TModel.RunRenderCommands;
//Called from render.rendermodel
begin
Meshes.CurrentModel := Self;
OnRender.ExecuteCommands;
if CurrentState<>nil then
CurrentState.OnRender.ExecuteCommands;
end;
{$ifndef minimal}
procedure TModel.DesignerUpdate;
begin
//Update renderers: particlesystems, beams etc
OnRender.Update;
end;
{$endif}
constructor TModel.Create(OwnerList: TZComponentList);
begin
inherited Create(OwnerList);
ChildModelRefs := TZArrayList.CreateReferenced;
Personality := System.Random;
ModelClassId := _NextModelClassId;
Inc(_NextModelClassId);
end;
destructor TModel.Destroy;
begin
ChildModelRefs.Free;
inherited;
end;
{ TMeshSphere }
procedure TMeshSphere.DefineProperties(List: TZPropertyList);
begin
inherited;
List.AddProperty({$IFNDEF MINIMAL}'ZSamples',{$ENDIF}(@ZSamples), zptInteger);
List.GetLast.DefaultValue.IntegerValue := 10;
List.AddProperty({$IFNDEF MINIMAL}'RadialSamples',{$ENDIF}(@RadialSamples), zptInteger);
List.GetLast.DefaultValue.IntegerValue := 10;
end;
procedure TMeshSphere.ProduceOutput(Content : TContent; Stack : TZArrayList);
const
Radius : single = 1.0;
var
ZSm1,ZSm2,ZSm3,RSp1,VQuantity,TQuantity : integer;
R, Z, ZStart, i, Save : integer;
InvRS,ZFactor,Angle,ZFraction,fZ,SliceRadius{,RadialFraction} : single;
afSin,afCos : PFloatArray;
SliceCenter,Normal,Radial : TZVector3f;
Mesh : TMesh;
LocalIndex : PIndicesArray;
i0,i1,i2,i3 : integer;
VQm1,VQm2,Offset : integer;
begin
{$ifndef minimal}
if (ZSamples<=2) or (RadialSamples<=2) then
Exit;
{$endif}
Mesh := TMesh.Create(nil);
ZSm1 := ZSamples-1;
ZSm2 := ZSamples-2;
ZSm3 := ZSamples-3;
RSp1 := RadialSamples+1;
VQuantity := ZSm2*RSp1 + 2;
TQuantity := 2*ZSm2*RadialSamples;