forked from VIDA-NYU/ache
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
142 lines (125 loc) · 4.25 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'application'
apply plugin: "jacoco"
apply plugin: 'com.github.kt3k.coveralls'
sourceCompatibility = 1.8
targetCompatibility = 1.8
compileJava.options.encoding = "UTF-8"
version = '0.10.0-SNAPSHOT'
mainClassName = 'focusedCrawler.Main'
applicationDefaultJvmArgs = ["-Dname=ache -XX:+UseConcMarkSweepGC -XX:+HeapDumpOnOutOfMemoryError"]
repositories {
mavenCentral()
}
dependencies {
// Logging
compile 'org.slf4j:slf4j-api:1.7.+'
compile 'ch.qos.logback:logback-classic:1.1.+'
// Commons
compile 'com.google.guava:guava:20.0'
compile 'org.apache.commons:commons-lang3:3.4'
compile 'org.apache.commons:commons-compress:1.12'
compile 'commons-codec:commons-codec:1.10'
compile 'commons-validator:commons-validator:1.5.1'
compile 'com.github.crawler-commons:crawler-commons:0.8'
compile 'org.apache.httpcomponents:httpclient:4.5.2'
// CLI
compile 'io.airlift:airline:0.7'
// Data serialization
compile 'com.fasterxml.jackson.core:jackson-databind:2.8.5'
compile 'com.fasterxml.jackson.dataformat:jackson-dataformat-cbor:2.8.5'
compile 'com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.8.5'
compile 'com.esotericsoftware:kryo:4.0.0'
// Others
compile 'org.rocksdb:rocksdbjni:4.11.2'
compile 'org.apache.tika:tika-parsers:1.14'
compile 'com.syncthemall:boilerpipe:1.2.2'
compile 'net.sourceforge.nekohtml:nekohtml:1.9.22'
//compile 'nz.ac.waikato.cms.weka:weka-stable:3.6.13'
compile 'com.github.haifengl:smile-core:1.5.0'
compile 'org.apache.lucene:lucene-core:4.10.4'
compile 'org.elasticsearch:elasticsearch:1.4.4'
compile 'org.elasticsearch.client:elasticsearch-rest-client:5.6.3'
compile 'io.dropwizard.metrics:metrics-core:3.1.3'
compile 'io.dropwizard.metrics:metrics-json:3.1.3'
compile 'io.dropwizard.metrics:metrics-jvm:3.1.3'
compile 'com.amazonaws:aws-java-sdk-s3:1.11.213'
compile 'org.jsoup:jsoup:1.10.3'
compile 'com.squareup.okhttp3:okhttp:3.8.1'
compile group: 'org.apache.kafka', name: 'kafka-clients', version: '0.11.0.1'
compile('org.netpreserve.commons:webarchive-commons:1.1.8') {
exclude group: 'org.apache.hadoop', module: 'hadoop-core'
exclude group: 'junit', module: 'junit'
}
// REST server dependencies
compile "com.sparkjava:spark-core:2.5.3"
testCompile 'junit:junit:4.12'
testCompile 'org.hamcrest:hamcrest-all:1.3'
testCompile 'org.mockito:mockito-core:1.10.+'
testCompile 'org.eclipse.jetty:jetty-server:9.3.6.v20151106' // for tests of crawler commons library fork
testCompile 'com.squareup.okhttp3:mockwebserver:3.8.1'
// TODO fill these in from Maven Central instead of that local libs dir
compile files('libs/jsonic-1.2.0.jar') // recommend updating this, it's for langdetect.jar
compile files('libs/langdetect-03-03-2014.jar') // TODO why isn't this in maven central
}
//
// Make sure that ache-dashboard is compiled and copied into resources folder
// before the resources are processed and bundled into the JAR file
//
processResources {
dependsOn ':ache-dashboard:install'
}
//
// Adds version to final JAR artifact
//
jar {
manifest {
attributes(
"Implementation-Title": project.name,
"Implementation-Version": version
)
}
}
//
// Copies config folder into final distribution file
//
task copyConfig {
def f = file("$buildDir/config")
outputs.dir f
doLast {
copy {
from "config/"
into "$buildDir/config"
exclude "sample_model", "sample_training_data", "sample.seeds"
}
}
}
applicationDistribution.from(copyConfig) {
into "config"
}
//
// Integration for test coverage service: coveralls
//
buildscript {
repositories {
mavenCentral()
}
dependencies {
classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.4.0'
}
}
jacocoTestReport {
reports {
xml.enabled = true // coveralls plugin depends on xml format report
html.enabled = true
}
afterEvaluate {
classDirectories = files(classDirectories.files.collect {
fileTree(
dir: it,
exclude: ['focusedCrawler/tools/**']
)
})
}
}