-
Notifications
You must be signed in to change notification settings - Fork 6
/
AbstractRules.wl
2388 lines (1687 loc) · 61.2 KB
/
AbstractRules.wl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
BeginPackage["CodeInspector`AbstractRules`"]
$DefaultAbstractRules
Begin["`Private`"]
Needs["CodeParser`"]
Needs["CodeParser`Utils`"]
Needs["CodeInspector`"]
Needs["CodeInspector`Format`"]
Needs["CodeInspector`Utils`"]
(*
Rules are of the form: pat -> func where pat is the node pattern to match on and func is the processing function for the node.
Functions are of the form: function[pos_, ast_] where pos is the position of the node in the AST, and ast is the AST itself.
And function must return a list of Lints.
A rule of thumb is to make patterns as specific as possible, to offload work of calling the function.
*)
$DefaultAbstractRules = <|
CallNode[LeafNode[Symbol, "String" | "Integer" | "Real" | "True", _], _, _] -> scanBadCalls,
(*
not a good scan
CallNode[SymbolNode["Failure", _, _], _, _] -> scanFailureCalls,
*)
(*
Tags: Control
*)
LeafNode[Symbol, "Return" | "Break" | "Continue", _] -> scanControls,
CallNode[LeafNode[Symbol, "Pattern", _], _, _] -> scanPatterns,
(*
Tags: WhichArguments SwitchWhichConfusion
*)
CallNode[LeafNode[Symbol, "Which", _], _, _] -> scanWhichs,
(*
Tags: SwitchArguments SwitchWhichConfusion OperatingSystemLinux
*)
CallNode[LeafNode[Symbol, "Switch", _], _, _] -> scanSwitchs,
(*
Tags: IfArguments
*)
CallNode[LeafNode[Symbol, "If", _], _, _] -> scanIfs,
(*
Tags: DuplicateKeys
*)
CallNode[LeafNode[Symbol, "Association", _], _, _] -> scanAssocs,
CallNode[LeafNode[Symbol, "List", _], { CallNode[LeafNode[Symbol, "Rule" | "RuleDelayed", _], _, _]... }, _] -> scanListsOfRules,
(*
Tags:
*)
CallNode[LeafNode[Symbol, "Module", _], _, _] -> scanModules,
(*
Tags:
*)
CallNode[LeafNode[Symbol, "DynamicModule", _], _, _] -> scanDynamicModules,
(*
Tags:
*)
CallNode[LeafNode[Symbol, "With", _], _, _] -> scanWiths,
(*
Tags:
*)
CallNode[LeafNode[Symbol, "Block" | "Internal`InheritedBlock", _], _, _] -> scanBlocks,
(*
Tags:
*)
(*
1-arg Optional[] is ok to have named patterns
Only scan 2-arg Optionals
*)
CallNode[LeafNode[Symbol, "Optional", _], {_, _}, _] -> scanOptionals,
(*
Tags:
*)
(*
experimental
must handle Condition
CallNode[LeafNode[Symbol, "Replace" | "ReplaceAll" | "ReplaceRepeated", _], _, _] -> scanReplaces,
*)
(*
Scan some symbols that are intuitive, yet do not exist
*)
LeafNode[Symbol,
"AnyFalse" | "AllFalse" | "Failed" | "Boolean" | "RealQ" | "FalseQ" | "RationalQ" |
"ComplexQ" | "SymbolQ" | "Match" | "UnSameQ" | "StringMatch", _] -> scanBadSymbols,
(*
If LoadJavaClass["java.lang.System"] is called, then these symbols are created in System`
It is therefore dangerous to use these symbols in production code where it is unknown whether JLink will be used.
too noisy
SymbolNode[Symbol, "arraycopy" | "clearProperty" | "console" | "currentTimeMillis" | "err" | "exit" | "gc" |
"getenv" | "getProperties" | "getProperty" | "getSecurityManager" | "identityHashCode" |
"in" | "inheritedChannel" | "lineSeparator" | "load" | "loadLibrary" | "mapLibraryName" |
"nanoTime" | "out" | "runFinalization" | "runFinalizersOnExit" | "setErr" | "setIn" |
"setOut" | "setProperties" | "setProperty" | "setSecurityManager", _] -> scanJavaSystemSymbols,
*)
CallNode[LeafNode[Symbol, "LoadJavaClass" | "JLink`LoadJavaClass", _], {
LeafNode[String, "\"java.lang.System\"", _] }, _] -> scanLoadJavaClassSystem,
(*
scan for a := a and a = a
possible results from batch renaming symbols
*)
CallNode[LeafNode[Symbol, "Set" | "SetDelayed", _], {
LeafNode[Symbol, token_, _], LeafNode[Symbol, token_, _] }, _] -> scanSelfAssignments,
ContextNode[{LeafNode[String, "\"Private`\"", _]}, _, _] -> scanPrivateContextNode,
LeafNode[Symbol, "$HistoryLength" | "$Line", _] -> scanSessionSymbols,
CallNode[LeafNode[Symbol, "In" | "Out" | "InString", _], _, _] -> scanSessionCalls,
(*
too noisy
CallNode[LeafNode[Symbol, "Print" | "Echo", _], _, _] -> scanDebugCalls,
*)
(*
experimental
FileNode[_, _, _] -> scanFiles,
*)
(*
experimental
detect a?fooQ when you meant a_?fooQ
currently too difficult to determine what is a pattern
CallNode[SymbolNode[Symbol, "PatternTest", _], {
lhs_ /; FreeQ[lhs, CallNode[SymbolNode[Symbol, "Pattern" | "Blank" | "BlankSequence" | "BlankNullSequence", _], _, _]],
_}, _] -> scanPatternTestMissingPattern,
*)
(*
experimental
detect calls like f[a_] := a_
TODO: A clever thing to do would be to detet when inside of Quiet[ ,{Rule::rhs, RuleDelayed::rhs}] and turn off this check
CallNode[SymbolNode[Symbol, "Set" | "SetDelayed", _], { lhs_, rhs_ } /;
Intersection[Cases[lhs, CallNode[SymbolNode[Symbol, "Pattern", _], {SymbolNode[Symbol, name_, _], _}, _] :> name, {0, Infinity}],
Cases[rhs, CallNode[SymbolNode[Symbol, "Pattern", _], {SymbolNode[Symbol, name_, _], _}, _] :> name, {0, Infinity}]] != {}, _] -> scanRHSPatterns,
*)
CallNode[LeafNode[Symbol, "And", _], _, _] -> scanAnds,
CallNode[LeafNode[Symbol, "Or", _], _, _] -> scanOrs,
CallNode[LeafNode[Symbol, "Alternatives", _], _, _] -> scanAlternatives,
CallNode[LeafNode[Symbol, "Slot" | "SlotSequence", <||>], _, _] -> scanSlots,
CallNode[LeafNode[Symbol, "Refine" | "Reduce" | "Solve" | "FindInstance" | "Assuming", _], _, _] -> scanSolverCalls,
CallNode[LeafNode[Symbol, "Rule", _], {lhs_ /; !FreeQ[lhs, CallNode[LeafNode[Symbol, "Pattern", _], _, _]], _}, _] -> scanPatternRules,
CallNode[LeafNode[Symbol, "Rule", _], {LeafNode[Symbol, "ImageSize", _], rhs_ /; !FreeQ[rhs, CallNode[LeafNode[Symbol, "ImageDimensions", _], _, _]]}, _] -> scanImageSizes,
(*
Do a basic scan for Patterns in rhs here, this is just a preliminary scan
*)
CallNode[LeafNode[Symbol, "RuleDelayed" | "SetDelayed", _], {lhs_, rhs_ /; !FreeQ[rhs, CallNode[LeafNode[Symbol, "Pattern", _], _, _]]}, _] -> scanRHSPatterns,
CallNode[LeafNode[Symbol, "OptionsPattern", _], {}, _] -> scanOptionsPattern,
(*
cst of [x] is fine
ast of [x] is an error
*)
AbstractSyntaxErrorNode[_, _, _] -> scanAbstractSyntaxErrorNodes,
(*
Tags: SyntaxError NotContiguous
*)
KeyValuePattern[AbstractSyntaxIssues -> _] -> scanAbstractSyntaxIssues,
Nothing
|>
Attributes[scanBadCalls] = {HoldRest}
scanBadCalls[pos_List, astIn_] :=
Module[{ast, node, data, head, issues},
ast = astIn;
node = Extract[ast, {pos}][[1]];
head = node[[1]];
name = head["String"];
data = head[[3]];
issues = {};
Switch[name,
"String",
AppendTo[issues, InspectionObject["BadCall", "``String`` is not a function.", "Error", <|
Source -> data[Source],
CodeActions -> {
CodeAction["Replace ``String`` with ``StringQ``", ReplaceNode, <|
"ReplacementNode" -> ToNode[StringQ], Source -> data[Source] |>] }, ConfidenceLevel -> 0.90 |>]]
,
"Integer",
AppendTo[issues, InspectionObject["BadCall", "``Integer`` is not a function.", "Error", <|
Source -> data[Source],
CodeActions -> {
CodeAction["Replace ``Integer`` with ``IntegerQ``", ReplaceNode, <|
"ReplacementNode" -> ToNode[IntegerQ], Source -> data[Source] |>] }, ConfidenceLevel -> 0.90 |>]]
,
"Real",
AppendTo[issues, InspectionObject["BadCall", "``Real`` is not a function.", "Error", <|
Source -> data[Source],
CodeActions -> {
CodeAction["Replace ``Real`` with ``Developer`RealQ``", ReplaceNode, <|
"ReplacementNode" -> ToNode[Developer`RealQ], Source -> data[Source] |>] }, ConfidenceLevel -> 0.90 |>]]
,
"True",
AppendTo[issues, InspectionObject["BadCall", "``True`` is not a function.", "Error", <|
Source -> data[Source],
CodeActions -> {
CodeAction["Replace ``True`` with ``TrueQ``", ReplaceNode, <|
"ReplacementNode" -> ToNode[TrueQ], Source -> data[Source] |>] }, ConfidenceLevel -> 0.95 |>]]
,
_,
AppendTo[issues, InspectionObject["BadCall", format[name] <> " is not a function.", "Error", <|
data,
ConfidenceLevel -> 0.90 |> ]]
];
issues
]
(*
not a good scan
Attributes[scanFailureCalls] = {HoldRest}
scanFailureCalls[pos_List, astIn_] :=
Module[{ast, node, children, data},
ast = astIn;
node = Extract[ast, {pos}][[1]];
children = node[[2]];
data = node[[3]];
If[Length[children] == 1,
{Lint["FailureCall", {"Calling ", LintBold["Failure"], " as a function. Did you mean ", LintBold["FailureQ"],
"? This may be ok if ", LintBold["Failure"], " is handled programmatically."}, "Error", data]}
,
{}
]
]
*)
Attributes[scanAssocs] = {HoldRest}
scanAssocs[pos_List, astIn_] :=
Catch[
Module[{ast, node, children, data, issues, actions, counts, selected, srcs, dupKeys, expensiveChildren, filtered},
ast = astIn;
node = Extract[ast, {pos}][[1]];
children = node[[2]];
data = node[[3]];
issues = {};
If[!MatchQ[children, { CallNode[LeafNode[Symbol, "Rule" | "RuleDelayed", _], _, _]... }],
(*
Association does not have all Rule arguments.
*)
Throw[{}]
];
(*
Skip <| _ -> a, _ -> b |>
*)
filtered = DeleteCases[children, CallNode[_, { CallNode[LeafNode[Symbol, "Blank", _], _, _], _ }, _]];
expensiveChildren = ToFullFormString[#[[2, 1]]]& /@ filtered;
(*
bail out if there are errors and ToFullFormString has failed
*)
If[AnyTrue[expensiveChildren, FailureQ],
Throw[issues]
];
counts = CountsBy[filtered, ToFullFormString[#[[2, 1]]]&];
dupKeys = Keys[Select[counts, # > 1&]];
selecteds = Function[key, Pick[filtered, (# == key)& /@ expensiveChildren]] /@ dupKeys;
Do[
If[empty[selected],
Continue[]
];
srcs = #[[2, 1, 3, Key[Source]]]& /@ selected;
actions = MapIndexed[CodeAction["Delete key " <> ToString[#2[[1]]], DeleteNode, <|Source->#|>]&, srcs];
AppendTo[issues, InspectionObject["DuplicateKeys", "``Association`` has duplicated keys.", "Error", <|
Source -> First[srcs],
"AdditionalSources" -> Rest[srcs],
CodeActions -> actions, ConfidenceLevel -> 1.0 |> ]
];
,
{selected, selecteds}
];
issues
]]
Attributes[scanListsOfRules] = {HoldRest}
scanListsOfRules[pos_List, astIn_] :=
Catch[
Module[{ast, node, children, data, selected, issues, srcs, counts, keys, dupKeys, actions, expensiveChildren},
ast = astIn;
node = Extract[ast, {pos}][[1]];
children = node[[2]];
data = node[[3]];
issues = {};
keys = children[[All, 2, 1]];
(*
heuristic
if something like {_ -> {}, _ -> {}} then do not warn, it is just a pattern
*)
If[AnyTrue[keys, MatchQ[#, CallNode[LeafNode[Symbol, "Blank", _], _, _]]&],
Throw[issues]
];
expensiveChildren = ToFullFormString[#[[2, 1]]]& /@ children;
(*
bail out if there are errors and ToFullFormString has failed
*)
If[AnyTrue[expensiveChildren, FailureQ],
Throw[issues]
];
counts = CountsBy[children, ToFullFormString[#[[2, 1]]]&];
dupKeys = Keys[Select[counts, # > 1&]];
selecteds = Function[key, Pick[children, (# == key)& /@ expensiveChildren]] /@ dupKeys;
Do[
If[empty[selected],
Continue[]
];
(*
It is perfectly valid to have things like {1 -> NetPort["Output"], 1 -> 2 -> NetPort["Sum"]} in NetGraph
So make Remark for now
*)
srcs = #[[2, 1, 3, Key[Source]]]& /@ selected;
actions = MapIndexed[CodeAction["Delete key " <> ToString[#2[[1]]], DeleteNode, <|Source->#|>]&, srcs];
AppendTo[issues, InspectionObject["DuplicateKeys", "Duplicate keys in list of rules.", "Remark", <|
Source -> First[srcs],
"AdditionalSources" -> Rest[srcs],
CodeActions -> actions, ConfidenceLevel -> 1.0 |> ]
];
,
{selected, selecteds}
];
issues
]]
Attributes[scanWhichs] = {HoldRest}
scanWhichs[pos_List, astIn_] :=
Catch[
Module[{ast, node, children, data, issues, span, selected, lintData, srcs, counts, selecteds,
dupKeys, expensiveChildren, firsts},
ast = astIn;
node = Extract[ast, {pos}][[1]];
children = node[[2]];
data = node[[3]];
issues = {};
If[empty[children],
AppendTo[issues,
InspectionObject["WhichArguments", "``Which`` does not have any arguments.", "Error", <|data, ConfidenceLevel -> 0.55|>]];
Throw[issues]
];
If[!EvenQ[Length[children]],
AppendTo[issues,
InspectionObject["WhichArguments", "``Which`` does not have even number of arguments.", "Error", <|
data,
ConfidenceLevel -> 0.55|>]];
Throw[issues]
];
If[MatchQ[children[[1]], LeafNode[Symbol, "$OperatingSystem", _]],
span = children[[1, 3]];
AppendTo[issues,
InspectionObject["SwitchWhichConfusion", "``Which`` has ``$OperatingSystem`` in first place.\n\
Did you mean ``Switch``?", "Error", <|span, ConfidenceLevel -> 0.75|>]];
];
If[MatchQ[children[[-2]], CallNode[LeafNode[Symbol, "Blank", _], _, _]],
lintData = children[[-2, 3]];
AppendTo[issues,
InspectionObject["SwitchWhichConfusion", "``_`` is not a test.", "Error", <|
lintData,
CodeActions -> {
CodeAction["Replace ``_`` with ``True``", ReplaceNode, <|
"ReplacementNode" -> ToNode[True], Source->lintData[Source] |>]}, ConfidenceLevel -> 1.0 |>]];
];
Scan[(If[MatchQ[#, CallNode[LeafNode[Symbol, "Set", _], _, _]],
AppendTo[issues, InspectionObject["WhichSet", "``Which`` has ``=`` as a clause.\n\
Did you mean ``==``?", "Error", <|#[[3]], ConfidenceLevel -> 0.85|>]];
];)&, children[[;;;;2]]];
expensiveChildren = ToFullFormString /@ children[[;;;;2]];
(*
bail out if there are errors and ToFullFormString has failed
*)
If[AnyTrue[expensiveChildren, FailureQ],
Throw[issues]
];
counts = CountsBy[children[[;;;;2]], ToFullFormString];
dupKeys = Keys[Select[counts, # > 1&]];
selecteds = Function[key, Pick[children[[;;;;2]], (# == key)& /@ expensiveChildren]] /@ dupKeys;
Do[
If[empty[selected],
Continue[]
];
firsts = firstTokenWithSource /@ selected;
srcs = #[[3, Key[Source]]]& /@ firsts;
AppendTo[issues, InspectionObject["DuplicateClausesWhich", "Duplicate clauses in ``Which``.", "Error", <|
Source -> First[srcs],
"AdditionalSources" -> Rest[srcs],
ConfidenceLevel -> 0.95 |> ]
];
,
{selected, selecteds}
];
issues
]]
Attributes[scanSwitchs] = {HoldRest}
scanSwitchs[pos_List, astIn_] :=
Catch[
Module[{ast, node, children, data, src, cases, issues, selected, srcs, span, counts,
dupKeys, expensiveChildren, firsts},
ast = astIn;
node = Extract[ast, {pos}][[1]];
children = node[[2]];
data = node[[3]];
issues = {};
If[Length[children] == 1,
AppendTo[issues, InspectionObject["SwitchArguments", "``Switch`` only has one argument.", "Error", <|
data,
ConfidenceLevel -> 0.55|>]];
Throw[issues];
];
If[!OddQ[Length[children]],
AppendTo[issues, InspectionObject["SwitchArguments", "``Switch`` does not have odd number of arguments.", "Error", <|
data,
ConfidenceLevel -> 0.55|>]];
Throw[issues];
];
If[MatchQ[children[[1]], LeafNode[Symbol, "$OperatingSystem", _]],
cases = Cases[children[[2;;-1;;2]], LeafNode[String, "\"Linux\"", _], {0, Infinity}];
If[cases =!= {},
src = cases[[1, 3, Key[Source]]];
AppendTo[issues, InspectionObject["OperatingSystemLinux", "``\"Linux\"`` is not a value of ``$OperatingSystem``.", "Error", <|
Source -> src,
ConfidenceLevel -> 0.95, CodeActions -> {
CodeAction["Replace Linux with Unix", ReplaceNode, <|Source->src, "ReplacementNode"->ToNode["Unix"]|>]}|>]];
]
];
(*
Something like:
Switch[a,
1->2,
3->4,
_,5]
*)
If[Length[children] >= 5,
If[MatchQ[children[[2;;-3]], { CallNode[LeafNode[Symbol, "Rule", _], _, _].. }],
AppendTo[issues, InspectionObject["SwitchArguments", "``Switch`` does not take ``Rules`` for arguments.", "Error", <|
data,
ConfidenceLevel -> 0.95|>]];
]
];
(*
Switch has True in last place like this: Switch[a,1,b,True,c]
*)
If[MatchQ[children[[-2]], LeafNode[Symbol, "True", _]],
(*
heuristic
presence of False makes it less likely that True is unintended
*)
If[FreeQ[children[[2;;-4;;2]], LeafNode[Symbol, "False", _]],
span = children[[-2, 3]];
AppendTo[issues, InspectionObject["SwitchWhichConfusion", "``Switch`` has ``True`` in last place.\n\
Did you mean ``_``?", "Warning", <|span, ConfidenceLevel -> 0.75|>]];
]
];
expensiveChildren = ToFullFormString /@ children[[2;;;;2]];
(*
bail out if there are errors and ToFullFormString has failed
*)
If[AnyTrue[expensiveChildren, FailureQ],
Throw[issues]
];
counts = CountsBy[children[[2;;;;2]], ToFullFormString];
dupKeys = Keys[Select[counts, # > 1&]];
selecteds = Function[key, Pick[children[[2;;;;2]], (# == key)& /@ expensiveChildren]] /@ dupKeys;
Do[
If[empty[selected],
Continue[]
];
firsts = firstTokenWithSource /@ selected;
srcs = #[[3, Key[Source]]]& /@ firsts;
AppendTo[issues, InspectionObject["DuplicateClausesSwitch", "Duplicate clauses in ``Switch``.", "Error", <|
Source -> First[srcs],
"AdditionalSources" -> Rest[srcs],
ConfidenceLevel -> 0.95 |> ]
];
,
{selected, selecteds}
];
(*
pairs = Partition[children[[2;;]], 2];
Scan[(
form = #[[1]];
value = #[[2]];
formPatternNames = Cases[form, CallNode[LeafNode[Symbol, "Pattern", _], {LeafNode[Symbol, n_, _], _}, _] :> n, {0, Infinity}];
Scan[(
valuePatterns = Cases[value, LeafNode[Symbol, #, _], {0, Infinity}];
If[empty[valuePatterns],
(*
too noisy
add a Remark about unused named pattern in Switch? *)
Null
,
(*
too many false positives, so make this a Remark for now
experimental
Scan[(AppendTo[issues, Lint["NamedPatternInSwitch", "Named pattern in ``Switch``: ``" <> ToFullFormString[#] <> "``.\n\
The pattern ``" <> ToFullFormString[#] <> "`` occurs in the matching form, but ``Switch`` does not support pattern replacement.\n\
This may be ok if ``" <> ToFullFormString[#] <> "`` is set before being used.\n\
Consider removing the named pattern ``" <> ToFullFormString[#] <> "``.", "Remark", #[[3]]]])&, valuePatterns]*)
Null
]
)&, formPatternNames];
)&, pairs];*)
issues
]]
Attributes[scanIfs] = {HoldRest}
scanIfs[pos_List, astIn_] :=
Catch[
Module[{ast, node, children, data, issues, selected, srcs, counts, firsts},
ast = astIn;
node = Extract[ast, {pos}][[1]];
children = node[[2]];
data = node[[3]];
issues = {};
Which[
Length[children] == 0,
AppendTo[issues, InspectionObject["IfArguments", "``If`` has zero arguments.", "Error", <|data, ConfidenceLevel -> 0.55|>]];
Throw[issues];
,
Length[children] == 1,
AppendTo[issues, InspectionObject["IfArguments", "``If`` only has one argument.", "Error", <|data, ConfidenceLevel -> 0.55|>]];
Throw[issues];
];
If[MatchQ[children[[1]], CallNode[LeafNode[Symbol, "Set", _], _, _]],
AppendTo[issues, InspectionObject["IfSet", "``If`` has ``=`` as first argument.\n\
Did you mean ``==``?", "Warning", <| children[[1, 3]], ConfidenceLevel -> 0.85|>]];
];
srcs = {};
If[Length[children] >= 3,
counts = CountsBy[children[[2;;3]], ToFullFormString];
(*
bail out if there are errors and ToFullFormString has failed
*)
If[AnyTrue[Keys[counts], FailureQ],
Throw[issues]
];
(*
Do not warn about If[a, _, _]
*)
counts = KeyDrop[counts, "Blank[]"];
selected = Select[children[[2;;3]], counts[ToFullFormString[#]] > 1&];
If[!empty[selected],
firsts = firstTokenWithSource /@ selected;
srcs = #[[3, Key[Source]]]& /@ firsts;
AppendTo[issues, InspectionObject["DuplicateClausesIf", "Both branches of ``If`` are the same.", "Error", <|
Source -> First[srcs],
"AdditionalSources" -> Rest[srcs], ConfidenceLevel -> 0.95|>]]
];
];
issues
]]
(*
experimental
must handle Condition
Attributes[scanReplaces] = {HoldRest}
scanReplaces[pos_List, astIn_] :=
Catch[
Module[{ast, node, children, data, duplicates, issues, selected, rules, lhss},
ast = astIn;
node = Extract[ast, {pos}][[1]];
children = node[[2]];
data = node[[3]];
If[Length[children] == 2,
rules = children[[2]];
,
(*
operator form
*)
rules = children[[1]];
];
If[!MatchQ[rules, CallNode[LeafNode[Symbol, "List", _], _, _]],
Throw[{}];
];
Scan[(If[!MatchQ[#, CallNode[LeafNode[Symbol, "Rule" | "RuleDelayed", _], { _, _ }, _]],
Throw[{}];
];)&, rules[[2]]];
issues = {};
(*
get the lhss of all of the rules
*)
lhss = rules[[2, All, 2, 1]];
duplicates = Keys[Select[CountsBy[lhss, ToFullFormString], # > 1&]];
selected = Flatten[Select[lhss, Function[{c}, ToFullFormString[c] === #]]& /@ duplicates, 1];
Scan[(AppendTo[issues, Lint["DuplicateClauses", "Duplicate clauses in ``Replace``.", "Error", #[[3]]]])&, selected];
issues
]]
*)
Attributes[scanPatterns] = {HoldRest}
scanPatterns[pos_List, astIn_] :=
Catch[
Module[{ast, node, patSymbol, name, rhs, children, patterns, issues},
ast = astIn;
node = Extract[ast, {pos}][[1]];
children = node[[2]];
data = node[[3]];
issues = {};
If[Length[children] != 2,
AppendTo[issues, InspectionObject["PatternArguments", "``Pattern`` takes 2 arguments.", "Error", <|
data,
ConfidenceLevel -> 0.85|>]];
Throw[issues];
];
patSymbol = children[[1]];
name = patSymbol["String"];
rhs = children[[2]];
patterns = Cases[rhs, CallNode[LeafNode[Symbol, "Pattern", _], _, _], {0, Infinity}];
Scan[(
If[#[[2, 1]]["String"] == name,
AppendTo[issues, InspectionObject["DuplicatePatternName", "Pattern name " <> format[name] <> " occurs inside pattern with same name.", "Error", <|
Source -> #[[2, 1, 3, Key[Source]]],
"AdditionalSources" -> { patSymbol[[3, Key[Source]]] }, ConfidenceLevel -> 0.95 |> ]];
];
)&, patterns];
issues
]]
Attributes[scanControls] = {HoldRest}
scanControls[pos_List, astIn_] :=
Catch[
Module[{ast, node, data, parentPos, parent, s},
If[pos == {},
(* top node, no parent *)
Throw[{}]
];
ast = astIn;
node = Extract[ast, {pos}][[1]];
s = node["String"];
data = node[[3]];
parentPos = Most[pos];
parent = Extract[ast, {parentPos}][[1]];
While[ListQ[parent],
parentPos = Most[parentPos];
parent = Extract[ast, {parentPos}][[1]];
];
If[MatchQ[parent, CallNode[node, _, _]],
Throw[{}]
];
{InspectionObject["Control", format[s] <> " appears but is not called.\n\
Did you mean " <> format[s<>"[]"] <>"?", "Warning", <|data, ConfidenceLevel -> 0.85|>]}
]]
Attributes[scanModules] = {HoldRest}
scanModules[pos_List, astIn_] :=
Catch[
Module[{ast, node, children, data, selected, params, issues, vars, usedSymbols, unusedParams, counts,
ruleDelayedRHSs, ruleDelayedRHSSymbols, ruleDelayedRHSParams, stringFunctions, paramUses, paramString},
ast = astIn;
node = Extract[ast, {pos}][[1]];
children = node[[2]];
data = node[[3]];
issues = {};
If[empty[children],
AppendTo[issues, InspectionObject["ModuleArguments", "``Module`` does not have 2 arguments.", "Error", <|
data,
ConfidenceLevel -> 0.55|>]];
Throw[issues]
];
(*
Used as a pattern or GroupMissingCloserNode, so no issues
*)
If[MatchQ[children[[1]],
CallNode[LeafNode[Symbol, "Pattern" | "Blank" | "BlankSequence" | "BlankNullSequence", _], _, _] |
GroupMissingCloserNode[_, _, _]]
,
Throw[issues]
];
If[Length[children] != 2,
AppendTo[issues, InspectionObject["ModuleArguments", "``Module`` does not have 2 arguments.", "Error", <|
data,
ConfidenceLevel -> 0.55|>]];
Throw[issues]
];
(*
Module[Evaluate[]] denotes meta-programming
*)
If[MatchQ[children[[1]], CallNode[LeafNode[Symbol, "Evaluate", _], _, _]],
Throw[issues]
];
If[!MatchQ[children[[1]], CallNode[LeafNode[Symbol, "List", _], _, _]],
AppendTo[issues, InspectionObject["ModuleArguments", "``Module`` does not have a ``List`` for argument 1.", "Error", <|
children[[1, 3]],
ConfidenceLevel -> 0.55|>]];
Throw[issues]
];
If[MatchQ[children[[1]], CallNode[LeafNode[Symbol, "List", _], {}, _]],
AppendTo[issues, InspectionObject["ModuleArgumentsEmpty", "``Module`` has an empty ``List`` for argument 1.", "Remark", <|
children[[1, 3]],
ConfidenceLevel -> 0.90|>]];
];
params = children[[1, 2]];
vars = # /. {
CallNode[LeafNode[Symbol, "Set"|"SetDelayed", _], {
sym:LeafNode[Symbol, _, _], _}, _] :> sym,
sym:LeafNode[Symbol, _, _] :> sym,
(*
Compiler syntax includes:
Module[{ Typed[x, "Integer64"] }, x]
TODO: support this
CallNode[SymbolNode["Typed", {}, _], { sym:SymbolNode[_, _, _], _ }, _] :> sym
*)
err_ :> (AppendTo[issues, InspectionObject["ModuleArguments", "Variable " <> format[ToFullFormString[err]] <>
"does not have proper form.", "Error", <|#[[3]], ConfidenceLevel -> 0.85|>]]; Nothing)}& /@ params;
counts = CountsBy[vars, ToFullFormString];
(*
bail out if there are errors and ToFullFormString has failed
*)
If[AnyTrue[Keys[counts], FailureQ],
Throw[issues]
];
selected = Select[vars, counts[ToFullFormString[#]] > 1&];
If[!empty[selected],
srcs = #[[3, Key[Source]]]& /@ selected;
AppendTo[issues, InspectionObject["DuplicateVariables", "Duplicate variables in ``Module``.", "Error",
<| Source->First[srcs], "AdditionalSources"->Rest[srcs], ConfidenceLevel -> 1.0 |> ]];
];
usedSymbols = ToFullFormString /@ Cases[children[[2]], LeafNode[Symbol, _, _], {0, Infinity}];
unusedParams = Select[vars, Function[{c}, !MemberQ[usedSymbols, ToFullFormString[c]]]];
Scan[
AppendTo[issues, InspectionObject["UnusedVariables", "Unused variable in ``Module``: " <> format[ToFullFormString[#]] <> ".", "Warning", <|
#[[3]],
CodeActions -> { CodeAction["Delete", DeleteNode, <|Source->#[[3, Key[Source]]]|>]}, ConfidenceLevel -> 1.0 |> ]]&
,
unusedParams
];
stringFunctions =
Cases[children[[2]],
CallNode[LeafNode[Symbol, "StringReplace" | "StringReplaceList" | "StringSplit" | "StringCases", _], _, _], {0, Infinity}];
ruleDelayedRHSs =
Flatten[