This repository has been archived by the owner on May 20, 2023. It is now read-only.
-
Notifications
You must be signed in to change notification settings - Fork 303
/
PKGBUILD
51 lines (43 loc) · 1.75 KB
/
PKGBUILD
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Sébastien Luttringer <seblu@aur.archlinux.org>
pkgname=lynis
pkgver=3.0.8
pkgrel=1
pkgdesc='Security and system auditing tool to harden Unix/Linux systems'
url='https://cisofy.com/lynis/'
arch=('any')
license=('GPL3')
backup=('etc/lynis/default.prf')
depends=('sh' 'awk')
optdepends=('net-tools: networking tests'
'bind-tools: nameserver tests'
'iptables: firewall tests')
source=("https://downloads.cisofy.com/lynis/lynis-$pkgver.tar.gz"{,.asc})
sha512sums=('df41aa8b7518a72ee17732eb7e69ccc62ca6e1323d3adc7aec509cd1c21494fece873e101bc317655dafbf58b32699f56dd27eec13a2ce615801cee75961cd33'
'SKIP')
b2sums=('490bd6799619a4247c3fa68cc96f2f1fead651b23db0ffb512394960f8ca0360ab7f25d2bb8d9e742641558972e1fdd4b1e18d7de0d13007988276eed3a97b1f'
'SKIP')
validpgpkeys=('84FAA9983B24AEF24D6C87F1FEBB7D1812576482') # CISOfy (Software Signing Key) <software@cisofy.com>
prepare() {
cd "$pkgname"
sed -e 's|/path/to/lynis|/usr/bin/lynis|g' -i extras/systemd/lynis.service
}
package() {
cd "$pkgname"
# application
install -Dm 755 lynis -t "${pkgdir}/usr/bin"
install -Dm 644 default.prf -t "${pkgdir}/etc/${pkgname}"
install -d "${pkgdir}/usr/share/${pkgname}"
cp -ra db include plugins "${pkgdir}/usr/share/${pkgname}"
# doc files
install -Dm 644 README INSTALL CHANGELOG.md FAQ \
-t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 "${pkgname}.8" -t "${pkgdir}/usr/share/man/man8"
# completion
install -Dm 644 extras/bash_completion.d/${pkgname} \
-t "${pkgdir}/usr/share/bash-completion/completions"
# systemd
install -Dm 644 extras/systemd/{lynis.service,lynis.timer} \
-t "${pkgdir}/usr/lib/systemd/system"
}
# vim: ts=2 sw=2 et: