generated from bazel-contrib/rules-template
-
-
Notifications
You must be signed in to change notification settings - Fork 27
/
esbuild.bzl
380 lines (332 loc) · 13.8 KB
/
esbuild.bzl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
"esbuild rule"
load("@aspect_bazel_lib//lib:expand_make_vars.bzl", "expand_variables")
load("@aspect_bazel_lib//lib:copy_to_bin.bzl", "copy_file_to_bin_action", "copy_files_to_bin_actions")
load("@aspect_rules_js//js:libs.bzl", "js_lib_helpers")
load("@aspect_rules_js//js:providers.bzl", "JsInfo", "js_info")
load(":helpers.bzl", "desugar_entry_point_names", "filter_files", "write_args_file")
_ATTRS = {
"args_file": attr.label(
allow_single_file = True,
mandatory = False,
doc = "Internal use only",
),
"define": attr.string_dict(
default = {},
doc = """A dict of global identifier replacements. Values are subject to $(location ...) expansion.
Example:
```python
esbuild(
name = "bundle",
define = {
"process.env.NODE_ENV": "production"
},
)
```
See https://esbuild.github.io/api/#define for more details
""",
),
"deps": attr.label_list(
default = [],
doc = "A list of direct dependencies that are required to build the bundle",
providers = [JsInfo],
),
"data": js_lib_helpers.JS_LIBRARY_DATA_ATTR,
"entry_point": attr.label(
allow_single_file = True,
doc = """The bundle's entry point (e.g. your main.js or app.js or index.js)
This is a shortcut for the `entry_points` attribute with a single entry.
Specify either this attribute or `entry_point`, but not both.
""",
),
"entry_points": attr.label_list(
allow_files = True,
doc = """The bundle's entry points (e.g. your main.js or app.js or index.js)
Specify either this attribute or `entry_point`, but not both.
""",
),
"external": attr.string_list(
default = [],
doc = """A list of module names that are treated as external and not included in the resulting bundle
See https://esbuild.github.io/api/#external for more details
""",
),
"format": attr.string(
values = ["iife", "cjs", "esm", ""],
mandatory = False,
doc = """The output format of the bundle, defaults to iife when platform is browser
and cjs when platform is node. If performing code splitting or multiple entry_points are specified, defaults to esm.
See https://esbuild.github.io/api/#format for more details
""",
),
"launcher": attr.label(
executable = True,
doc = "Override the default esbuild wrapper, which is supplied by the esbuild toolchain",
cfg = "exec",
),
"max_threads": attr.int(
mandatory = False,
doc = """Sets the `GOMAXPROCS` variable to limit the number of threads that esbuild can run with.
This can be useful if running many esbuild rule invocations in parallel, which has the potential to cause slowdown.
For general use, leave this attribute unset.
""",
),
"metafile": attr.bool(
default = False,
doc = "If true, esbuild creates a metafile along with the output",
mandatory = False,
),
"minify": attr.bool(
default = False,
doc = """Minifies the bundle with the built in minification.
Removes whitespace, shortens identifieres and uses equivalent but shorter syntax.
Sets all --minify-* flags
See https://esbuild.github.io/api/#minify for more details
""",
),
"output": attr.output(
mandatory = False,
doc = "Name of the output file when bundling",
),
"output_css": attr.output(
mandatory = False,
doc = """Declare a .css file will be output next to output bundle.
If your JS code contains import statements that import .css files, esbuild will place the
content in a file next to the main output file, which you'll need to declare. If your output
file is named 'foo.js', you should set this to 'foo.css'.""",
),
"output_dir": attr.bool(
default = False,
doc = """If true, esbuild produces an output directory containing all output files""",
),
"output_map": attr.output(
mandatory = False,
doc = "Name of the output source map when bundling",
),
"platform": attr.string(
default = "browser",
values = ["node", "browser", "neutral", ""],
doc = """The platform to bundle for.
See https://esbuild.github.io/api/#platform for more details
""",
),
"sourcemap": attr.string(
values = ["external", "inline", "both", ""],
mandatory = False,
doc = """Defines where sourcemaps are output and how they are included in the bundle. By default, a separate `.js.map` file is generated and referenced by the bundle. If `external`, a separate `.js.map` file is generated but not referenced by the bundle. If `inline`, a sourcemap is generated and its contents are inlined into the bundle (and no external sourcemap file is created). If `both`, a sourcemap is inlined and a `.js.map` file is created.
See https://esbuild.github.io/api/#sourcemap for more details
""",
),
"sources_content": attr.bool(
mandatory = False,
default = False,
doc = """If False, omits the `sourcesContent` field from generated source maps
See https://esbuild.github.io/api/#sources-content for more details
""",
),
"splitting": attr.bool(
default = False,
doc = """If true, esbuild produces an output directory containing all the output files from code splitting for multiple entry points
See https://esbuild.github.io/api/#splitting and https://esbuild.github.io/api/#entry-points for more details
""",
),
"srcs": attr.label_list(
allow_files = True,
default = [],
doc = """Source files to be made available to esbuild""",
),
"target": attr.string(
default = "es2015",
doc = """Environment target (e.g. es2017, chrome58, firefox57, safari11,
edge16, node10, esnext). Default es2015.
See https://esbuild.github.io/api/#target for more details
""",
),
"config": attr.label(
mandatory = False,
allow_single_file = True,
doc = """Configuration file used for esbuild. Note that options set in this file may get overwritten.
TODO: show how to write a config file that depends on plugins, similar to the esbuild_config macro in rules_nodejs.
""",
),
}
def _esbuild_impl(ctx):
node_toolinfo = ctx.toolchains["@rules_nodejs//nodejs:toolchain_type"].nodeinfo
esbuild_toolinfo = ctx.toolchains["@aspect_rules_esbuild//esbuild:toolchain_type"].esbuildinfo
entry_points = desugar_entry_point_names(ctx.file.entry_point, ctx.files.entry_points)
args = dict({
"bundle": True,
"define": dict([
[
k,
expand_variables(ctx, ctx.expand_location(v), attribute_name = "define"),
]
for k, v in ctx.attr.define.items()
]),
# the entry point files to bundle
"entryPoints": [entry_point.short_path for entry_point in entry_points],
"external": ctx.attr.external,
# by default the log level is "info" and includes an output file summary
# under bazel this is slightly redundant and may lead to spammy logs
# Also disable the log limit and show all logs
"logLevel": "warning",
"logLimit": 0,
"metafile": ctx.attr.metafile,
"platform": ctx.attr.platform,
# Don't preserve symlinks since doing so breaks node_modules resolution
# in the pnpm-style symlinked node_modules structure.
# See https://pnpm.io/symlinked-node-modules-structure.
# NB: esbuild will currently leave the sandbox and end up in the output
# tree until symlink guards are created to prevent this.
# See https://github.com/aspect-build/rules_esbuild/pull/32.
"preserveSymlinks": False,
"sourcesContent": ctx.attr.sources_content,
"target": ctx.attr.target,
})
if len(ctx.attr.sourcemap) > 0:
args.update({"sourcemap": ctx.attr.sourcemap})
else:
args.update({"sourcemap": True})
if ctx.attr.minify:
args.update({"minify": True})
else:
# by default, esbuild will tree-shake "pure" functions
# disable this unless also minifying
args.update({"ignoreAnnotations": True})
if ctx.attr.splitting:
if not ctx.attr.output_dir:
fail("output_dir must be set to True when splitting is set to True")
args.update({
"format": "esm",
"splitting": True,
})
output_sources = []
if ctx.attr.output_dir:
js_out = ctx.actions.declare_directory("%s" % ctx.attr.name)
output_sources.append(js_out)
# disable the log limit and show all logs
args.update({
"outdir": js_out.short_path,
})
else:
js_out = ctx.outputs.output
output_sources.append(js_out)
js_out_map = ctx.outputs.output_map
if ctx.attr.sourcemap != "inline":
if js_out_map == None:
fail("output_map must be specified if sourcemap is not set to 'inline'")
output_sources.append(js_out_map)
if ctx.outputs.output_css:
output_sources.append(ctx.outputs.output_css)
if ctx.attr.format:
args.update({"format": ctx.attr.format})
args.update({"outfile": js_out.short_path})
env = {
"BAZEL_BINDIR": ctx.bin_dir.path,
"ESBUILD_BINARY_PATH": "../../../" + esbuild_toolinfo.target_tool_path,
}
if ctx.attr.max_threads > 0:
env["GOMAXPROCS"] = str(ctx.attr.max_threads)
execution_requirements = {}
if "no-remote-exec" in ctx.attr.tags:
execution_requirements = {"no-remote-exec": "1"}
# setup the args passed to the launcher
launcher_args = ctx.actions.args()
other_inputs = []
args_file = write_args_file(ctx, args)
other_inputs.append(args_file)
launcher_args.add("--esbuild_args=%s" % args_file.short_path)
if ctx.attr.metafile:
# add metafile
meta_file = ctx.actions.declare_file("%s_metadata.json" % ctx.attr.name)
output_sources.append(meta_file)
launcher_args.add("--metafile=%s" % meta_file.short_path)
# add reference to the users args file, these are merged within the launcher
if ctx.attr.args_file:
other_inputs.append(ctx.file.args_file)
launcher_args.add("--user_args=%s" % ctx.file.args_file.short_path)
if ctx.attr.config:
other_inputs.append(copy_file_to_bin_action(ctx, ctx.file.config))
launcher_args.add("--config_file=%s" % ctx.file.config.short_path)
# stamp = ctx.attr.node_context_data[NodeContextInfo].stamp
# if stamp:
# inputs.append(ctx.info_file)
# env["BAZEL_INFO_FILE"] = ctx.info_file.path
# inputs.append(ctx.version_file)
# env["BAZEL_VERSION_FILE"] = ctx.version_file.path
input_sources = depset(
copy_files_to_bin_actions(ctx, [
file
for file in ctx.files.srcs + filter_files(entry_points)
if not (file.path.endswith(".d.ts") or file.path.endswith(".tsbuildinfo"))
]) + other_inputs + node_toolinfo.tool_files + esbuild_toolinfo.tool_files,
transitive = [js_lib_helpers.gather_files_from_js_providers(
targets = ctx.attr.srcs + ctx.attr.deps,
include_transitive_sources = True,
include_declarations = False,
include_npm_linked_packages = True,
)],
)
launcher = ctx.executable.launcher or esbuild_toolinfo.launcher.files_to_run
ctx.actions.run(
inputs = input_sources,
outputs = output_sources,
arguments = [launcher_args],
progress_message = "%s Javascript %s [esbuild]" % ("Bundling" if not ctx.attr.output_dir else "Splitting", " ".join([entry_point.short_path for entry_point in entry_points])),
execution_requirements = execution_requirements,
mnemonic = "esbuild",
env = env,
executable = launcher,
)
npm_linked_packages = js_lib_helpers.gather_npm_linked_packages(
srcs = ctx.attr.srcs,
deps = [],
)
npm_package_store_deps = js_lib_helpers.gather_npm_package_store_deps(
targets = ctx.attr.data,
)
output_sources_depset = depset(output_sources)
runfiles = js_lib_helpers.gather_runfiles(
ctx = ctx,
sources = output_sources_depset,
data = ctx.attr.data,
# Since we're bundling, we don't propogate any transitive runfiles from dependencies
deps = [],
)
return [
DefaultInfo(
files = output_sources_depset,
runfiles = runfiles,
),
js_info(
npm_linked_package_files = npm_linked_packages.direct_files,
npm_linked_packages = npm_linked_packages.direct,
npm_package_store_deps = npm_package_store_deps,
sources = output_sources_depset,
# Since we're bundling, we don't propogate linked npm packages from dependencies since
# they are bundled and the dependencies are dropped. If a subset of linked npm
# dependencies are not bundled it is up the the user to re-specify these in `data` if
# they are runtime dependencies to progagate to binary rules or `srcs` if they are to be
# propagated to downstream build targets.
transitive_npm_linked_package_files = npm_linked_packages.direct_files,
transitive_npm_linked_packages = npm_linked_packages.direct,
# Since we're bundling, we don't propogate any transitive sources from dependencies
transitive_sources = output_sources_depset,
),
]
lib = struct(
attrs = _ATTRS,
implementation = _esbuild_impl,
toolchains = [
"@rules_nodejs//nodejs:toolchain_type",
"@aspect_rules_esbuild//esbuild:toolchain_type",
],
)
esbuild_bundle = rule(
implementation = _esbuild_impl,
attrs = _ATTRS,
toolchains = lib.toolchains,
doc = """\
Runs the esbuild bundler under Bazel
For further information about esbuild, see https://esbuild.github.io/
""",
)