forked from esl/ejabberd_tests
/
mam_SUITE.erl
1331 lines (1140 loc) · 45.3 KB
/
mam_SUITE.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%%==============================================================================
%% Copyright 2012 Erlang Solutions Ltd.
%%
%% Licensed under the Apache License, Version 2.0 (the "License");
%% you may not use this file except in compliance with the License.
%% You may obtain a copy of the License at
%%
%% http://www.apache.org/licenses/LICENSE-2.0
%%
%% Unless required by applicable law or agreed to in writing, software
%% distributed under the License is distributed on an "AS IS" BASIS,
%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
%% See the License for the specific language governing permissions and
%% limitations under the License.
%%==============================================================================
-module(mam_SUITE).
%% CT callbacks
-export([all/0,
groups/0,
suite/0,
init_per_suite/1,
end_per_suite/1,
init_per_group/2,
end_per_group/2,
init_per_testcase/2,
end_per_testcase/2]).
%% Tests
-export([mam_service_discovery/1,
muc_service_discovery/1,
simple_archive_request/1,
muc_archive_request/1,
muc_private_message/1,
range_archive_request/1,
limit_archive_request/1,
prefs_set_request/1,
pagination_first5/1,
pagination_last5/1,
pagination_before10/1,
pagination_after10/1,
pagination_empty_rset/1,
archived/1,
strip_archived/1,
policy_violation/1,
offline_message/1,
purge_single_message/1,
purge_multiple_messages/1,
purge_old_single_message/1]).
-include_lib("escalus/include/escalus.hrl").
-include_lib("common_test/include/ct.hrl").
-include_lib("exml/include/exml_stream.hrl").
-define(assert_equal(E, V), (
[ct:fail("ASSERT EQUAL~n\tExpected ~p~n\tValue ~p~n", [(E), (V)])
|| (E) =/= (V)]
)).
-record(rsm_in, {
max :: non_neg_integer() | undefined,
direction :: before | 'after' | undefined,
id :: binary() | undefined,
index ::non_neg_integer() | undefined
}).
-record(forwarded_message, {
from :: binary() | undefined,
to :: binary() | undefined,
result_queryid :: binary() | undefined,
result_id :: binary() | undefined,
delay_from :: binary() | undefined,
delay_stamp :: binary() | undefined,
message_to :: binary() | undefined,
message_type :: binary() | undefined,
message_body :: binary() | undefined
}).
-record(result_iq, {
from :: binary(),
to :: binary(),
id :: binary(),
first :: binary() | undefined,
first_index :: non_neg_integer() | undefined,
last :: binary() | undefined,
count :: non_neg_integer()
}).
-record(error_iq, {
id :: binary(),
type :: binary(),
error_type :: binary(),
condition :: binary(),
text :: binary()
}).
-record(prefs_result_iq, {
default_mode :: binary() | undefined,
always_jids = [] :: [binary()],
never_jids = [] :: [binary()]
}).
%%--------------------------------------------------------------------
%% Suite configuration
%%--------------------------------------------------------------------
muc_host() ->
<<"muc.localhost">>.
host() ->
<<"localhost">>.
configurations() ->
[odbc_async,
odbc,
odbc_mnesia,
riak_mnesia].
basic_group_names() ->
[
bootstrapped,
mam,
mam_purge,
muc,
rsm,
archived,
policy_violation,
offline_message].
all() ->
[{group, full_group(C, G)}
|| C <- configurations(), G <- basic_group_names()].
groups() ->
[{full_group(C, G), Props, Tests}
|| C <- configurations(), {G, Props, Tests} <- basic_groups()].
basic_groups() ->
[{bootstrapped, [], bootstrapped_cases()},
{mam, [], mam_cases()},
{mam_purge, [], mam_purge_cases()},
{archived, [], archived_cases()},
{policy_violation, [], policy_violation_cases()},
{offline_message, [], offline_message_cases()},
{muc, [], muc_cases()},
{rsm, [], rsm_cases()}].
bootstrapped_cases() ->
[purge_old_single_message].
mam_cases() ->
[mam_service_discovery,
simple_archive_request,
range_archive_request,
limit_archive_request,
prefs_set_request].
mam_purge_cases() ->
[purge_single_message,
purge_multiple_messages].
archived_cases() ->
[archived,
strip_archived].
policy_violation_cases() ->
[policy_violation].
offline_message_cases() ->
[offline_message].
muc_cases() ->
[muc_service_discovery,
muc_archive_request,
muc_private_message].
rsm_cases() ->
[pagination_first5,
pagination_last5,
pagination_before10,
pagination_after10,
pagination_empty_rset].
suite() ->
escalus:suite().
init_per_suite(Config) ->
clean_archives(escalus:create_users(escalus:init_per_suite(Config))).
end_per_suite(Config) ->
escalus:end_per_suite(escalus:delete_users(Config)).
init_per_group(Group, Config) ->
C = configuration(Group),
B = basic_group(Group),
Config1 = init_modules(C, B, Config),
init_state(C, B, Config1).
end_per_group(Group, Config) ->
C = configuration(Group),
B = basic_group(Group),
Config1 = end_state(C, B, Config),
end_modules(C, B, Config1).
init_modules(odbc, muc, Config) ->
init_module(muc_host(), mod_mam, odbc_muc_args()),
Config;
init_modules(odbc_async, muc, Config) ->
init_module(muc_host(), mod_mam, odbc_async_muc_args()),
Config;
init_modules(odbc_mnesia, muc, Config) ->
init_module(muc_host(), mod_mam, odbc_mnesia_muc_args()),
Config;
init_modules(riak_mnesia, muc, Config) ->
init_module(muc_host(), mod_mam, riak_mnesia_muc_args()),
Config;
init_modules(odbc, _, Config) ->
init_module(host(), mod_mam, odbc_args()),
Config;
init_modules(odbc_async, _, Config) ->
init_module(host(), mod_mam, odbc_async_args()),
Config;
init_modules(odbc_mnesia, _, Config) ->
init_module(host(), mod_mam, odbc_mnesia_args()),
Config;
init_modules(riak_mnesia, _, Config) ->
init_module(host(), mod_mam, riak_mnesia_args()),
Config.
end_modules(_, _, Config) ->
Config.
odbc_args() ->
[{prefs_module, mod_mam_odbc_prefs},
{writer_module, mod_mam_odbc_arch},
{archive_module, mod_mam_odbc_arch}].
odbc_async_args() ->
[{prefs_module, mod_mam_odbc_prefs},
{writer_module, mod_mam_odbc_async_writer},
{archive_module, mod_mam_odbc_arch}].
odbc_mnesia_args() ->
[{prefs_module, mod_mam_mnesia_prefs},
{writer_module, mod_mam_odbc_arch},
{archive_module, mod_mam_odbc_arch}].
riak_mnesia_args() ->
[{prefs_module, mod_mam_mnesia_prefs},
{writer_module, mod_mam_riak_arch},
{archive_module, mod_mam_riak_arch}].
odbc_async_muc_args() ->
[{muc, true},
{prefs_module, mod_mam_odbc_prefs},
{writer_module, mod_mam_muc_odbc_async_writer},
{archive_module, mod_mam_muc_odbc_arch}].
odbc_muc_args() ->
[{muc, true},
{prefs_module, mod_mam_odbc_prefs},
{writer_module, mod_mam_muc_odbc_arch},
{archive_module, mod_mam_muc_odbc_arch}].
%% TODO write mod_mam_muc_mnesia_prefs
odbc_mnesia_muc_args() ->
[{muc, true},
{prefs_module, mod_mam_mnesia_prefs},
{writer_module, mod_mam_muc_odbc_arch},
{archive_module, mod_mam_muc_odbc_arch}].
%% TODO write mod_mam_muc_riak_arch
riak_mnesia_muc_args() ->
[{muc, true},
{prefs_module, mod_mam_mnesia_prefs},
{writer_module, mod_mam_odbc_arch},
{archive_module, mod_mam_odbc_arch}].
init_state(_, rsm, Config) ->
send_rsm_messages(clean_archives(Config));
init_state(_, _, Config) ->
clean_archives(Config).
end_state(_, _, Config) ->
Config.
init_per_testcase(C=archived, Config) ->
escalus:init_per_testcase(C, clean_archives(Config));
init_per_testcase(C=strip_archived, Config) ->
escalus:init_per_testcase(C, clean_archives(Config));
init_per_testcase(C=purge_single_message, Config) ->
escalus:init_per_testcase(C, clean_archives(Config));
init_per_testcase(C=purge_multiple_messages, Config) ->
escalus:init_per_testcase(C, clean_archives(Config));
init_per_testcase(C=purge_old_single_message, Config) ->
escalus:init_per_testcase(C,
bootstrap_archive(clean_archives(Config)));
init_per_testcase(C=muc_archive_request, Config) ->
escalus:init_per_testcase(C, start_alice_room(Config));
init_per_testcase(C=muc_private_message, Config) ->
escalus:init_per_testcase(C, start_alice_room(Config));
init_per_testcase(CaseName, Config) ->
escalus:init_per_testcase(CaseName, Config).
end_per_testcase(C=muc_archive_request, Config) ->
destroy_room(Config),
escalus:end_per_testcase(C, Config);
end_per_testcase(C=muc_private_message, Config) ->
destroy_room(Config),
escalus:end_per_testcase(C, Config);
end_per_testcase(CaseName, Config) ->
escalus:end_per_testcase(CaseName, Config).
init_module(Host, Mod, Args) ->
stop_module(Host, Mod),
ok = start_module(Host, Mod, Args).
is_loaded_module(Host, Mod) ->
rpc_apply(gen_mod, is_loaded, [Host, Mod]).
start_module(Host, Mod, Args) ->
rpc_apply(gen_mod, start_module, [Host, Mod, Args]).
stop_module(Host, Mod) ->
case is_loaded_module(Host, Mod) of
non_existing -> ok;
_ -> just_stop_module(Host, Mod)
end.
just_stop_module(Host, Mod) ->
{atomic, ok} = rpc_apply(gen_mod, stop_module, [Host, Mod]),
ok.
rpc_apply(M, F, Args) ->
case escalus_ejabberd:rpc(M, F, Args) of
{badrpc, Reason} ->
ct:fail("~p:~p/~p with arguments ~p fails with reason ~p.",
[M, F, length(Args), Args, Reason]);
Result ->
Result
end.
%%--------------------------------------------------------------------
%% Group name helpers
%%--------------------------------------------------------------------
full_group(Conf, Group) ->
list_to_atom(atom_to_list(Conf) ++ "_" ++ atom_to_list(Group)).
%% @doc Delete suffix.
configuration(Group) ->
match_atom_prefix(Group, make_greedy(configurations())).
%% @doc Rearrange a list of strings (or atoms), that all prefixes
%% will be tested.
%%
%% Example:
%% `make_greedy(odbc_mnesia_muc, [odbc, odbc_mnesia]) -> odbc'
%% `make_greedy(odbc_mnesia_muc, match_longer_first([odbc, odbc_mnesia])) -> odbc_mnesia'
%% @end
make_greedy(List) ->
lists:reverse(lists:usort(List)).
%% @doc Delete prefix.
basic_group(Group) ->
basic_group(Group, configuration(Group)).
basic_group(Group, Conf) ->
ConfS = atom_to_list(Conf),
GroupS = atom_to_list(Group),
list_to_atom(delete_delimiter(delete_prefix(ConfS, GroupS))).
match_atom_prefix(Target, Prefixes) ->
match_atom_prefix_1(atom_to_list(Target), Prefixes).
match_atom_prefix_1(TargetS, [PrefixA|Prefixes]) ->
PrefixS = atom_to_list(PrefixA),
case lists:prefix(PrefixS, TargetS) of
true -> PrefixA;
false -> match_atom_prefix_1(TargetS, Prefixes)
end.
delete_prefix([H|Prefix], [H|Target]) ->
delete_prefix(Prefix, Target);
delete_prefix([], Target) ->
Target.
delete_delimiter("_" ++ Tail) ->
Tail.
%%--------------------------------------------------------------------
%% Adhoc tests
%%--------------------------------------------------------------------
%% Querying the archive for messages
simple_archive_request(Config) ->
F = fun(Alice, Bob) ->
%% Alice sends "OH, HAI!" to Bob
%% {xmlel,<<"message">>,
%% [{<<"from">>,<<"alice@localhost/res1">>},
%% {<<"to">>,<<"bob@localhost/res1">>},
%% {<<"xml:lang">>,<<"en">>},
%% {<<"type">>,<<"chat">>}],
%% [{xmlel,<<"body">>,[],[{xmlcdata,<<"OH, HAI!">>}]}]}
escalus:send(Alice, escalus_stanza:chat_to(Bob, <<"OH, HAI!">>)),
escalus:send(Alice, stanza_archive_request(<<"q1">>)),
assert_respond_size(1, wait_archive_respond_iq_first(Alice)),
ok
end,
escalus:story(Config, [1, 1], F).
archived(Config) ->
F = fun(Alice, Bob) ->
%% Archive must be empty.
%% Alice sends "OH, HAI!" to Bob.
escalus:send(Alice, escalus_stanza:chat_to(Bob, <<"OH, HAI!">>)),
%% Bob receives a message.
Msg = escalus:wait_for_stanza(Bob),
try
Arc = exml_query:subelement(Msg, <<"archived">>),
%% JID of the archive (i.e. where the client would send queries to)
By = exml_query:attr(Arc, <<"by">>),
%% Attribute giving the message's UID within the archive.
Id = exml_query:attr(Arc, <<"id">>),
?assert_equal(By, escalus_client:short_jid(Bob)),
%% Bob calls archive.
escalus:send(Bob, stanza_archive_request(<<"q1">>)),
[_ArcIQ, ArcMsg] = assert_respond_size(1, wait_archive_respond_iq_first(Bob)),
#forwarded_message{result_id=ArcId} = parse_forwarded_message(ArcMsg),
?assert_equal(Id, ArcId),
ok
catch Class:Reason ->
Stacktrace = erlang:get_stacktrace(),
ct:pal("Msg ~p", [Msg]),
erlang:raise(Class, Reason, Stacktrace)
end
end,
escalus:story(Config, [1, 1], F).
strip_archived(Config) ->
F = fun(Alice, Bob) ->
%% Archive must be empty.
%% Alice sends "OH, HAI!" to Bob.
escalus:send(Alice,
append_subelem(escalus_stanza:chat_to(Bob, <<"OH, HAI!">>),
archived_elem(escalus_client:short_jid(Bob),
<<"fake-id">>))),
%% Bob receives a message.
Msg = escalus:wait_for_stanza(Bob),
Arc = exml_query:subelement(Msg, <<"archived">>),
%% JID of the archive (i.e. where the client would send queries to)
By = exml_query:attr(Arc, <<"by">>),
%% Attribute giving the message's UID within the archive.
Id = exml_query:attr(Arc, <<"id">>),
?assert_equal(escalus_client:short_jid(Bob), By),
try
%% Bob calls archive.
escalus:send(Bob, stanza_archive_request(<<"q1">>)),
[_ArcIQ, ArcMsg] = assert_respond_size(1, wait_archive_respond_iq_first(Bob)),
#forwarded_message{result_id=ArcId} = parse_forwarded_message(ArcMsg),
?assert_equal(ArcId, Id),
ok
catch Class:Reason ->
Stacktrace = erlang:get_stacktrace(),
ct:pal("Msg ~p", [Msg]),
erlang:raise(Class, Reason, Stacktrace)
end
end,
escalus:story(Config, [1, 1], F).
wait_archive_respond_iq_first(User) ->
%% rot1
[IQ|Messages] = lists:reverse(wait_archive_respond(User)),
[IQ|lists:reverse(Messages)].
wait_archive_respond(User) ->
S = escalus:wait_for_stanza(User, 5000),
case escalus_pred:is_iq_error(S) of
true ->
ct:pal("Stanza ~p", [S]),
ct:fail("Unexpected error IQ.", []);
false -> ok
end,
case escalus_pred:is_iq_result(S) of
true -> [S];
false -> [S|wait_archive_respond(User)]
end.
assert_respond_size(Size, Respond) when length(Respond) =:= (Size + 1) ->
Respond;
assert_respond_size(ExpectedSize, Respond) ->
RespondSize = length(Respond) - 1,
ct:fail("Respond size is ~p, ~p is expected.", [RespondSize, ExpectedSize]).
%% void()
%% To conserve resources, a server MAY place a reasonable limit on how many
%% stanzas may be pushed to a client in one request.
%% If a query returns a number of stanzas greater than this limit and
%% the client did not specify a limit using RSM then the server should
%% return a policy-violation error to the client.
policy_violation(Config) ->
F = fun(Alice, Bob) ->
%% Alice sends messages to Bob.
%% WARNING: are we sending too fast?
[escalus:send(Alice,
escalus_stanza:chat_to(Bob, generate_message_text(N)))
|| N <- lists:seq(1, 51)],
%% Bob is waiting for 51 messages for 5 seconds.
escalus:wait_for_stanzas(Bob, 51, 5000),
%% Get whole history (queryid is "will_fail", id is random).
escalus:send(Alice, stanza_archive_request(<<"will_fail">>)),
ErrorIQ = escalus:wait_for_stanza(Alice, 5000),
try
#error_iq{condition = Condition} = parse_error_iq(ErrorIQ),
?assert_equal(<<"policy-violation">>, Condition),
ok
catch Class:Reason ->
Stacktrace = erlang:get_stacktrace(),
ct:pal("ErrorIQ ~p", [ErrorIQ]),
erlang:raise(Class, Reason, Stacktrace)
end
end,
escalus:story(Config, [1, 1], F).
offline_message(Config) ->
Msg = <<"Is there anybody here?">>,
F1 = fun(Alice) ->
%% Alice sends a message to Bob while bob is offline.
escalus:send(Alice,
escalus_stanza:chat_to(bob, Msg)),
ok
end,
escalus:story(Config, [1], F1),
F2 = fun(Bob) ->
%% Bob logins and checks the archive.
escalus:send(Bob, stanza_archive_request(<<"q1">>)),
[_ArcRes, ArcMsg] = wait_archive_respond_iq_first(Bob),
#forwarded_message{message_body=ArcMsgBody} =
parse_forwarded_message(ArcMsg),
?assert_equal(Msg, ArcMsgBody),
ok
end,
escalus:story(Config, [{bob, 1}], F2).
purge_single_message(Config) ->
F = fun(Alice, Bob) ->
escalus:send(Alice, escalus_stanza:chat_to(Bob, <<"OH, HAI!">>)),
escalus:send(Alice, stanza_archive_request(<<"q1">>)),
[_IQ, Mess] = assert_respond_size(1, wait_archive_respond_iq_first(Alice)),
ParsedMess = parse_forwarded_message(Mess),
#forwarded_message{result_id=MessId} = ParsedMess,
escalus:send(Alice, stanza_purge_single_message(MessId)),
%% Waiting for ack.
escalus:assert(is_iq_result, escalus:wait_for_stanza(Alice)),
escalus:send(Alice, stanza_archive_request(<<"q2">>)),
assert_respond_size(0, wait_archive_respond_iq_first(Alice)),
ok
end,
escalus:story(Config, [1, 1], F).
purge_old_single_message(Config) ->
F = fun(Alice) ->
escalus:send(Alice, stanza_archive_request(<<"q1">>)),
[_IQ|AllMessages] = assert_respond_size(12,
wait_archive_respond_iq_first(Alice)),
ParsedMessages = [parse_forwarded_message(M) || M <- AllMessages],
%% Delete fifth message.
ParsedMess = lists:nth(5, ParsedMessages),
#forwarded_message{result_id=MessId} = ParsedMess,
escalus:send(Alice, stanza_purge_single_message(MessId)),
%% Waiting for ack.
escalus:assert(is_iq_result, escalus:wait_for_stanza(Alice)),
%% Check, that it was deleted.
escalus:send(Alice, stanza_archive_request(<<"q2">>)),
assert_respond_size(11, wait_archive_respond_iq_first(Alice)),
ok
end,
escalus:story(Config, [1], F).
purge_multiple_messages(Config) ->
F = fun(Alice, Bob) ->
%% Alice sends messages to Bob.
[begin
escalus:send(Alice,
escalus_stanza:chat_to(Bob, generate_message_text(N))),
timer:sleep(100)
end || N <- lists:seq(1, 15)],
%% Bob is waiting for 15 messages for 5 seconds.
escalus:wait_for_stanzas(Bob, 15, 5000),
%% Bob purges all messages from his archive.
escalus:send(Bob, stanza_purge_multiple_messages(
undefined, undefined, undefined)),
%% Waiting for ack.
escalus:assert(is_iq_result, escalus:wait_for_stanza(Bob)),
escalus:send(Bob, stanza_archive_request(<<"q2">>)),
assert_respond_size(0, wait_archive_respond_iq_first(Bob)),
ok
end,
escalus:story(Config, [1, 1], F).
muc_archive_request(Config) ->
F = fun(Alice, Bob) ->
Room = ?config(room, Config),
RoomAddr = room_address(Room),
Text = <<"Hi, Bob!">>,
escalus:send(Alice, stanza_muc_enter_room(Room, nick(Alice))),
escalus:send(Bob, stanza_muc_enter_room(Room, nick(Bob))),
%% Bob received presences.
escalus:wait_for_stanzas(Bob, 2),
%% Bob received the room's subject.
escalus:wait_for_stanzas(Bob, 1),
%% Alice sends to the chat room.
escalus:send(Alice, escalus_stanza:groupchat_to(RoomAddr, Text)),
%% Bob received the message "Hi, Bob!".
%% This message will be archived (by alicesroom@localhost).
%% User's archive is disabled (i.e. bob@localhost).
BobMsg = escalus:wait_for_stanza(Bob),
escalus:assert(is_message, BobMsg),
Arc = exml_query:subelement(BobMsg, <<"archived">>),
%% JID of the archive (i.e. where the client would send queries to)
By = exml_query:attr(Arc, <<"by">>),
%% Attribute giving the message's UID within the archive.
Id = exml_query:attr(Arc, <<"id">>),
%% Bob requests the room's archive.
escalus:send(Bob, stanza_to_room(stanza_archive_request(<<"q1">>), Room)),
[_ArcRes, ArcMsg] = assert_respond_size(1, wait_archive_respond_iq_first(Bob)),
#forwarded_message{result_id=ArcId, message_body=ArcMsgBody} =
parse_forwarded_message(ArcMsg),
?assert_equal(Text, ArcMsgBody),
?assert_equal(ArcId, Id),
?assert_equal(RoomAddr, By),
ok
end,
escalus:story(Config, [1, 1], F).
muc_private_message(Config) ->
F = fun(Alice, Bob) ->
Room = ?config(room, Config),
Text = <<"Hi, Bob!">>,
escalus:send(Alice, stanza_muc_enter_room(Room, nick(Alice))),
escalus:send(Bob, stanza_muc_enter_room(Room, nick(Bob))),
%% Bob received presences.
escalus:wait_for_stanzas(Bob, 2),
%% Bob received the room's subject.
escalus:wait_for_stanzas(Bob, 1),
%% Alice sends to Bob, using his occupant JID.
%% This message will not be put into room's history.
Msg = escalus_stanza:chat_to(room_address(Room, nick(Bob)), Text),
escalus:send(Alice, Msg),
%% Bob received the message "Hi, Bob!".
BobMsg = escalus:wait_for_stanza(Bob),
escalus:assert(is_message, BobMsg),
?assert_equal(undefined, exml_query:subelement(BobMsg, <<"archived">>)),
%% Bob requests the room's archive.
escalus:send(Bob, stanza_to_room(stanza_archive_request(<<"q1">>), Room)),
[_ArcRes] = assert_respond_size(0, wait_archive_respond_iq_first(Bob)),
ok
end,
escalus:story(Config, [1, 1], F).
%% @doc Querying the archive for all messages in a certain timespan.
range_archive_request(Config) ->
F = fun(Alice) ->
%% Send
%% <iq type='get'>
%% <query xmlns='urn:xmpp:mam:tmp'>
%% <start>2010-06-07T00:00:00Z</start>
%% <end>2010-07-07T13:23:54Z</end>
%% </query>
%% </iq>
escalus:send(Alice, stanza_date_range_archive_request()),
escalus:wait_for_stanza(Alice, 5000),
ok
end,
escalus:story(Config, [1], F).
%% @doc A query using Result Set Management.
%% See also `#rsm_in.max'.
limit_archive_request(Config) ->
F = fun(Alice) ->
%% Send
%% <iq type='get' id='q29302'>
%% <query xmlns='urn:xmpp:mam:tmp'>
%% <start>2010-08-07T00:00:00Z</start>
%% <set xmlns='http://jabber.org/protocol/rsm'>
%% <limit>10</limit>
%% </set>
%% </query>
%% </iq>
escalus:send(Alice, stanza_limit_archive_request()),
escalus:wait_for_stanza(Alice, 5000),
ok
end,
escalus:story(Config, [1], F).
pagination_empty_rset(Config) ->
F = fun(Alice) ->
%% Get the first page of size 5.
RSM = #rsm_in{max=0},
escalus:send(Alice, stanza_page_archive_request(<<"empty_rset">>, RSM)),
wait_empty_rset(Alice, 15)
end,
escalus:story(Config, [1], F).
pagination_first5(Config) ->
F = fun(Alice) ->
%% Get the first page of size 5.
RSM = #rsm_in{max=5},
escalus:send(Alice, stanza_page_archive_request(<<"first5">>, RSM)),
wait_message_range(Alice, 1, 5),
ok
end,
escalus:story(Config, [1], F).
pagination_last5(Config) ->
F = fun(Alice) ->
%% Get the last page of size 5.
RSM = #rsm_in{max=5, direction=before},
escalus:send(Alice, stanza_page_archive_request(<<"last5">>, RSM)),
wait_message_range(Alice, 11, 15),
ok
end,
escalus:story(Config, [1], F).
pagination_before10(Config) ->
F = fun(Alice) ->
%% Get the last page of size 5.
RSM = #rsm_in{max=5, direction=before, id=message_id(10, Config)},
escalus:send(Alice, stanza_page_archive_request(<<"before10">>, RSM)),
wait_message_range(Alice, 5, 9),
ok
end,
escalus:story(Config, [1], F).
pagination_after10(Config) ->
F = fun(Alice) ->
%% Get the last page of size 5.
RSM = #rsm_in{max=5, direction='after', id=message_id(10, Config)},
escalus:send(Alice, stanza_page_archive_request(<<"after10">>, RSM)),
wait_message_range(Alice, 11, 15),
ok
end,
escalus:story(Config, [1], F).
generate_message_text(N) when is_integer(N) ->
<<"Message #", (list_to_binary(integer_to_list(N)))/binary>>.
prefs_set_request(Config) ->
F = fun(Alice) ->
%% Send
%%
%% <iq type='set' id='juliet2'>
%% <prefs xmlns='urn:xmpp:mam:tmp' default="roster">
%% <always>
%% <jid>romeo@montague.net</jid>
%% </always>
%% <never>
%% <jid>montague@montague.net</jid>
%% </never>
%% </prefs>
%% </iq>
escalus:send(Alice, stanza_prefs_set_request(<<"roster">>,
[<<"romeo@montague.net">>],
[<<"montague@montague.net">>])),
ReplySet = escalus:wait_for_stanza(Alice),
escalus:send(Alice, stanza_prefs_get_request()),
ReplyGet = escalus:wait_for_stanza(Alice),
ResultIQ1 = parse_prefs_result_iq(ReplySet),
ResultIQ2 = parse_prefs_result_iq(ReplyGet),
?assert_equal(ResultIQ1, ResultIQ2),
ok
end,
escalus:story(Config, [1], F).
mam_service_discovery(Config) ->
F = fun(Alice) ->
Server = escalus_client:server(Alice),
escalus:send(Alice, escalus_stanza:disco_info(Server)),
Stanza = escalus:wait_for_stanza(Alice),
try
escalus:assert(is_iq_result, Stanza),
escalus:assert(has_feature, [mam_ns_binary()], Stanza),
ok
catch Class:Reason ->
Stacktrace = erlang:get_stacktrace(),
ct:pal("Stanza ~p.", [Stanza]),
erlang:raise(Class, Reason, Stacktrace)
end
end,
escalus:story(Config, [1], F).
%% Check, that MUC is supported.
muc_service_discovery(Config) ->
F = fun(Alice) ->
Domain = escalus_config:get_config(ejabberd_domain, Config),
Server = escalus_client:server(Alice),
escalus:send(Alice, escalus_stanza:service_discovery(Server)),
Stanza = escalus:wait_for_stanza(Alice),
%% If this fails, than check your config.
%% `{mod_disco, [{extra_domains, [<<"muc.localhost">>]}]}' must be there.
escalus:assert(has_service, [muc_host()], Stanza),
escalus:assert(is_stanza_from, [Domain], Stanza),
ok
end,
escalus:story(Config, [1], F).
%%--------------------------------------------------------------------
%% Helpers
%%--------------------------------------------------------------------
nick(User) -> escalus_utils:get_username(User).
mam_ns_binary() -> <<"urn:xmpp:mam:tmp">>.
muc_ns_binary() -> <<"http://jabber.org/protocol/muc">>.
stanza_purge_single_message(MessId) ->
escalus_stanza:iq(<<"set">>, [#xmlel{
name = <<"purge">>,
attrs = [{<<"xmlns">>,mam_ns_binary()}, {<<"id">>, MessId}]
}]).
stanza_purge_multiple_messages(BStart, BEnd, BWithJID) ->
escalus_stanza:iq(<<"set">>, [#xmlel{
name = <<"purge">>,
attrs = [{<<"xmlns">>,mam_ns_binary()}],
children = skip_undefined([
maybe_start_elem(BStart),
maybe_end_elem(BEnd),
maybe_with_elem(BWithJID)])
}]).
skip_undefined(Xs) ->
[X || X <- Xs, X =/= undefined].
maybe_attr(_, undefined) ->
[];
maybe_attr(K, V) ->
[{K, V}].
mam_ns_attr() ->
[{<<"xmlns">>,mam_ns_binary()}].
maybe_start_elem(undefined) ->
undefined;
maybe_start_elem(BStart) ->
#xmlel{
name = <<"start">>,
children = #xmlcdata{content = BStart}}.
maybe_end_elem(undefined) ->
undefined;
maybe_end_elem(BEnd) ->
#xmlel{
name = <<"end">>,
children = #xmlcdata{content = BEnd}}.
maybe_with_elem(undefined) ->
undefined;
maybe_with_elem(BWithJID) ->
#xmlel{
name = <<"with">>,
children = #xmlcdata{content = BWithJID}}.
%% An optional 'queryid' attribute allows the client to match results to
%% a certain query.
stanza_archive_request(QueryId) ->
stanza_lookup_messages_iq(QueryId,
undefined, undefined,
undefined, undefined).
stanza_date_range_archive_request() ->
stanza_lookup_messages_iq(undefined,
"2010-06-07T00:00:00Z", "2010-07-07T13:23:54Z",
undefined, undefined).
stanza_limit_archive_request() ->
stanza_lookup_messages_iq(undefined, "2010-08-07T00:00:00Z",
undefined, undefined, #rsm_in{max=10}).
stanza_page_archive_request(QueryId, RSM) ->
stanza_lookup_messages_iq(QueryId, undefined, undefined, undefined, RSM).
stanza_lookup_messages_iq(QueryId, BStart, BEnd, BWithJID, RSM) ->
escalus_stanza:iq(<<"get">>, [#xmlel{
name = <<"query">>,
attrs = mam_ns_attr() ++ maybe_attr(<<"queryid">>, QueryId),
children = skip_undefined([
maybe_start_elem(BStart),
maybe_end_elem(BEnd),
maybe_with_elem(BWithJID),
maybe_rsm_elem(RSM)])
}]).
maybe_rsm_elem(undefined) ->
undefined;
maybe_rsm_elem(#rsm_in{max=Max, direction=Direction, id=Id, index=Index}) ->
#xmlel{name = <<"set">>,
children = skip_undefined([
maybe_rsm_max(Max),
maybe_rsm_index(Index),
maybe_rsm_direction(Direction, Id)])}.
maybe_rsm_id(undefined) -> [];
maybe_rsm_id(Id) -> #xmlcdata{content = Id}.
maybe_rsm_direction(undefined, undefined) ->
undefined;
maybe_rsm_direction(Direction, Id) ->
#xmlel{
name = atom_to_binary(Direction, latin1),
children = maybe_rsm_id(Id)}.
maybe_rsm_index(undefined) ->
undefined;
maybe_rsm_index(Index) when is_integer(Index) ->
#xmlel{
name = <<"index">>,
children = #xmlcdata{content = integer_to_list(Index)}}.
maybe_rsm_max(undefined) ->
undefined;
maybe_rsm_max(Max) when is_integer(Max) ->
#xmlel{
name = <<"max">>,
children = #xmlcdata{content = integer_to_list(Max)}}.
%% ----------------------------------------------------------------------
%% PREFERENCE QUERIES
stanza_prefs_set_request(DefaultMode, AlwaysJIDs, NewerJIDs) ->
AlwaysEl = #xmlel{name = <<"always">>,
children = encode_jids(AlwaysJIDs)},
NewerEl = #xmlel{name = <<"never">>,
children = encode_jids(NewerJIDs)},
escalus_stanza:iq(<<"set">>, [#xmlel{
name = <<"prefs">>,
attrs = [{<<"xmlns">>,mam_ns_binary()}]
++ [{<<"default">>, DefaultMode} || is_def(DefaultMode)],
children = [AlwaysEl, NewerEl]
}]).
stanza_prefs_get_request() ->
escalus_stanza:iq(<<"get">>, [#xmlel{
name = <<"prefs">>,
attrs = [{<<"xmlns">>,mam_ns_binary()}]
}]).
encode_jids(JIDs) ->
[#xmlel{name = <<"jid">>,
children = [#xmlcdata{content = JID}]}
|| JID <- JIDs].
%% ----------------------------------------------------------------------
%% PARSING RESPONDS
parse_forwarded_message(#xmlel{name = <<"message">>,
attrs = Attrs, children = Children}) ->
M = #forwarded_message{
from = proplists:get_value(<<"from">>, Attrs),
to = proplists:get_value(<<"to">>, Attrs)},
lists:foldl(fun 'parse_children[message]'/2, M, Children).
'parse_children[message]'(#xmlel{name = <<"result">>,
attrs = Attrs,
children = Children}, M) ->
M1 = M#forwarded_message{
result_queryid = proplists:get_value(<<"queryid">>, Attrs),
result_id = proplists:get_value(<<"id">>, Attrs)},
lists:foldl(fun 'parse_children[message/result]'/2, M1, Children).
'parse_children[message/result]'(#xmlel{name = <<"forwarded">>,
children = Children}, M) ->
lists:foldl(fun 'parse_children[message/result/forwarded]'/2, M, Children).
'parse_children[message/result/forwarded]'(#xmlel{name = <<"delay">>,
attrs = Attrs}, M) ->
M#forwarded_message{
delay_from = proplists:get_value(<<"from">>, Attrs),
delay_stamp = proplists:get_value(<<"stamp">>, Attrs)};