-
Notifications
You must be signed in to change notification settings - Fork 0
/
life.bf
270 lines (268 loc) · 16.5 KB
/
life.bf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
++++++++++++++++++++++++++++++++++++++++++++++++ 48
>,<[>-<-]>[>+>+<<-] считали первый символ; привели к числу и скопировали в две соседние ячейки
>>>>++++++++++ 10
[ умножаем на 10
<<<[<+>-]
>[<+>>+<-]
>[<+>-]
>-
]
<[-]<[-]<[-]<<++++++++++++++++++++++++++++++++++++++++++++++++>>,<<[>>-<<-]>>[<+>-]<[<+>-] в первой ячейке осталось введенно число; текущая ячейка вторая
,[-] любой символ разделитель
++++++++++++++++++++++++++++++++++++++++++++++++ 48
>,<[>-<-]>[>+>+<<-] считали первый символ; привели к числу и скопировали в две соседние ячейки
>>>>++++++++++ 10
[ умножаем на 10
<<<[<+>-]
>[<+>>+<-]
>[<+>-]
>-
]
<[-]<[-]<[-]<<++++++++++++++++++++++++++++++++++++++++++++++++>>,<<[>>-<<-]>>[<+>-]<[<+>-] во второй ячейке осталось введенное число; текущая ячейка третья
<[>>+>+<<<-]>>>[<<<+>>>-]<<< копируем ширину
<[>>+>>+<<<<-]>>>>[<<<<+>>>>-]<<<< копируем высоту
>>>[>>>+<<<-]<[>>>+<<<-]<[>>>+<<<-]<[>>>+<<<-]>>> сдвигаем блок с индексами вправо на три ячейки; текущая ячейка четвертая
>[-]<
><
[
>>>[>+<-]>[<+<<+>>>-]<<<< в каждой строке считываем w (ширина) ячеек
>[
<<<< сдвигаемся влево на четыре; чтобы прочитать символ
,---------- если это перевод строки; то считать следующий символ
>+<
[ не перевод строки
--------------------------------- вычитаем дальше для проверки на плюс
>[-]< сброс флага else
[>>+<<-] выход из цикла if
]
>[ перевод строки
,------------------------------------------- считали элемент матрицы; если значение плюс; то в ячейке есть клетка; иначе нет
[>+<-] выход из цикла else
]<
>>[<<+>>-]<<
>+< флаг else
[ нет клетки
>>[-]+++<< будущее значение ячейки = 3
>[-]< сброс флага else
[-] выход из цикла if
]
>[ есть клетка
>[-]+< будущее значение ячейки = 1
[-] выход из цикла else
]<
>>[<<+>>-]<< копируем в ячейку нужное значение
>>>> в этой строке надо прочитать на ячейку меньше
>>[>+<-]<[>+<-]<[>+<-]<[>+<-]>>- сдвиг блока вправо
]<- надо прочитать на строку меньше
] ввод закончен
++++++++++.[-] печатаем перевод строки для красоты
>>>[<<<+<<+>>>>>-]<[<<<+<<+>>>>>-]<<<<< скопировали высоту и ширину в ячейки $1/$3 и $2/$4 соответсвенно
>[-]<
[ переместиться в начало матрицы
>>>[>+<-]>[<+<<+>>>-]<<<< копируем; сколько ячеек в каждой строке
>[
<<[>>>>>>>>>>>>>>>+<<<<<<<<<<<<<<<-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-] сдвиг ячейки матрицы и блока
<<<<<<<<<<<<<- возвращаемся к счетчику
]<-
]
>>>>>>>>,[ ожидание ввода enter'а; текущая ячейка $9
---------- код enter'а = 10
<<[-]+>> флаг else
[ не enter
<<[-]>> не выполнять else
[-] выход из if
]
<<[ был enter; надо построить следующее поколение и вывести его
<<<<<< переходим в начало блока
!построение нового поколения
>>[>>+<<-]>>[<<+<<+>>>>-]<<<< копируем высоту матрицы
[
>>>[>+<-]>[<+<<+>>>-]<<<< копируем ширину таблицы
>[
>>>>>>>>>>>>[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-] с первой по четырнадцатую ячейки блока сдвинуты вправо; текущая ячейка первая
>>>>>>>>>>>>>>>[<<<<<<<<<<<<<<<+>>>>>>>>>>>>>>>-]<<<<<<<<<<<<<<< сдвинули ячейку; стоящую после блока данных
>>>[>>>>>>>>>>+<<<<<<<<<<-]>>>>>>>>>>[<+<<<<<<<<<+>>>>>>>>>>-]<<<<<<<<<<<<[>>>>>>>>>>>->+<<<<<<<<<<<<-]>>>>>>>>>>>>[<<<<<<<<<<<<+>>>>>>>>>>>>-]<<<<<<<<<<<<< записали в $12 разность
>>>>>>>[-]+>>>>>[ если $12 не ноль; то мы обрабатываем ячейку; находящуюся не на последней строке; текущая ячейка $12
<<<<<<<<<<<< возвращаемся к клетке $0
>>>>>>>[-]<<<<<<< обнуление флага else; возвращение в $0
>>>>>>>>>>>>[-]<<<<<<<<<<<< обнуление $12
нужно проверить; не на первой ли мы строке
>[>>>>>>>>>>>+>+<<<<<<<<<<<<-]>>>>>>+>>>>>->[<<<<<<<<<<<<+>>>>>>>>>>>>-]<<<<<<<<<<<<< скопировали в $12 номер строки минус 1; вернулись в $0
>>>>>>>>>>>>[ если в $12 не ноль; то мы не на последней строчке
<<<<<<<<<<<< возвращаемся в $0
>>>>[>>>>>>>>>+<<<<<<<<<-]>>>>>>>>[-]>[<+<<<<<<<<+>>>>>>>>>-]<<<<<<<<< << [>>>>>>>>>>>+<<<<<<<<<<<-]>>>>>>>>>>>[<-<<<<<<<<<<+>>>>>>>>>>>-]<<<<<<<<<<< << записываем в $12 разность ширины матрицы и индекса текущей ячейки в строке
>>>>>>>[-]+<<<<<<< записали флаг else
>>>>>>>>>>>>[ если в $12 не ноль; то мы не на левой крайней ячейке
<<<<<<<<<<<< возвращаемся в $0
>>>>>>>[-]+>>>>>[-]<<<<<<<<<<<< сбрасываем предыдущие значения; они будут нужны для другого условия
>>[>>>>>>>>>>>+<<<<<<<<<<<-]>>>>>>>>>>>[<+<<<<<<<<<<+>>>>>>>>>>>-]<<<<<<<<<<<<<
>>>>>>>>>>>>-[ если в $12 было больше единицы; то мы не в правой крайней ячейке
<<<<<<<<<<<< текущая ячейка $0
!обнуление счетчика живых соседей!
>>>>>>>[-]>[-]>[-]<<<<<<<<<
!средняя строка; не крайние ячейки; нужен обычный обход матрицы; текущая ячейка $0!
можно использовать ячейки $7 $9 $10 $11
в $3 и $4 высота и ширина соответственно
>>>>>>>[-]>>[-]>[-] >[-]< <<<<<<<<<<
>>>> [>>>>>+ >+< <<<<<-] >>>>>>[<<<<<<+>>>>>>-]<<<<<< <<<< скопировать ширину из $4 в $9
>>>>>>>>>[ вернуться на $9 клеток назад и посчитать живых соседей (верхних трех)
>+<- по окончании цикла значение $9 будет скопировано в $10; чтобы можно было вернуться к исходной ячейке
]<<<<<<<<<
>>>>>>>>>>[ возвращение к исходной ячейке
-
]<<<<<<<<<<
[-]+++
>>>>>>>>[-]>>>>[-] выход из if
]<<<<<<<<<<<<
>>>>>>>[ else; в $12 ноль; мы в правой крайней ячейке
<<<<<<<
!правая средняя ячейка матрицы; нужен особый обход матрицы!
[-]+ оживить клетку
>>>>>>>[-] выход из else
]<<<<<<<
>>>>>>>[-]<<<<<<< сбрасываем флаг else
>>>>>>>>>>>>[-] возвращаемся в $12; выходим из if
]<<<<<<<<<<<<
>>>>>>>[ else; в $12 ноль; крайняя левая ячейка
<<<<<<< возвращаемся в $0
!левая средняя ячейка; нужен особый обход матрицы!
[-]+ оживить клетку
>>>>>>>[-] выход из else
]<<<<<<<
>>>>>>>>>>>>[-]<<<<<<<<<<<<
>>>>>>>[-]<<<<<<< обнуляем флаг else
>>>>>>>>>>>>[-] выходим из if
]<<<<<<<<<<<<
>>>>>>>[ в $12 ноль; мы на последней строке
<<<<<<< возвращаемся в $0
>>>>[>>>>>>>>>+<<<<<<<<<-]>>>>>>>>[-]>[<+<<<<<<<<+>>>>>>>>>-]<<<<<<<<< << [>>>>>>>>>>>+<<<<<<<<<<<-]>>>>>>>>>>>[<-<<<<<<<<<<+>>>>>>>>>>>-]<<<<<<<<<<< << записываем в $12 разность ширины матрицы и индекса текущей ячейки в строке
>>>>>>>[-]+<<<<<<< записали флаг else
>>>>>>>>>>>>[ если в $12 не ноль; то мы не на левой крайней ячейке
<<<<<<<<<<<< возвращаемся в $0
>>>>>>>[-]+>>>>>[-]<<<<<<<<<<<< сбрасываем предыдущие значения; они будут нужны для другого условия
>>[>>>>>>>>>>>+<<<<<<<<<<<-]>>>>>>>>>>>[<+<<<<<<<<<<+>>>>>>>>>>>-]<<<<<<<<<<<<<
>>>>>>>>>>>>-[ если в $12 было больше единицы; то мы не в правой крайней ячейке
<<<<<<<<<<<<
!нижняя строка; не крайние ячейки; нужен особый обход матрицы!
[-]+ оживить клетку
>>>>>>>[-]<<<<<<< обнуление флага else
>>>>>>>>>>>>[-] выход из if
]<<<<<<<<<<<<
>>>>>>>[ else; в $12 ноль; мы в правой крайней ячейке
<<<<<<<
!правая нижняя ячейка матрицы; нужен особый обход матрицы!
[-]+++ убить клетку
>>>>>>>[-] выход из else
]<<<<<<<
>>>>>>>[-]<<<<<<< сбрасываем флаг else
>>>>>>>>>>>>[-] возвращаемся в $12; выходим из if
]<<<<<<<<<<<<
>>>>>>>[ else; в $12 ноль; крайняя левая ячейка
<<<<<<< возвращаемся в $0
!левая нижняя ячейка; нужен особый обход матрицы!
[-]+++ убить клeтку
>>>>>>>[-] выход из else
]<<<<<<<
>>>>>>>>>>>>[-]<<<<<<<<<<<<
>>>>>>>[-] выходим из else
]<<<<<<<
>>>>>>>[-]<<<<<<< обнуление флага else; возвращение в $0
>>>>>>>>>>>>[-] выход из if
]<<<<<<<<<<<< возвращаемся к $0
>>>>>>>[ $12 ноль; мы на первой строке; текущая ячейка $7
<<<<<<< возвращаемся к клетке $0
>>>>[>>>>>>>>>+<<<<<<<<<-]>>>>>>>>[-]>[<+<<<<<<<<+>>>>>>>>>-]<<<<<<<<< << [>>>>>>>>>>>+<<<<<<<<<<<-]>>>>>>>>>>>[<-<<<<<<<<<<+>>>>>>>>>>>-]<<<<<<<<<<< << записываем в $12 разность ширины матрицы и индекса текущей ячейки в строке
>>>>>>>[-]+<<<<<<< записали флаг else
>>>>>>>>>>>>[ если в $12 не ноль; то мы не на левой крайней ячейке
<<<<<<<<<<<< возвращаемся в $0
>>>>>>>[-]+>>>>>[-]<<<<<<<<<<<< сбрасываем предыдущие значения; они будут нужны для другого условия
>>[>>>>>>>>>>>+<<<<<<<<<<<-]>>>>>>>>>>>[<+<<<<<<<<<<+>>>>>>>>>>>-]<<<<<<<<<<<<<
>>>>>>>>>>>>-[ если в $12 было больше единицы; то мы не в правой крайней ячейке
<<<<<<<<<<<<
!верхняя строка; не крайние ячейки; нужен особый обход матрицы!
[-]+ оживить клeтку
>>>>>>>[-]<<<<<<< обнуление флага else
>>>>>>>>>>>>[-] выход из if
]<<<<<<<<<<<<
>>>>>>>[ else; в $12 ноль; мы в правой крайней ячейке
<<<<<<<
!правая верхнаяя ячейка матрицы; нужен особый обход матрицы!
[-]+++ убить клетку
>>>>>>>[-] выход из else
]<<<<<<<
>>>>>>>[-]<<<<<<< сбрасываем флаг else
>>>>>>>>>>>>[-] возвращаемся в $12; выходим из if
]<<<<<<<<<<<<
>>>>>>>[ else; в $12 ноль; крайняя левая ячейка
<<<<<<< возвращаемся в $0
!левая верхняя ячейка; нужен особый обход матрицы!
[-]+++ убить клетку
>>>>>>>[-] выход из else
]<<<<<<<
>>>>>>>>>>>>[-]<<<<<<<<<<<<
>>>>>>>[-] выход из else
]<<<<<<< возвращаемся к $0
>>-
]<-
]
!сдвинуть блок данных в начало; оживить оживших и убить умерших
>>[>>+<<-]>>[<<+<<+>>>>-]<<<< копируем высоту матрицы
[ возвращаемся к началу матрицы
>>>[>+<-]>[<+<<+>>>-]<<<< копируем; сколько ячеек в каждой строке
>[
<<[>>>>>>>>>>>>>>>+<<<<<<<<<<<<<<<-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-] сдвиг ячейки матрицы и блока
<<<<<<<<<<<<<- возвращаемся к счетчику
<< вернулись к значению; нужно проверить; если клетка изменяет свое состояние; надо изменить его
>>>>>>>>>>>>>>>> перешли к ячейке со значением
<<[-]<[-]>>>[<<+<+>>>-]<<<[>>>+<<<-]>>> скопировали в предыдущую ячейку
<< <+> переходим в ячейку с копией значения; флаг else перед ней
-[ было значение больше единицы
-[ if; значение было больше 2
-[ if; значение было 4
>>[-]+<<
<[-]>[-] выход из if и else
]
<[ else; значение было 3
- выход из else
]>
<[-]>[-] выход из if и else
]
<[ else; значение было 2
> >>[-]+++<< <[-] убиваем клетку; выходим из if
]>
<[-]>[-] выход из else и if
]
<[ else; значение равнялось единице; клетка не изменяется
-
]>
>>
<<<<<<<<<<<<<<<<
!оживить оживших; убить умерших!
>>
]<-
]
>>[>>+<<-]>>[<<+<<+>>>>-]<<<< копируем в ячейку $1 высоту
[ печать поколения
>>>[>+<-]>[<+<<+>>>-]<<<< копируем; сколько ячеек в каждой строке
>[
>>>>>>>>>>>>[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-]<[>+<-] с первой по четырнадцатую ячейки блока сдвинуты вправо; текущая ячейка первая
>>>>>>>>>>>>>>>[<<<<<<<<<<<<<<<+>>>>>>>>>>>>>>>-]<<<<<<<<<<<<<<< сдвинули ячейку; стоящую после блока данных
++++++++++++++++++++++++++++++++++++++++++.------------------------------------------ выводим текущую ячейку
>>-
]<-
>>>>>>>>[-]++++++++++.[-]<<<<<<<< печатаем перевод строки
] поколение выведено на экран; необходимо вернуть блок данных в начало; текущая ячейка первая
>>[>>+<<-]>>[<<+<<+>>>>-]<<<< копируем высоту матрицы
[ возвращаемся к началу матрицы
>>>[>+<-]>[<+<<+>>>-]<<<< копируем; сколько ячеек в каждой строке
>[
<<[>>>>>>>>>>>>>>>+<<<<<<<<<<<<<<<-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-]>[<+>-] сдвиг ячейки матрицы и блока
<<<<<<<<<<<<<- возвращаемся к счетчику
]<-
]
>>>>>> переходим к ячейке с флагом
>>,<< считываем следующий символ
[-] выход из else
]>>
]
[-]>[-]>[-]>[-]>[-]<<<<<++++++++++[>+++++++>++++++++++++>++++++++++>++++++++++++>+<<<<<-]>-.>.>+++++.>----.>. Exit