forked from Aqua-Ye/OpaChat
-
Notifications
You must be signed in to change notification settings - Fork 0
/
main.opa
195 lines (167 loc) · 5.83 KB
/
main.opa
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
/* A simple, one-room, scalable real-time web chat
Copyright (C) 2010-2011 MLstate
This program is free software: you can redistribute it and/or modify
it under the terms of the GNU Affero General Public License as
published by the Free Software Foundation, either version 3 of the
License, or (at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU Affero General Public License for more details.
You should have received a copy of the GNU Affero General Public License
along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import stdlib.core.date
import stdlib.web.client
import stdlib.system
GITHUB_URL = "https://github.com/Aqua-Ye/OpaChat"
type user = (int, string) // user_id, user_name
type author = { system } / { author : user }
type message = {
author : author
text : string
date : Date.date
event : string
}
type client_channel = channel(void)
type msg = {message : message} / {connection : (user, client_channel)} / {disconnection : (user, client_channel)} / {stats}
db /history : intmap(message)
@publish room = Network.cloud("room") : Network.network(msg)
@private
users = Mutable.make([]:list(user))
@private
launch_date = Date.now()
@server
server_observe(message) =
match message
{connection=(user, client_channel)} ->
do jlog("connection {user}")
do users.set(List.add(user, users.get()))
do Network.broadcast({stats}, room)
do Session.on_remove(client_channel, (->
do jlog("auto disconnection {user}")
do server_observe({disconnection=(user, client_channel)})
void
))
void
{disconnection=(user, _client_channel)} ->
do jlog("disconnection {user}")
do users.set(List.remove(user, users.get()))
do Network.broadcast({stats}, room)
void
_ -> void
@server
_ = Network.observe(server_observe, room)
@client
update_stats((uptime, mem)) =
do Dom.transform([#uptime <- <>Uptime: {Date.to_string_time_only(uptime)}</>])
do Dom.transform([#memory <- <>Memory: {mem} Mo</>])
void
@client
update_users(users) =
list = List.fold((elt, acc -> <>{acc}<li>{elt.f2}</li></>), users, <></>)
do Dom.transform([#users <- <>Users: {List.length(users)}</>])
do Dom.transform([#user_list <- <ul>{list}</ul>])
void
@client
message_update(stats)(messages:list(message)) =
do update_stats(stats)
do List.iter(message->
line = <div class="line {message.event}">
<span class="date">{Date.to_string_time_only(message.date)}</span>
{ match message.author with
| {system} -> <span class="system"/>
| {~author} -> <span class="user">{author.f2}</span> }
<span class="message">{message.text}</span>
</div>
do Dom.transform([#conversation +<- line])
void
, messages)
Dom.set_scroll_top(Dom.select_window(), Dom.get_scrollable_size(#content).y_px)
@server
broadcast(author, event, text) =
message = {~author ~text date=Date.now() ~event}
do /history[?] <- message
Network.broadcast({message = message}, room)
@server
build_page(header, content) =
<div id=#header>
<div id=#logo/>
<div>{header}</div>
</div>
<div id=#content>{content}</div>
@client
send_message(broadcast) =
_ = broadcast("", Dom.get_value(#entry))
Dom.clear_value(#entry)
@client
do_broadcast(broadcast)(_) = send_message(broadcast)
@server
mem() = System.get_memory_usage()/(1024*1024)
compute_stats() =
uptime_duration = Date.between(launch_date, Date.now())
uptime = Date.of_duration(uptime_duration)
uptime = Date.shift_backward(uptime, Date.to_duration(Date.milliseconds(3600000))) // 1 hour shift
(uptime, mem())
@server
client_observe(msg) =
match msg
{~message} -> message_update(compute_stats())([message])
{stats} ->
do update_stats(compute_stats())
do update_users(users.get())
void
_ -> void
@server
init_client(user, client_channel) =
obs = Network.observe(client_observe, room)
_ = Network.broadcast({connection=(user, client_channel)}, room)
do Dom.bind_beforeunload_confirmation(_ ->
do Network.broadcast({disconnection=(user, client_channel)}, room)
do Network.unobserve(obs)
{none}
)
history_list = IntMap.To.val_list(/history)
len = List.length(history_list)
history = List.drop(len-20, history_list)
do message_update(compute_stats())(history)
void
@server
launch_chat(user:user, client_channel) =
broadcast = broadcast({author=user}, _, _)
build_page(
<a class="button github" href="{GITHUB_URL}" target="_blank">Fork me on GitHub !</a>,
<div id=#conversation onready={_ -> init_client(user, client_channel)}/>
<div id=#user_list/>
<div id=#stats><span id=#users/><span id=#uptime/><span id=#memory/></div>
<div id=#chatbar>
<input id=#entry onready={_ -> Dom.give_focus(#entry)} onnewline={do_broadcast(broadcast)}/>
<span class="button" onclick={do_broadcast(broadcast)}>Send</span>
</div>
)
@client
do_join(user_id, launch)(_) =
user = (user_id, Dom.get_value(#author))
client_channel = Session.make_callback(ignore)
Dom.transform([
#main <- <>Loading chat...</>,
#main <- launch(user, client_channel)
])
@server
main() =
user_id = Random.int(65536) // a user identifier
<div id=#main>{
build_page(
<h1>Wecome to OpaChat</h1>,
<span>Choose your name: </span>
<input id=#author onready={_ -> Dom.give_focus(#author)} onnewline={do_join(user_id, launch_chat)}/>
<span class="button" onclick={do_join(user_id, launch_chat)}>Join</span>
)
}</div>
server =
Server.one_page_bundle(
"OpaChat - a chat built with Opa",
[@static_resource_directory("resources")], // include resources directory
["resources/style.css"], // web application CSS
main
)