forked from ChasManRors/ecb
-
Notifications
You must be signed in to change notification settings - Fork 21
/
ecb-util.el
733 lines (637 loc) · 30.3 KB
/
ecb-util.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
;;; ecb-util.el --- utility functions for ECB
;; Copyright (C) 2000, 2001 Jesper Nordenberg
;; Author: Jesper Nordenberg <mayhem@home.se>
;; Maintainer: Klaus Berndl <klaus.berndl@sdm.de>
;; Keywords: java, class, browser
;; This program is free software; you can redistribute it and/or modify it under
;; the terms of the GNU General Public License as published by the Free Software
;; Foundation; either version 2, or (at your option) any later version.
;; This program is distributed in the hope that it will be useful, but WITHOUT
;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
;; FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
;; details.
;; You should have received a copy of the GNU General Public License along with
;; GNU Emacs; see the file COPYING. If not, write to the Free Software
;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
;;; Commentary:
;;
;; Contains misc utility functions for ECB.
;;
;; This file is part of the ECB package which can be found at:
;; http://ecb.sourceforge.net
;;; History
;;
;; For the ChangeLog of this file see the CVS-repository. For a complete
;; history of the ECB-package see the file NEWS.
;; $Id$
;;; Code:
(eval-when-compile
(require 'silentcomp))
;; XEmacs
(silentcomp-defun mswindows-cygwin-to-win32-path)
(silentcomp-defun frame-property)
(silentcomp-defun point-at-bol)
(silentcomp-defun point-at-eol)
(silentcomp-defun frame-parameter)
(silentcomp-defun line-beginning-position)
(silentcomp-defun line-end-position)
(silentcomp-defun window-pixel-edges)
(silentcomp-defun make-dialog-box)
(silentcomp-defun display-message)
(silentcomp-defun clear-message)
(silentcomp-defun noninteractive)
;; Emacs
(silentcomp-defvar message-log-max)
(silentcomp-defvar message-truncate-lines)
(silentcomp-defun x-popup-dialog)
(silentcomp-defvar noninteractive)
;; Some constants
(defconst ecb-running-xemacs (string-match "XEmacs\\|Lucid" emacs-version))
(defconst ecb-running-emacs-21 (and (not ecb-running-xemacs)
(> emacs-major-version 20)))
(defconst ecb-directory-sep-char (if (boundp 'directory-sep-char)
directory-sep-char
?/))
(defconst ecb-directory-sep-string (char-to-string ecb-directory-sep-char))
(defconst ecb-temp-dir
(file-name-as-directory
(or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP")
(cond ((eq system-type 'windows-nt) "c:/temp/")
(t "/tmp/"))))
"a directory where ECB can store temporary files.")
(defconst ecb-ecb-dir
(expand-file-name (file-name-directory (locate-library "ecb"))))
(defconst ecb-semantic-dir
(if (locate-library "semantic")
(expand-file-name (file-name-directory (locate-library "semantic")))))
(defconst ecb-ecb-parent-dir (expand-file-name (concat ecb-ecb-dir "../")))
;; we assume that current loaded ECB is a regular XEmacs-package if and only
;; if `ecb-ecb-dir' contains the files "_pkg.el" and "auto-autoloads.el" and
;; we are running XEmacs
(defconst ecb-regular-xemacs-package-p
(and ecb-running-xemacs
(file-exists-p (expand-file-name (concat ecb-ecb-dir "_pkg.el")))
(file-exists-p (expand-file-name (concat ecb-ecb-dir "auto-autoloads.el")))))
(defconst ecb-semantic-regular-xemacs-package-p
(and ecb-running-xemacs
ecb-semantic-dir
(file-exists-p (expand-file-name (concat ecb-semantic-dir "_pkg.el")))
(file-exists-p (expand-file-name (concat ecb-semantic-dir "auto-autoloads.el")))))
(if ecb-running-xemacs
(progn
(defun ecb-subst-char-in-string (fromchar tochar string &optional inplace)
"Replace FROMCHAR with TOCHAR in STRING each time it occurs.
Unless optional argument INPLACE is non-nil, return a new string."
(let ((i (length string))
(newstr (if inplace string (copy-sequence string))))
(while (> i 0)
(setq i (1- i))
(if (eq (aref newstr i) fromchar)
(aset newstr i tochar)))
newstr))
(defalias 'ecb-frame-parameter 'frame-property)
(defalias 'ecb-line-beginning-pos 'point-at-bol)
(defalias 'ecb-line-end-pos 'point-at-eol)
(defun ecb-frame-char-width (&optional frame)
(/ (frame-pixel-width frame) (frame-width frame)))
(defun ecb-frame-char-height (&optional frame)
(/ (frame-pixel-height frame) (frame-height frame)))
(defun ecb-window-edges (&optional window)
(let ((pix-edges (window-pixel-edges window)))
(list (/ (nth 0 pix-edges) (ecb-frame-char-width))
(/ (nth 1 pix-edges) (ecb-frame-char-height))
(/ (nth 2 pix-edges) (ecb-frame-char-width))
(/ (nth 3 pix-edges) (ecb-frame-char-height))))))
(defalias 'ecb-subst-char-in-string 'subst-char-in-string)
(defalias 'ecb-frame-parameter 'frame-parameter)
(defalias 'ecb-line-beginning-pos 'line-beginning-position)
(defalias 'ecb-line-end-pos 'line-end-position)
(defalias 'ecb-frame-char-width 'frame-char-width)
(defalias 'ecb-frame-char-height 'frame-char-height)
(defalias 'ecb-window-edges 'window-edges))
;; Emacs 20 has no window-list function and the XEmacs and Emacs 21 one has
;; no specified ordering. The following one is stolen from XEmacs and has
;; fixed this lack of a well defined order.
(defun ecb-window-list (&optional frame minibuf window)
"Return a list of windows on FRAME, beginning with WINDOW. The
windows-objects in the result-list are in the same canonical windows-ordering
of `next-window'. If omitted, WINDOW defaults to the selected window. FRAME and
WINDOW default to the selected ones. Optional second arg MINIBUF t means count
the minibuffer window even if not active. If MINIBUF is neither t nor nil it
means not to count the minibuffer even if it is active."
(setq window (or window (selected-window))
frame (or frame (selected-frame)))
(if (not (eq (window-frame window) frame))
(error "Window must be on frame."))
(let ((current-frame (selected-frame))
list)
(unwind-protect
(save-window-excursion
(select-frame frame)
(walk-windows
(function (lambda (cur-window)
(if (not (eq window cur-window))
(setq list (cons cur-window list)))))
minibuf
'selected)
;; This is needed to get the right canonical windows-order, i.e. the
;; same order of windows than `walk-windows' walks through!
(setq list (nreverse list))
(setq list (cons window list)))
(select-frame current-frame))))
(defconst ecb-basic-adviced-functions (if ecb-running-xemacs
'((delete-frame . around)
(compilation-set-window-height . around)
(shrink-window-if-larger-than-buffer . around)
(show-temp-buffer-in-current-frame . around)
(scroll-other-window . around)
(compile-internal . before)
(custom-save-all . around)
(winner-mode . around)
(winner-redo . around)
(winner-undo . around)
(scroll-all-mode . after))
'((delete-frame . around)
(compilation-set-window-height . around)
(resize-temp-buffer-window . around)
(shrink-window-if-larger-than-buffer . around)
(scroll-other-window . around)
(compile-internal . before)
(custom-save-all . around)
(winner-mode . around)
(winner-redo . around)
(winner-undo . around)
(scroll-all-mode . after)))
"These functions are always adviced if ECB is active. Each element of the
list is a cons-cell where the car is the function-symbol and the cdr the
advice-class \(before, around or after). If a function should be adviced with
more than one class \(e.g. with a before and an after-advice) then for every
class a cons must be added to this list.
Every basic advice of ECB must be registered in this constant but can be
implemented in another file!")
(defun ecb-enable-basic-advices ()
(dolist (elem ecb-basic-adviced-functions)
(ad-enable-advice (car elem) (cdr elem) 'ecb)
(ad-activate (car elem))))
(defun ecb-disable-basic-advices ()
(dolist (elem ecb-basic-adviced-functions)
(ad-disable-advice (car elem) (cdr elem) 'ecb)
(ad-activate (car elem))))
;; some basic advices
(defadvice custom-save-all (around ecb)
"Save the customized options completely in the background, i.e. the
file-buffer where the value is saved \(see option `custom-file') is not parsed
by semantic and also killed afterwards."
(let ((ecb-window-sync nil)
(kill-buffer-hook nil)
(semantic-after-toplevel-cache-change-hook nil)
(semantic-after-partial-cache-change-hook nil))
;; now we do the standard task
ad-do-it
;; now we have to kill the custom-file buffer otherwise semantic would
;; parse the buffer of custom-file and the method-buffer would be updated
;; with the contents of custom-file which is definitely not desired.
(ignore-errors
(kill-buffer (find-file-noselect (cond (ecb-running-xemacs
custom-file)
(ecb-running-emacs-21
(custom-file))
(t
(or custom-file
user-init-file))))))))
;; assoc helpers
(defun ecb-remove-assoc (list key)
(delete* key list :test (function (lambda (key item) (string= key (car item))))))
(defun ecb-add-assoc (list key-value)
(cons key-value list))
(defun ecb-find-assoc-value (list key)
(cdr (assoc key list)))
(defun ecb-find-assoc (list key)
(assoc key list))
;;; Compatibility
(defun ecb-noninteractive ()
"Return non-nil if running non-interactively, i.e. in batch mode."
(if ecb-running-xemacs
(noninteractive)
noninteractive))
;; canonical filenames
(defun ecb-fix-filename (path &optional filename substitute-env-vars)
"Normalizes path- and filenames for ECB. If FILENAME is not nil its pure
filename \(i.e. without directory part) will be concatenated to PATH. The
result will never end with the directory-separator! If SUBSTITUTE-ENV-VARS is
not nil then in both PATH and FILENAME env-var substitution is done. If the
`system-type' is 'cygwin32 then the path is converted to win32-path-style!"
(when (stringp path)
(let (norm-path)
(setq norm-path (if (and ecb-running-xemacs (equal system-type 'cygwin32))
(mswindows-cygwin-to-win32-path path)
path))
(setq norm-path (expand-file-name (if substitute-env-vars
(substitute-in-file-name norm-path)
norm-path)))
(setq norm-path (if (and (> (length norm-path) 1)
(= (aref norm-path
(1- (length norm-path))) ecb-directory-sep-char))
(substring norm-path 0 (1- (length norm-path)))
norm-path))
(concat norm-path
(if (stringp filename)
(concat (if (> (length norm-path) 1)
ecb-directory-sep-string)
(file-name-nondirectory (if substitute-env-vars
(substitute-in-file-name filename)
filename))))))))
(defun ecb-nolog-message (&rest args)
"Works exactly like `message' but does not log the message"
(let ((msg (cond ((or (null args)
(null (car args)))
nil)
((null (cdr args))
(car args))
(t
(apply 'format args)))))
;; Now message is either nil or the formated string.
(if ecb-running-xemacs
;; XEmacs way of preventing log messages.
(if msg
(display-message 'no-log msg)
(clear-message 'no-log))
;; Emacs way of preventing log messages.
(let ((message-log-max nil)
(message-truncate-lines nil))
(if msg
(message "%s" msg)
(message nil))))
msg))
(defun ecb-confirm (text)
(yes-or-no-p text))
(defun ecb-create-source-internal (dir)
(let* ((use-dialog-box nil)
(filename (file-name-nondirectory (read-file-name "Source name: "
(concat dir "/")))))
(ecb-select-edit-window)
(if (string-match "\\.java$" filename)
(ecb-jde-gen-class-buffer dir filename)
(find-file (concat dir "/" filename)))))
(defun ecb-create-directory-source (node)
(ecb-create-source-internal (tree-node-get-data node)))
(defun ecb-create-source (node)
(ecb-create-source-internal (ecb-fix-filename (file-name-directory
(tree-node-get-data node)))))
;; ecb.el 4005
(defun ecb-create-file (node)
(ecb-create-file-3 (tree-node-get-data node)))
;; Nur intern
(defun ecb-create-file-3 (dir)
(ecb-select-edit-window)
(find-file (concat dir "/" (read-from-minibuffer "File name: "))))
;; ecb.el 4030
(defun ecb-create-file-2 (node)
(ecb-create-file-3 (ecb-fix-filename (file-name-directory
(tree-node-get-data node)))))
;; ecb.el 4029, 4077
(defun ecb-delete-source-2 (node)
(ecb-delete-source (tree-node-get-data node)))
;; ecb-upgrade.el: 701
(defun ecb-delete-file (file)
(let ((exp-file (expand-file-name file)))
(if (file-exists-p exp-file)
(delete-file exp-file))))
;; Nur intern
(defun ecb-delete-source (file)
(when (ecb-confirm (concat "Delete " file "?"))
(when (get-file-buffer file)
(kill-buffer (get-file-buffer file)))
(ecb-delete-file file)
(ecb-clear-history -1)))
;; ecb.el 4007
(defun ecb-create-directory (parent-node)
(make-directory (concat (tree-node-get-data parent-node) "/"
(read-from-minibuffer "Directory name: ")))
(ecb-update-directory-node parent-node)
(tree-buffer-update))
;; ecb.el 4008
(defun ecb-delete-directory (node)
(delete-directory (tree-node-get-data node))
(ecb-update-directory-node (tree-node-get-parent node))
(tree-buffer-update))
(defun ecb-grep-directory-internal (node find)
(select-window (or ecb-last-edit-window-with-point ecb-edit-window))
(let ((default-directory (concat (ecb-fix-filename
(if (file-directory-p
(tree-node-get-data node))
(tree-node-get-data node)
(file-name-directory
(tree-node-get-data node))))
ecb-directory-sep-string)))
(call-interactively (if find
(or (and (fboundp ecb-grep-find-function)
ecb-grep-find-function)
'grep-find)
(or (and (fboundp ecb-grep-function)
ecb-grep-function)
'grep)))))
(defun ecb-grep-find-directory (node)
(ecb-grep-directory-internal node t))
(defun ecb-grep-directory (node)
(ecb-grep-directory-internal node nil))
(defun ecb-enlarge-window(window &optional val)
"Enlarge the given window
If VAL is nil then WINDOW is enlarged so that it is 1/2 of the current frame.
If VAL is a positive integer then WINDOW is enlarged so that its new height is
VAL lines. If VAL is > 0 and < 1 then WINDOW is enlarged so that its new
height is that fraction of the frame."
(if (and window (window-live-p window))
(let* ((norm-val (if val
(ecb-normalize-number val (1- (frame-height)))
(/ (1- (frame-height)) 2)))
(enlargement (- norm-val (window-height window))))
(save-selected-window
(select-window window)
(if (> enlargement 0)
(enlarge-window enlargement))))
(error "Window is not alive!")))
;; stolen from query.el and slightly enhanced
(defun ecb-query-string (prompt choices &optional other-prompt)
"Prints PROMPT and returns a string which must be one of CHOICES.
CHOICES is either a list of strings whereas the first choice is the default
\(which is returned if the user simply types RET) or nil \(then only a simple
RET quits the query and returns nil). If OTHER-PROMPT is not nil and a string
then the choice \"other\" is added to CHOICES and after selecting this choice
the user is prompted with OTHER-PROMPT to insert any arbitrary string."
(let* ((new-choices (if other-prompt
;; Emacs 20.X add-to-list can not append at the end
(append choices (list "other"))
choices))
(default (car new-choices))
answer)
(setq prompt (concat prompt
" ["
(if new-choices
(mapconcat (function (lambda (x) x))
new-choices ", ")
"RET")
"] "))
(setq new-choices (nconc (mapcar (function (lambda (x) (list x t)))
new-choices)
'('("" t))))
(setq answer (completing-read prompt new-choices nil t ""))
(cond ((string= answer "")
(setq answer default))
((string= answer "other")
(setq answer (read-string (concat other-prompt ": ")))))
answer))
(defun ecb-normalize-number (value &optional ref-value)
"Normalize VALUE in the following manner and return:
* VALUE > -1.0 and < +1.0 and REF-VALUE a number: `floor' of VALUE * REF-VALUE
* all other cases: `floor' of VALUE"
(floor (if (and (< value 1.0)
(> value -1.0)
(numberp ref-value))
(* ref-value value)
value)))
(defmacro ecb-with-readonly-buffer (buffer &rest body)
"Make buffer BUFFER current but do not display it. Evaluate BODY in buffer
BUFFER \(not readonly an evaluation-time of BODY) and make afterwards BUFFER
readonly. Note: All this is done with `save-excursion' so after BODY that
buffer is current which was it before calling this macro."
`(if (buffer-live-p ,buffer)
(save-excursion
(set-buffer ,buffer)
(unwind-protect
(progn
(setq buffer-read-only nil)
,@body)
(setq buffer-read-only t)))
(ecb-error "Try to set a not existing buffer.")))
(put 'ecb-with-readonly-buffer 'lisp-indent-function 1)
(defmacro ecb-do-if-buffer-visible-in-ecb-frame (buffer-name-symbol &rest body)
"Evaluate BODY if the following condititions are all true:
- The symbol BUFFER-NAME-SYMBOL is bound
- The value of BUFFER-NAME-SYMBOL is a name of a living buffer B
- The buffer B is visible and displayed in a window of the `ecb-frame'
- ECB is active
- The current frame is the `ecb-frame'
- The window of buffer B is not the `ecb-edit-window'.
If one of these condititions is false then nothing will be done.
During the evaluation of BODY the following local variables are bound:
- visible-buffer: The buffer-object which name is the value of
BUFFER-NAME-SYMBOL.
- visible-window: The window which displays visible-buffer"
`(let* ((visible-buffer (if (and (boundp ,buffer-name-symbol)
(stringp (symbol-value ,buffer-name-symbol)))
(get-buffer (symbol-value ,buffer-name-symbol))))
(visible-window (if (bufferp visible-buffer)
(get-buffer-window visible-buffer))))
(when (and ecb-minor-mode
(equal (selected-frame) ecb-frame)
visible-window
(window-live-p visible-window)
(not (equal visible-window ecb-edit-window)))
,@body)))
(put 'ecb-do-if-buffer-visible-in-ecb-frame 'lisp-indent-function 1)
(defun ecb-read-number (prompt &optional init-value)
"Ask in the minibuffer for a number with promptstring PROMPT. Optional
INIT-VALUE can be either a number or a string-representation of a number."
(let ((init (cond ((numberp init-value)
(number-to-string init-value))
((stringp init-value)
(if (string= init-value "0")
init-value
(if (not (= 0 (string-to-number init-value)))
init-value
(ecb-error "ecb-read-number: init-value not a valid number!"))))
(t nil)))
result)
(while (progn
(setq result (read-string prompt init))
(not (or (string= "0" result)
(not (= 0 (string-to-number result)))))))
(string-to-number result)))
(defun ecb-option-get-value (option &optional type)
"Return the value of a customizable ECB-option OPTION with TYPE, where TYPE
can either be 'standard-value \(the default-value of the defcustom) or
'saved-value \(the value stored durable by the user via customize) or
'customized-value \(the value set but not saved in the customize buffer).
If TYPE is nil then the most recent set value is returned, means it
tries the customized-value, then the saved-value and then the standard-value
in exactly this sequence."
(let ((val (car (if type
(get option type)
(or (get option 'customized-value)
(get option 'saved-value)
(get option 'standard-value))))))
(cond ((not (listp val)) val)
((equal 'quote (car val)) (car (cdr val)))
(t (car val)))))
(defun ecb-message-box (message-str &optional title-text button-text)
"Display a messagebox with message MESSAGE-STR and title TITLE-TEXT if
TITLE-TEXT is not nil - otherwise \"Messagebox\" is used as title. The title
gets always the prefix \"ECB - \". Second optional argument BUTTON-TEXT
specifies the text of the message-box button; if nil then \"OK\" is used.
Remark: BUTTON-TEXT is currently only used with XEmacs. Wie GNU Emacs the
message itself is the button because GNU Emacs currently does not support
dialog-boxes very well.
If `window-system' is nil then a simple message is displayed in the echo-area."
(let ((button (if (stringp button-text)
button-text
"OK"))
(title (concat "ECB"
(if (stringp title-text)
(concat " - " title-text)
" Message"))))
(if window-system
(progn
(if ecb-running-xemacs
(make-dialog-box 'question
:title title
:modal t
:question message-str
:buttons (list (vector button '(identity nil) t)))
(x-popup-dialog t (list title (cons message-str t))))
t)
(message (concat title " " message-str)))))
(defun ecb-error (&rest args)
"Signals an error but prevents it from entering the debugger. This is
usefull if an error-message should be signaled to the user and evaluating
should stopped but no debugging is senseful."
(let ((debug-on-error nil))
(error (concat "ECB " ecb-version ": "
(apply 'format args)))))
;; trimming
(defun ecb-excessive-trim (str)
"Return a string where all double-and-more whitespaces in STR are replaced
with a single space-character."
(let ((s str))
(while (string-match "[ \t][ \t]+" s)
(setq s (concat (substring s 0 (match-beginning 0))
" "
(substring s (match-end 0)))))
s))
(defun ecb-left-trim (str)
"Return a string stripped of all leading whitespaces of STR."
(or (car (split-string str "^[\n\t ]*")) ""))
(defun ecb-right-trim (str)
"Return a string stripped of all trailing whitespaces of STR."
(or (car (split-string str "[\n\t ]*$")) ""))
(defun ecb-trim (str)
"Applies `ecb-right-trim' and `ecb-left-trim' to STR."
(ecb-left-trim (ecb-right-trim str)))
(defun ecb-full-trim (str)
"Applies `ecb-trim' and `ecb-middle-trim' to STR."
(ecb-excessive-trim (ecb-trim str)))
;; code for a working display - complete stolen from the semantic-package.
;; ECB has thrown away all code which is not needed by ECB
;; The original code is written by Eric M. Ludlam <zappo@gnu.org>
;; we need this here so we are independent of the semantic-package so we can
;; download eieio and semantic even if the user has not installed any version
;; of semantic.
;;; Variables used in stages
;;
(defvar ecb-working-message nil
"Message stored when in a status loop.")
(defvar ecb-working-donestring nil
"Done string stored when in a status loop.")
(defvar ecb-working-ref1 nil
"A reference number used in a status loop.")
(defvar ecb-working-last-percent 0
"A reference number used in a status loop.")
(defun ecb-working-frame-animation-display (length number frames)
"Manage a simple frame-based animation for working functions.
LENGTH is the number of characters left. NUMBER is a passed in
number (which happens to be ignored.). While coders pass t into
NUMBER, functions using this should convert NUMBER into a vector
describing how to render the done message.
Argument FRAMES are the frames used in the animation."
(cond ((vectorp number)
(let ((zone (- (length (aref frames 0)) (length (aref number 0))
(length (aref number 1)))))
(if (< (length ecb-working-donestring) zone)
(concat " " (aref number 0)
(make-string
(ceiling (/ (- (float zone)
(length ecb-working-donestring)) 2)) ? )
ecb-working-donestring
(make-string
(floor (/ (- (float zone)
(length ecb-working-donestring)) 2)) ? )
(aref number 1))
(concat " " (aref frames (% ecb-working-ref1 (length frames)))
" " ecb-working-donestring))))
(t (concat " " (aref frames (% ecb-working-ref1 (length frames)))))))
(defvar ecb-working-celeron-strings
[ "[O ]" "[oO ]" "[-oO ]" "[ -oO ]" "[ -oO ]" "[ -oO]"
"[ -O]" "[ O]" "[ Oo]" "[ Oo-]" "[ Oo- ]" "[ Oo- ]"
"[Oo- ]" "[O- ]"]
"Strings representing a silly celeron.")
(defun ecb-working-celeron-display (length number)
"Return a string displaying a celeron as things happen.
LENGTH is the amount of display that has been used. NUMBER
is t to display the done string, or the number to display."
(cond ((eq number t)
(ecb-working-frame-animation-display length [ "[" "]" ]
ecb-working-celeron-strings))
;; All the % signs because it then gets passed to message.
(t (ecb-working-frame-animation-display length number
ecb-working-celeron-strings))))
(defun ecb-working-dynamic-status (&optional number)
"show the status. If NUMBER is nil, then increment a local NUMBER from 0
with each call. If it is a number or float, use it as the raw percentile."
(let* ((n (or number ecb-working-ref1))
(m1 (funcall 'format ecb-working-message))
(m2 (ecb-working-celeron-display (length m1) n)))
(ecb-nolog-message "%s%s" m1 m2)
(setq ecb-working-ref1 (1+ ecb-working-ref1))))
(defmacro ecb-working-status-timeout (timeout message donestr &rest forms)
"Contain a block of code during which working status is shown.
The code may call `sit-for' or `accept-process-output', so a timer
is needed to update the message.
TIMEOUT is the length of time to wait between message updates.
MESSAGE is the message string to use and DONESTR is the completed text
to use when the functions `ecb-working-status' is called from FORMS."
(let ((current-message (make-symbol "ecb-working-current-message")))
`(let* ((,current-message (current-message))
(ecb-working-message ,message)
(ecb-working-donestring ,donestr)
(ecb-working-ref1 0)
(time ,timeout)
(ecb-working-timer
(run-with-timer time time 'ecb-working-dynamic-status)))
(unwind-protect
(progn ,@forms)
(cancel-timer ecb-working-timer)
(ecb-working-dynamic-status t)
(message ,current-message)))))
(defun ecb-working-status-call-process
(timeout message donestr program &optional infile buffer display &rest args)
"Display working messages while running a process.
TIMEOUT is how fast to display the messages.
MESSAGE is the message to show, and DONESTR is the string to add when done.
CALLPROCESSARGS are the same style of args as passed to `call-process'.
The are: PROGRAM, INFILE, BUFFER, DISPLAY, and ARGS.
Since it actually calls `start-process', not all features will work."
(ecb-working-status-timeout timeout message donestr
(let ((proc (apply 'start-process "ecb-working"
(if (listp buffer) (car buffer) buffer)
program args)))
(set-process-sentinel proc 'list)
(while (eq (process-status proc) 'run)
(accept-process-output proc)
;; accept-process-output caused my solaris Emacs 20.3 to crash.
;; If this is unreliable for you, use the below which will work
;; in that situation.
;; (if (not (sit-for timeout)) (read-event))
))))
(defun ecb-file-content-as-string (file)
"If FILE exists and is readable returns the contents as a string otherwise
return nil.
Note: No major/minor-mode is activated and no local variables are evaluated
for FILE, but proper EOL-conversion and charcater interpretation is done!"
(let ((exp-filename (expand-file-name file)))
(if (and (file-exists-p exp-filename)
(file-readable-p exp-filename))
(with-temp-buffer
(insert-file-contents exp-filename)
(buffer-string)))))
(silentcomp-provide 'ecb-util)
;;; ecb-util.el ends here