/
CGDisplayListImageBufferBackend.mm
201 lines (168 loc) · 7.8 KB
/
CGDisplayListImageBufferBackend.mm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
/*
* Copyright (C) 2021-2022 Apple Inc. All rights reserved.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the distribution.
*
* THIS SOFTWARE IS PROVIDED BY APPLE INC. AND ITS CONTRIBUTORS ``AS IS''
* AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
* THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
* PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL APPLE INC. OR ITS CONTRIBUTORS
* BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
* CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
* SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
* INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
* CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
* THE POSSIBILITY OF SUCH DAMAGE.
*/
#import "config.h"
#import "CGDisplayListImageBufferBackend.h"
#if ENABLE(CG_DISPLAY_LIST_BACKED_IMAGE_BUFFER)
#import "CGDisplayList.h"
#import "Logging.h"
#import <WebCore/GraphicsContextCG.h>
#import <WebCore/PixelBuffer.h>
#import <WebKitAdditions/CGDisplayListImageBufferAdditions.h>
#import <pal/spi/cocoa/QuartzCoreSPI.h>
#import <wtf/IsoMallocInlines.h>
#import <wtf/MachSendRight.h>
#import <wtf/cocoa/TypeCastsCocoa.h>
#import <wtf/cocoa/VectorCocoa.h>
template<> struct WTF::CFTypeTrait<CAMachPortRef> {
static inline CFTypeID typeID(void) { return CAMachPortGetTypeID(); }
};
namespace WebKit {
static CFDictionaryRef makeContextOptions(const CGDisplayListImageBufferBackend::Parameters& parameters)
{
RetainPtr colorSpace = parameters.colorSpace.platformColorSpace();
if (!colorSpace)
return nil;
return (CFDictionaryRef)@{
@"colorspace" : (id)colorSpace.get()
};
}
class GraphicsContextCGDisplayList : public WebCore::GraphicsContextCG {
public:
GraphicsContextCGDisplayList(const CGDisplayListImageBufferBackend::Parameters& parameters)
: GraphicsContextCG(adoptCF(WKCGCommandsContextCreate(parameters.logicalSize, makeContextOptions(parameters))).autorelease())
{
m_immutableBaseTransform.scale(1, -1);
m_immutableBaseTransform.translate(0, -ceilf(parameters.logicalSize.height() * parameters.resolutionScale));
m_immutableBaseTransform.scale(parameters.resolutionScale);
m_inverseImmutableBaseTransform = *m_immutableBaseTransform.inverse();
m_resolutionScale = parameters.resolutionScale;
}
void setCTM(const WebCore::AffineTransform& transform) final
{
GraphicsContextCG::setCTM(m_inverseImmutableBaseTransform * transform);
}
WebCore::AffineTransform getCTM(IncludeDeviceScale includeDeviceScale) const final
{
return m_immutableBaseTransform * GraphicsContextCG::getCTM(includeDeviceScale);
}
WebCore::FloatRect roundToDevicePixels(const WebCore::FloatRect& rect, RoundingMode = RoundAllSides) const final
{
return rect;
}
bool canUseShadowBlur() const final { return false; }
protected:
void setCGShadow(WebCore::RenderingMode renderingMode, const WebCore::FloatSize& offset, float blur, const WebCore::Color& color, bool shadowsIgnoreTransforms) override
{
// This doesn't use `m_immutableBaseTransform.mapSize` because it doesn't output negative lengths.
WebCore::FloatSize scaledOffset = offset;
scaledOffset.scale(m_resolutionScale, -m_resolutionScale);
GraphicsContextCG::setCGShadow(renderingMode, scaledOffset, blur * m_resolutionScale, color, shadowsIgnoreTransforms);
}
private:
WebCore::AffineTransform m_immutableBaseTransform;
WebCore::AffineTransform m_inverseImmutableBaseTransform;
float m_resolutionScale;
};
WTF_MAKE_ISO_ALLOCATED_IMPL(CGDisplayListImageBufferBackend);
size_t CGDisplayListImageBufferBackend::calculateMemoryCost(const Parameters& parameters)
{
// FIXME: This is fairly meaningless, because we don't actually have a bitmap, and
// should really be based on the encoded data size.
auto backendSize = calculateBackendSize(parameters);
return WebCore::ImageBufferBackend::calculateMemoryCost(backendSize, calculateBytesPerRow(backendSize));
}
std::unique_ptr<CGDisplayListImageBufferBackend> CGDisplayListImageBufferBackend::create(const Parameters& parameters, const WebCore::ImageBufferCreationContext& creationContext)
{
if (parameters.logicalSize.isEmpty())
return nullptr;
return std::unique_ptr<CGDisplayListImageBufferBackend>(new CGDisplayListImageBufferBackend(parameters, creationContext));
}
CGDisplayListImageBufferBackend::CGDisplayListImageBufferBackend(const Parameters& parameters, const WebCore::ImageBufferCreationContext& creationContext)
: ImageBufferCGBackend { parameters }
{
if (creationContext.useCGDisplayListImageCache == UseCGDisplayListImageCache::Yes)
m_resourceCache = bridge_id_cast(adoptCF(WKCGCommandsCacheCreate(nullptr)));
}
ImageBufferBackendHandle CGDisplayListImageBufferBackend::createBackendHandle(SharedMemory::Protection) const
{
ASSERT(m_context);
RetainPtr<NSDictionary> options;
RetainPtr<NSMutableArray> ports;
if (m_resourceCache) {
ports = adoptNS([[NSMutableArray alloc] init]);
options = @{
@"ports": ports.get(),
@"cache": m_resourceCache.get()
};
}
auto data = adoptCF(WKCGCommandsContextCopyEncodedDataWithOptions(m_context->platformContext(), bridge_cast(options.get())));
ASSERT(data);
#if !RELEASE_LOG_DISABLED
auto size = backendSize();
RELEASE_LOG(RemoteLayerTree, "CGDisplayListImageBufferBackend of size %dx%d encoded display list of %ld bytes with %ld surfaces (useImageCache: %s)", size.width(), size.height(), CFDataGetLength(data.get()), [ports count], m_resourceCache ? "yes" : "no");
#endif
Vector<MachSendRight> sendRights;
if (m_resourceCache) {
sendRights = makeVector(ports.get(), [] (id port) -> std::optional<MachSendRight> {
// We `create` instead of `adopt` because CAMachPort has no API to leak its reference.
return { MachSendRight::create(CAMachPortGetPort(checked_cf_cast<CAMachPortRef>(port))) };
});
}
return CGDisplayList { WebCore::SharedBuffer::create(data.get()), WTFMove(sendRights) };
}
WebCore::GraphicsContext& CGDisplayListImageBufferBackend::context() const
{
if (!m_context)
m_context = makeUnique<GraphicsContextCGDisplayList>(m_parameters);
return *m_context;
}
WebCore::IntSize CGDisplayListImageBufferBackend::backendSize() const
{
return calculateBackendSize(m_parameters);
}
unsigned CGDisplayListImageBufferBackend::bytesPerRow() const
{
return calculateBytesPerRow(backendSize());
}
void CGDisplayListImageBufferBackend::clearContents()
{
m_context = nullptr;
}
RefPtr<WebCore::NativeImage> CGDisplayListImageBufferBackend::copyNativeImage(WebCore::BackingStoreCopy) const
{
ASSERT_NOT_REACHED();
return nullptr;
}
RefPtr<WebCore::PixelBuffer> CGDisplayListImageBufferBackend::getPixelBuffer(const WebCore::PixelBufferFormat&, const WebCore::IntRect&, const WebCore::ImageBufferAllocator&) const
{
ASSERT_NOT_REACHED();
return nullptr;
}
void CGDisplayListImageBufferBackend::putPixelBuffer(const WebCore::PixelBuffer&, const WebCore::IntRect&, const WebCore::IntPoint&, WebCore::AlphaPremultiplication)
{
ASSERT_NOT_REACHED();
}
}
#endif // ENABLE(CG_DISPLAY_LIST_BACKED_IMAGE_BUFFER)