Using avy-goto-word-1 in a wrapper

[kaushalmodi]

Can you suggest how I can get this functionality without using call-interactively?

(defun my/avy (arg)
      "
        `my/avy' -> `avy-goto-word-1'
    C-u `my/avy' -> `avy-goto-char-2'
C-u C-u `my/avy' -> `avy-goto-line'
"
      (interactive "p")
      (let ((avy-all-windows t) ; search in all windows
            (fci-state-orig fci-mode)
            (fn (cl-case arg
                  (4  'avy-goto-char-2) ; C-u
                  (16 'avy-goto-line) ; C-u C-u
                  (t  'avy-goto-word-1))))
        (if fci-state-orig
            (fci-mode 'toggle))
        (funcall fn)
        (if fci-state-orig
            (fci-mode 'toggle))))

The above wrapper function breaks because now the first arg to avy-goto-word-1 is a manadatory arg char; earlier its only arg was an optional arg to toggle avy-all-windows.

I cannot use call-interactively because then my wrapper function arg gets passed on to the function I am calling interactively.

[abo-abo]

What's fci-mode?

In any case, this works:

(defun my/avy (arg)
  "
        `my/avy' -> `avy-goto-word-1'
    C-u `my/avy' -> `avy-goto-char-2'
C-u C-u `my/avy' -> `avy-goto-line'
"
  (interactive "p")
  (let ((avy-all-windows t)
        (fn (cl-case arg
              (4 'avy-goto-char-2)
              (16 'avy-goto-line)
              (t 'avy-goto-word-1)))
        (current-prefix-arg nil))
    (call-interactively fn)))

[kaushalmodi]

Thanks! (current-prefix-arg nil) is what I needed.

fci-mode is a package that shows a vertical line overlay at your set fill column. It's a helful indicator to tell you how long your code lines should be.

The issue is that the overlay messes up the avi overlays and overlays in many other packages. So it is helpful to disable it temporarily.

Not disabling this temporarily causes this display anomaly. The gray line on the right is the _fci_.