-
-
Notifications
You must be signed in to change notification settings - Fork 181
/
tracer.ex
216 lines (174 loc) · 5.24 KB
/
tracer.ex
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
defmodule Ash.Tracer do
@moduledoc """
A behaviour for implementing tracing for an Ash application.
"""
@type span_type() ::
:action
| :changeset
| :query
| :flow
| :request_step
| :change
| :validation
| :preparation
| :custom_flow_step
| :custom
| :before_transaction
| :before_action
| :after_transaction
| :after_action
| {:custom, atom()}
@type metadata() :: %{
api: nil | module(),
resource: nil | module(),
actor: term(),
tenant: term(),
action: atom(),
authorize?: boolean()
}
@type t :: module
@callback start_span(span_type(), name :: String.t()) :: :ok
@callback stop_span() :: :ok
@callback get_span_context() :: term()
@callback set_span_context(term()) :: :ok
@callback set_error(Exception.t(), Keyword.t()) :: :ok
@callback trace_type?(atom) :: boolean()
@callback set_handled_error(Exception.t(), Keyword.t()) :: :ok
@doc """
Set metadata for the current span.
This may be called multiple times per span, and should ideally merge with previous metadata.
"""
@callback set_metadata(span_type(), metadata()) :: :ok
@callback set_error(Exception.t()) :: :ok
@optional_callbacks set_error: 2, set_error: 1, trace_type?: 1, set_handled_error: 2
defmacro span(type, name, tracer, block_opts \\ []) do
quote do
type = unquote(type)
name = unquote(name)
tracer = List.wrap(unquote(tracer))
tracer = Enum.filter(tracer, &Ash.Tracer.trace_type?(&1, type))
Ash.Tracer.start_span(tracer, type, name)
# no need to use try/rescue/after if no tracers
if Enum.empty?(tracer) do
unquote(block_opts[:do])
else
try do
unquote(block_opts[:do])
rescue
e ->
Ash.Tracer.set_error(tracer, e, stacktrace: __STACKTRACE__)
reraise e, __STACKTRACE__
after
Ash.Tracer.stop_span(tracer)
end
end
end
end
defmacro telemetry_span(name, metadata, opts) do
quote do
telemetry_name = unquote(name)
metadata = unquote(metadata)
start = System.monotonic_time()
compiling? = Code.can_await_module_compilation?()
unless compiling? do
:telemetry.execute(
telemetry_name ++ [:start],
%{system_time: System.system_time()},
metadata
)
end
try do
unquote(opts[:do])
after
duration = System.monotonic_time() - start
unless compiling? do
:telemetry.execute(
telemetry_name ++ [:stop],
%{system_time: System.system_time(), duration: duration},
metadata
)
end
end
end
end
def stop_span(nil), do: :ok
def stop_span(tracers) when is_list(tracers) do
Enum.each(tracers, &stop_span/1)
end
def stop_span(tracer) do
tracer.stop_span()
end
def trace_type?(tracer, type) do
if function_exported?(tracer, :trace_type?, 1) do
tracer.trace_type?(type)
else
true
end
end
def start_span(nil, _type, _name), do: :ok
def start_span(tracers, type, name) when is_list(tracers) do
Enum.each(tracers, &start_span(&1, type, name))
end
def start_span(tracer, type, name) do
tracer.start_span(type, name)
end
def set_handled_error(nil, _, _), do: :ok
def set_handled_error(tracers, error, opts) when is_list(tracers) do
Enum.each(tracers, &set_handled_error(&1, error, opts))
end
def set_handled_error(tracer, error, opts) do
if function_exported?(tracer, :set_handled_error, 2) do
tracer.set_handled_error(error, opts)
else
:ok
end
end
def set_error(nil, _, _), do: :ok
def set_error(tracers, error, opts) when is_list(tracers) do
Enum.each(tracers, &set_error(&1, error, opts))
end
def set_error(tracer, error, opts) do
if function_exported?(tracer, :set_error, 2) do
tracer.set_error(error, opts)
else
tracer.set_error(error)
end
end
def set_error(nil, _), do: :ok
def set_error(tracers, error) when is_list(tracers) do
Enum.each(tracers, &set_error(&1, error))
end
def set_error(tracer, error) do
if function_exported?(tracer, :set_error, 2) do
tracer.set_error(error, [])
else
tracer.set_error(error)
end
end
def get_span_context(nil), do: :ok
def get_span_context(tracer) when is_list(tracer) do
raise ArgumentError, "Cannot get span context from multiple tracers"
end
def get_span_context(tracer) do
tracer.get_span_context()
end
def set_span_context(nil, _), do: :ok
def set_span_context(tracer, _context) when is_list(tracer) do
raise ArgumentError, "Cannot set span context from multiple tracers"
end
def set_span_context(tracer, context) do
tracer.set_span_context(context)
end
def set_metadata(nil, _type, _metadata), do: :ok
def set_metadata(tracers, type, metadata) when is_list(tracers) do
Enum.each(tracers, &set_metadata(&1, type, metadata))
end
def set_metadata(tracer, type, metadata) do
tracer.set_metadata(type, metadata)
end
defmacro __using__(_) do
quote do
@behaviour Ash.Tracer
end
end
end