/
StartBaseTask.groovy
274 lines (234 loc) · 8.67 KB
/
StartBaseTask.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
/*
* Gretty
*
* Copyright (C) 2013-2015 Andrey Hihlovskiy and contributors.
*
* See the file "LICENSE" for copying and usage permission.
* See the file "CONTRIBUTORS" for complete list of contributors.
*/
package org.akhikhl.gretty
import org.akhikhl.gretty.scanner.JDKScannerManager
import org.gradle.api.DefaultTask
import org.gradle.api.Task
import org.gradle.api.internal.TaskInternal
import org.gradle.api.plugins.ExtensionAware
import org.gradle.api.tasks.TaskAction
import org.gradle.process.JavaForkOptions
import org.gradle.testing.jacoco.plugins.JacocoTaskExtension
import org.springframework.boot.devtools.autoconfigure.OptionalLiveReloadServer
import org.springframework.boot.devtools.livereload.LiveReloadServer
/**
* Base task for starting jetty
*
* @author akhikhl
*/
abstract class StartBaseTask extends DefaultTask {
boolean interactive = true
boolean debug = false
Integer debugPort
Boolean debugSuspend
private JacocoHelper jacocoHelper
protected final List<Closure> prepareServerConfigClosures = []
protected final List<Closure> prepareWebAppConfigClosures = []
Map serverStartInfo
StartBaseTask() {
initJacoco()
getOutputs().upToDateWhen { false }
}
@TaskAction
void action() {
LauncherConfig config = getLauncherConfig()
Launcher launcher = new DefaultLauncher(project, config)
if(config.serverConfig.liveReloadEnabled) {
launcher.optionalLiveReloadServer = new OptionalLiveReloadServer(new LiveReloadServer())
}
launcher.scannerManager = createScannerManager(config, launcher.optionalLiveReloadServer)
if(getIntegrationTest()) {
boolean result = false
try {
launcher.beforeLaunch()
try {
project.ext.grettyLauncher = launcher
project.ext.grettyLaunchThread = launcher.launchThread()
result = true
} finally {
// Need to call afterLaunch in case of unsuccessful launch.
// If launch was successful, afterLaunch will be called in AppAfterIntegrationTestTask or FarmAfterIntegrationTestTask
if(!result)
launcher.afterLaunch()
}
} finally {
// Need to dispose of launcher in case of unsuccessful launch.
// If launch was successful, launcher will be shut down in AppAfterIntegrationTestTask or FarmAfterIntegrationTestTask
if(!result)
launcher.dispose()
}
}
else {
try {
launcher.launch()
} finally {
launcher.dispose()
}
}
serverStartInfo = launcher.getServerStartInfo()
}
private ScannerManager createScannerManager(LauncherConfig config, OptionalLiveReloadServer optionalLiveReloadServer) {
switch (config.serverConfig.scanner) {
case 'jdk':
if(JDKScannerManager.available()) {
return new JDKScannerManager(project, config.serverConfig, config.webAppConfigs, config.managedClassReload)
} else {
logger.error('JDK scanner was specified but it\'s not available. Falling back to jetty scanner')
return new JettyScannerManager(project, config.serverConfig, config.webAppConfigs, config.managedClassReload)
}
case 'jetty':
return new JettyScannerManager(project, config.serverConfig, config.webAppConfigs, config.managedClassReload)
default:
throw new IllegalArgumentException("Unknown scanner config: ${config.serverConfig.scanner}")
}
}
protected final void doPrepareServerConfig(ServerConfig sconfig) {
CertificateGenerator.maybeGenerate(project, sconfig)
if(getJacoco()?.enabled) {
String jacocoConfigJvmArg = getJacoco().getAsJvmArg()
if(jacocoConfigJvmArg)
sconfig.jvmArgs jacocoConfigJvmArg
}
if(getManagedClassReload(sconfig)) {
sconfig.jvmArgs '-javaagent:' + project.configurations.grettySpringLoaded.singleFile.absolutePath, '-noverify'
sconfig.systemProperty 'springloaded', 'exclusions=org.akhikhl.gretty..*'
}
for(Closure c in prepareServerConfigClosures) {
c = c.rehydrate(sconfig, c.owner, c.thisObject)
c.resolveStrategy = Closure.DELEGATE_FIRST
c()
}
}
protected final void doPrepareWebAppConfig(WebAppConfig wconfig) {
for(Closure c in prepareWebAppConfigClosures) {
c = c.rehydrate(wconfig, c.owner, c.thisObject)
c.resolveStrategy = Closure.DELEGATE_FIRST
c()
}
}
protected boolean getDefaultJacocoEnabled() {
false
}
protected boolean getIntegrationTest() {
false
}
JacocoTaskExtension getJacoco() {
jacocoHelper?.jacoco
}
private void initJacoco() {
if(project.extensions.findByName('jacoco') && project.gretty.jacocoEnabled) {
Task startTask = this
jacocoHelper = (TaskInternal.methods.collectEntries({ [it.name, {} ] }) +
JavaForkOptions.methods.collectEntries({ [it.name, {} ] }) +
ExtensionAware.methods.collectEntries({ [it.name, {} ] }) + [
getExtensions: { startTask.getExtensions() },
getInputs: { startTask.getInputs() },
getJacoco: { startTask.extensions.jacoco },
getName: { startTask.getName() },
getOutputs: { startTask.getOutputs() },
getProject: { startTask.project },
getWorkingDir: { project.projectDir },
]) as JacocoHelper
project.jacoco.applyTo(jacocoHelper)
jacocoHelper.jacoco.enabled = getDefaultJacocoEnabled()
}
}
protected final LauncherConfig getLauncherConfig() {
def self = this
def startConfig = getStartConfig()
new LauncherConfig() {
boolean getDebug() {
self.debug
}
int getDebugPort() {
self.debugPort == null ? self.project.gretty.debugPort : self.debugPort
}
boolean getDebugSuspend() {
self.debugSuspend == null ? self.project.gretty.debugSuspend : self.debugSuspend
}
boolean getInteractive() {
self.getInteractive()
}
boolean getManagedClassReload() {
self.getManagedClassReload(startConfig.getServerConfig())
}
ServerConfig getServerConfig() {
startConfig.getServerConfig()
}
String getStopCommand() {
self.getStopCommand()
}
File getBaseDir() {
new File(self.project.buildDir, 'serverBaseDir_' + getServerConfig().servletContainer)
}
boolean getProductMode() {
false
}
WebAppClassPathResolver getWebAppClassPathResolver() {
new WebAppClassPathResolver() {
Collection<URL> resolveWebAppClassPath(WebAppConfig wconfig) {
Set<URL> resolvedClassPath = new LinkedHashSet<URL>()
if(wconfig.projectPath) {
def proj = self.project.project(wconfig.projectPath)
String runtimeConfig = ProjectUtils.isSpringBootApp(proj) ? 'springBoot' : 'runtime'
resolvedClassPath.addAll(ProjectUtils.resolveClassPath(proj, wconfig.beforeClassPath))
resolvedClassPath.addAll(ProjectUtils.getClassPath(proj, wconfig.inplace, runtimeConfig))
resolvedClassPath.addAll(ProjectUtils.resolveClassPath(proj, wconfig.classPath))
} else {
for (def classpath in [wconfig.beforeClassPath, wconfig.classPath]) {
if (classpath) {
for (String elem in classpath) {
URL url
if (elem =~ /.{2,}\:.+/)
url = new URL(elem)
else
url = new File(elem).toURI().toURL()
resolvedClassPath.add(url)
}
}
}
}
resolvedClassPath
}
}
}
Iterable<WebAppConfig> getWebAppConfigs() {
startConfig.getWebAppConfigs()
}
}
}
protected boolean getManagedClassReload(ServerConfig sconfig) {
sconfig.managedClassReload
}
Collection<URL> getRunnerClassPath() {
DefaultLauncher.getRunnerClassPath(project, getStartConfig().serverConfig)
}
protected abstract StartConfig getStartConfig()
protected abstract String getStopCommand()
/**
* key is context path, value is collection of classpath URLs
* @return
*/
Map<String, Collection<URL> > getWebappClassPaths() {
LauncherConfig config = getLauncherConfig()
WebAppClassPathResolver resolver = config.getWebAppClassPathResolver()
config.getWebAppConfigs().collectEntries { wconfig ->
[ wconfig.contextPath, resolver.resolveWebAppClassPath(wconfig) ]
}
}
final void jacoco(Closure configureClosure) {
getJacoco()?.with configureClosure
}
final void prepareServerConfig(Closure closure) {
prepareServerConfigClosures.add(closure)
}
final void prepareWebAppConfig(Closure closure) {
prepareWebAppConfigClosures.add(closure)
}
}