-
Notifications
You must be signed in to change notification settings - Fork 38
/
keywords.clj
63 lines (56 loc) · 2.37 KB
/
keywords.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
(ns compliment.sources.keywords
"Completion for keywords interned globally across the application"
(:require [compliment.sources :refer [defsource]]
[compliment.utils :refer [defmemoized resolve-namespace]])
(:import java.lang.reflect.Field))
(defmemoized ^:private keywords-table
[]
(let [^Field field (.getDeclaredField clojure.lang.Keyword "table")]
(.setAccessible field true)
(.get field nil)))
(defn- tagged-candidate [c]
{:candidate c, :type :keyword})
(defn qualified-candidates
"Returns a list of namespace-qualified double-colon keywords (like ::foo)
resolved for the given namespace."
[prefix ns]
(let [prefix (subs prefix 2)
ns-name (str ns)]
(for [[kw _] (keywords-table)
:when (= (namespace kw) ns-name)
:when (.startsWith (name kw) prefix)]
(tagged-candidate (str "::" (name kw))))))
(defn namespace-alias-candidates
"Returns a list of namespace aliases prefixed by double colon required in the
given namespace."
[prefix ns]
(let [prefix (subs prefix 2)
ns-name (str ns)]
(for [[alias _] (ns-aliases ns)
:let [aname (name alias)]
:when (.startsWith aname prefix)]
(tagged-candidate (str "::" aname)))))
(defn aliased-candidates
"Returns a list of alias-qualified double-colon keywords (like ::str/foo),
where alias has to be registered in the given namespace."
[prefix ns]
(when-let [[_ alias prefix] (re-matches #"::([^/]+)/(.*)" prefix)]
(let [alias-ns-name (str (resolve-namespace (symbol alias) ns))]
(for [[kw _] (keywords-table)
:when (= (namespace kw) alias-ns-name)
:when (.startsWith (name kw) prefix)]
(tagged-candidate (str "::" alias "/" (name kw)))))))
(defn candidates
[^String prefix, ns _]
(let [single-colon? (.startsWith prefix ":")
double-colon? (.startsWith prefix "::")
has-slash? (> (.indexOf prefix "/") -1)]
(cond (and double-colon? has-slash?) (aliased-candidates prefix ns)
double-colon? (concat (qualified-candidates prefix ns)
(namespace-alias-candidates prefix ns))
single-colon? (for [[kw _] (keywords-table)
:when (.startsWith (str kw) (subs prefix 1))]
(tagged-candidate (str ":" kw))))))
(defsource ::keywords
:candidates #'candidates
:doc (constantly nil))