-
Notifications
You must be signed in to change notification settings - Fork 230
/
riak_kv_vnode.erl
2665 lines (2462 loc) · 103 KB
/
riak_kv_vnode.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%% -------------------------------------------------------------------
%%
%% riak_kv_vnode: VNode Implementation
%%
%% Copyright (c) 2007-2010 Basho Technologies, Inc. All Rights Reserved.
%%
%% This file is provided to you under the Apache License,
%% Version 2.0 (the "License"); you may not use this file
%% except in compliance with the License. You may obtain
%% a copy of the License at
%%
%% http://www.apache.org/licenses/LICENSE-2.0
%%
%% Unless required by applicable law or agreed to in writing,
%% software distributed under the License is distributed on an
%% "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
%% KIND, either express or implied. See the License for the
%% specific language governing permissions and limitations
%% under the License.
%%
%% -------------------------------------------------------------------
-module(riak_kv_vnode).
-behaviour(riak_core_vnode).
%% API
-export([test_vnode/1, put/7]).
-export([start_vnode/1,
start_vnodes/1,
get/3,
get/4,
del/3,
put/6,
local_get/2,
local_put/2,
local_put/3,
coord_put/6,
readrepair/6,
list_keys/4,
fold/3,
fold/4,
get_vclocks/2,
vnode_status/1,
ack_keys/1,
repair/1,
repair_status/1,
repair_filter/1,
hashtree_pid/1,
rehash/3,
refresh_index_data/4,
request_hashtree_pid/1,
request_hashtree_pid/2,
reformat_object/2,
stop_fold/1,
get_modstate/1]).
%% riak_core_vnode API
-export([init/1,
terminate/2,
handle_command/3,
handle_overload_command/3,
handle_coverage/4,
is_empty/1,
delete/1,
request_hash/1,
object_info/1,
nval_map/1,
handle_handoff_command/3,
handoff_starting/2,
handoff_started/2, %% Note: optional function of the behaviour
handoff_cancelled/1,
handoff_finished/2,
handle_handoff_data/2,
encode_handoff_item/2,
handle_exit/3,
handle_info/2,
handle_overload_info/2,
ready_to_exit/0]). %% Note: optional function of the behaviour
-export([handoff_data_encoding_method/0]).
-export([set_vnode_forwarding/2]).
-include_lib("riak_kv_vnode.hrl").
-include_lib("riak_kv_index.hrl").
-include_lib("riak_kv_map_phase.hrl").
-include_lib("riak_core_pb.hrl").
-include("riak_kv_types.hrl").
-ifdef(TEST).
-include_lib("eunit/include/eunit.hrl").
-include_lib("riak_core/include/riak_core_bg_manager.hrl").
-export([put_merge/6]). %% For fsm_eqc_vnode
-endif.
%% N.B. The ?INDEX macro should be called any time the object bytes on
%% disk are modified.
-ifdef(TEST).
%% Use values so that test compile doesn't give 'unused vars' warning.
-define(INDEX(A,B,C), _=element(1,{A,B,C}), ok).
-else.
-define(INDEX(Obj, Reason, Partition), yz_kv:index(Obj, Reason, Partition)).
-endif.
-ifdef(TEST).
-define(YZ_SHOULD_HANDOFF(X), true).
-else.
-define(YZ_SHOULD_HANDOFF(X), yz_kv:should_handoff(X)).
-endif.
-record(mrjob, {cachekey :: term(),
bkey :: term(),
reqid :: term(),
target :: pid()}).
-record(state, {idx :: partition(),
mod :: module(),
modstate :: term(),
mrjobs :: term(),
vnodeid :: undefined | binary(),
delete_mode :: keep | immediate | pos_integer(),
bucket_buf_size :: pos_integer(),
index_buf_size :: pos_integer(),
key_buf_size :: pos_integer(),
async_folding :: boolean(),
in_handoff = false :: boolean(),
handoff_target :: node(),
handoffs_rejected = 0 :: integer(),
forward :: node() | [{integer(), node()}],
hashtrees :: pid(),
md_cache :: ets:tab(),
md_cache_size :: pos_integer() }).
-type index_op() :: add | remove.
-type index_value() :: integer() | binary().
-type index() :: non_neg_integer().
-type state() :: #state{}.
-define(MD_CACHE_BASE, "riak_kv_vnode_md_cache").
-define(DEFAULT_HASHTREE_TOKENS, 90).
-record(putargs, {returnbody :: boolean(),
coord:: boolean(),
lww :: boolean(),
bkey :: {binary(), binary()},
robj :: term(),
index_specs=[] :: [{index_op(), binary(), index_value()}],
reqid :: non_neg_integer(),
bprops :: maybe_improper_list(),
starttime :: non_neg_integer(),
prunetime :: undefined| non_neg_integer(),
is_index=false :: boolean(), %% set if the b/end supports indexes
crdt_op = undefined :: undefined | term() %% if set this is a crdt operation
}).
-spec maybe_create_hashtrees(state()) -> state().
maybe_create_hashtrees(State) ->
maybe_create_hashtrees(riak_kv_entropy_manager:enabled(), State).
-spec maybe_create_hashtrees(boolean(), state()) -> state().
maybe_create_hashtrees(false, State) ->
State;
maybe_create_hashtrees(true, State=#state{idx=Index,
mod=Mod, modstate=ModState}) ->
%% Only maintain a hashtree if a primary vnode
{ok, Ring} = riak_core_ring_manager:get_my_ring(),
case riak_core_ring:vnode_type(Ring, Index) of
primary ->
{ok, ModCaps} = Mod:capabilities(ModState),
Empty = case is_empty(State) of
{true, _} -> true;
{false, _, _} -> false
end,
Opts = [use_2i || lists:member(indexes, ModCaps)]
++ [vnode_empty || Empty],
case riak_kv_index_hashtree:start(Index, self(), Opts) of
{ok, Trees} ->
monitor(process, Trees),
State#state{hashtrees=Trees};
Error ->
lager:info("riak_kv/~p: unable to start index_hashtree: ~p",
[Index, Error]),
erlang:send_after(1000, self(), retry_create_hashtree),
State#state{hashtrees=undefined}
end;
_ ->
State
end.
%% @doc Reveal the underlying module state for testing
-spec(get_modstate(state()) -> {atom(), state()}).
get_modstate(_State=#state{mod=Mod,
modstate=ModState}) ->
{Mod, ModState}.
%% API
start_vnode(I) ->
riak_core_vnode_master:get_vnode_pid(I, riak_kv_vnode).
start_vnodes(IdxList) ->
riak_core_vnode_master:get_vnode_pid(IdxList, riak_kv_vnode).
test_vnode(I) ->
riak_core_vnode:start_link(riak_kv_vnode, I, infinity).
get(Preflist, BKey, ReqId) ->
%% Assuming this function is called from a FSM process
%% so self() == FSM pid
get(Preflist, BKey, ReqId, {fsm, undefined, self()}).
get(Preflist, BKey, ReqId, Sender) ->
Req = ?KV_GET_REQ{bkey=sanitize_bkey(BKey),
req_id=ReqId},
riak_core_vnode_master:command(Preflist,
Req,
Sender,
riak_kv_vnode_master).
del(Preflist, BKey, ReqId) ->
riak_core_vnode_master:command(Preflist,
?KV_DELETE_REQ{bkey=sanitize_bkey(BKey),
req_id=ReqId},
riak_kv_vnode_master).
%% Issue a put for the object to the preflist, expecting a reply
%% to an FSM.
put(Preflist, BKey, Obj, ReqId, StartTime, Options) when is_integer(StartTime) ->
put(Preflist, BKey, Obj, ReqId, StartTime, Options, {fsm, undefined, self()}).
put(Preflist, BKey, Obj, ReqId, StartTime, Options, Sender)
when is_integer(StartTime) ->
riak_core_vnode_master:command(Preflist,
?KV_PUT_REQ{
bkey = sanitize_bkey(BKey),
object = Obj,
req_id = ReqId,
start_time = StartTime,
options = Options},
Sender,
riak_kv_vnode_master).
local_put(Index, Obj) ->
local_put(Index, Obj, []).
local_put(Index, Obj, Options) ->
BKey = {riak_object:bucket(Obj), riak_object:key(Obj)},
Ref = make_ref(),
ReqId = erlang:phash2(erlang:now()),
StartTime = riak_core_util:moment(),
Sender = {raw, Ref, self()},
put({Index, node()}, BKey, Obj, ReqId, StartTime, Options, Sender),
receive
{Ref, Reply} ->
Reply
end.
local_get(Index, BKey) ->
Ref = make_ref(),
ReqId = erlang:phash2(erlang:now()),
Sender = {raw, Ref, self()},
get({Index,node()}, BKey, ReqId, Sender),
receive
{Ref, {r, Result, Index, ReqId}} ->
Result;
{Ref, Reply} ->
{error, Reply}
end.
refresh_index_data(Partition, BKey, IdxData, TimeOut) ->
riak_core_vnode_master:sync_command({Partition, node()},
{refresh_index_data, BKey, IdxData},
riak_kv_vnode_master,
TimeOut).
%% Issue a put for the object to the preflist, expecting a reply
%% to an FSM.
coord_put(IndexNode, BKey, Obj, ReqId, StartTime, Options) when is_integer(StartTime) ->
coord_put(IndexNode, BKey, Obj, ReqId, StartTime, Options, {fsm, undefined, self()}).
coord_put(IndexNode, BKey, Obj, ReqId, StartTime, Options, Sender)
when is_integer(StartTime) ->
riak_core_vnode_master:command(IndexNode,
?KV_PUT_REQ{
bkey = sanitize_bkey(BKey),
object = Obj,
req_id = ReqId,
start_time = StartTime,
options = [coord | Options]},
Sender,
riak_kv_vnode_master).
%% Do a put without sending any replies
readrepair(Preflist, BKey, Obj, ReqId, StartTime, Options) ->
put(Preflist, BKey, Obj, ReqId, StartTime, [rr | Options], ignore).
list_keys(Preflist, ReqId, Caller, Bucket) ->
riak_core_vnode_master:command(Preflist,
#riak_kv_listkeys_req_v2{
bucket=Bucket,
req_id=ReqId,
caller=Caller},
ignore,
riak_kv_vnode_master).
fold(Preflist, Fun, Acc0) ->
Req = riak_core_util:make_fold_req(Fun, Acc0),
riak_core_vnode_master:sync_spawn_command(Preflist,
Req,
riak_kv_vnode_master).
fold(Preflist, Fun, Acc0, Options) ->
Req = riak_core_util:make_fold_req(Fun, Acc0, false, Options),
riak_core_vnode_master:sync_spawn_command(Preflist,
Req,
riak_kv_vnode_master).
get_vclocks(Preflist, BKeyList) ->
riak_core_vnode_master:sync_spawn_command(Preflist,
?KV_VCLOCK_REQ{bkeys=BKeyList},
riak_kv_vnode_master).
%% @doc Get status information about the node local vnodes.
vnode_status(PrefLists) ->
ReqId = erlang:phash2({self(), os:timestamp()}),
%% Get the status of each vnode
riak_core_vnode_master:command(PrefLists,
?KV_VNODE_STATUS_REQ{},
{raw, ReqId, self()},
riak_kv_vnode_master),
wait_for_vnode_status_results(PrefLists, ReqId, []).
%% @doc Repair the given `Partition'.
-spec repair(partition()) ->
{ok, Pairs::[{partition(), node()}]} |
{down, Down::[{partition(), node()}]}.
repair(Partition) ->
Service = riak_kv,
MP = {riak_kv_vnode, Partition},
FilterModFun = {?MODULE, repair_filter},
riak_core_vnode_manager:repair(Service, MP, FilterModFun).
%% @doc Get the status of the repair process for the given `Partition'.
-spec repair_status(partition()) -> not_found | in_progress.
repair_status(Partition) ->
riak_core_vnode_manager:repair_status({riak_kv_vnode, Partition}).
%% @doc Given a `Target' partition generate a `Filter' fun to use
%% during partition repair.
-spec repair_filter(partition()) -> Filter::function().
repair_filter(Target) ->
{ok, Ring} = riak_core_ring_manager:get_my_ring(),
riak_core_repair:gen_filter(Target,
Ring,
nval_map(Ring),
riak_core_bucket:default_object_nval(),
fun object_info/1).
-spec hashtree_pid(index()) -> {ok, pid()} | {error, wrong_node}.
hashtree_pid(Partition) ->
riak_core_vnode_master:sync_command({Partition, node()},
{hashtree_pid, node()},
riak_kv_vnode_master,
infinity).
%% Asynchronous version of {@link hashtree_pid/1} that sends a message back to
%% the calling process. Used by the {@link riak_kv_entropy_manager}.
-spec request_hashtree_pid(index()) -> ok.
request_hashtree_pid(Partition) ->
ReqId = {hashtree_pid, Partition},
request_hashtree_pid(Partition, {raw, ReqId, self()}).
%% Version of {@link request_hashtree_pid/1} that takes a sender argument,
%% which could be a raw process, fsm, gen_server, etc.
request_hashtree_pid(Partition, Sender) ->
riak_core_vnode_master:command({Partition, node()},
{hashtree_pid, node()},
Sender,
riak_kv_vnode_master).
%% Used by {@link riak_kv_exchange_fsm} to force a vnode to update the hashtree
%% for repaired keys. Typically, repairing keys will trigger read repair that
%% will update the AAE hash in the write path. However, if the AAE tree is
%% divergent from the KV data, it is possible that AAE will try to repair keys
%% that do not have divergent KV replicas. In that case, read repair is never
%% triggered. Always rehashing keys after any attempt at repair ensures that
%% AAE does not try to repair the same non-divergent keys over and over.
rehash(Preflist, Bucket, Key) ->
riak_core_vnode_master:command(Preflist,
{rehash, Bucket, Key},
ignore,
riak_kv_vnode_master).
-spec reformat_object(index(), {riak_object:bucket(), riak_object:key()}) ->
ok | {error, term()}.
reformat_object(Partition, BKey) ->
riak_core_vnode_master:sync_spawn_command({Partition, node()},
{reformat_object,
sanitize_bkey(BKey)},
riak_kv_vnode_master).
%% VNode callbacks
init([Index]) ->
Mod = app_helper:get_env(riak_kv, storage_backend),
Configuration = app_helper:get_env(riak_kv),
BucketBufSize = app_helper:get_env(riak_kv, bucket_buffer_size, 1000),
IndexBufSize = app_helper:get_env(riak_kv, index_buffer_size, 100),
KeyBufSize = app_helper:get_env(riak_kv, key_buffer_size, 100),
WorkerPoolSize = app_helper:get_env(riak_kv, worker_pool_size, 10),
{ok, VId} = get_vnodeid(Index),
DeleteMode = app_helper:get_env(riak_kv, delete_mode, 3000),
AsyncFolding = app_helper:get_env(riak_kv, async_folds, true) == true,
MDCacheSize = app_helper:get_env(riak_kv, vnode_md_cache_size),
MDCache =
case MDCacheSize of
N when is_integer(N),
N > 0 ->
lager:debug("Initializing metadata cache with size limit: ~p bytes",
[MDCacheSize]),
new_md_cache(VId);
_ ->
lager:debug("No metadata cache size defined, not starting"),
undefined
end,
case catch Mod:start(Index, Configuration) of
{ok, ModState} ->
%% Get the backend capabilities
State = #state{idx=Index,
async_folding=AsyncFolding,
mod=Mod,
modstate=ModState,
vnodeid=VId,
delete_mode=DeleteMode,
bucket_buf_size=BucketBufSize,
index_buf_size=IndexBufSize,
key_buf_size=KeyBufSize,
mrjobs=dict:new(),
md_cache=MDCache,
md_cache_size=MDCacheSize},
try_set_vnode_lock_limit(Index),
case AsyncFolding of
true ->
%% Create worker pool initialization tuple
FoldWorkerPool = {pool, riak_kv_worker, WorkerPoolSize, []},
State2 = maybe_create_hashtrees(State),
{ok, State2, [FoldWorkerPool]};
false ->
{ok, State}
end;
{error, Reason} ->
lager:error("Failed to start ~p backend for index ~p error: ~p",
[Mod, Index, Reason]),
riak:stop("backend module failed to start."),
{error, Reason};
{'EXIT', Reason1} ->
lager:error("Failed to start ~p backend for index ~p crash: ~p",
[Mod, Index, Reason1]),
riak:stop("backend module failed to start."),
{error, Reason1}
end.
handle_overload_command(?KV_PUT_REQ{}, Sender, Idx) ->
riak_core_vnode:reply(Sender, {fail, Idx, overload});
handle_overload_command(?KV_GET_REQ{req_id=ReqID}, Sender, Idx) ->
riak_core_vnode:reply(Sender, {r, {error, overload}, Idx, ReqID});
handle_overload_command(?KV_VNODE_STATUS_REQ{}, Sender, Idx) ->
riak_core_vnode:reply(Sender, {vnode_status, Idx, [{error, overload}]});
handle_overload_command(_, Sender, _) ->
riak_core_vnode:reply(Sender, {error, mailbox_overload}).
%% Handle all SC overload messages here
handle_overload_info({ensemble_ping, _From}, _Idx) ->
%% Don't respond to pings in overload
ok;
handle_overload_info({ensemble_get, _, From}, _Idx) ->
riak_kv_ensemble_backend:reply(From, {error, vnode_overload});
handle_overload_info({ensemble_put, _, _, From}, _Idx) ->
riak_kv_ensemble_backend:reply(From, {error, vnode_overload});
handle_overload_info({raw_forward_put, _, _, From}, _Idx) ->
riak_kv_ensemble_backend:reply(From, {error, vnode_overload});
handle_overload_info({raw_forward_get, _, From}, _Idx) ->
riak_kv_ensemble_backend:reply(From, {error, vnode_overload});
handle_overload_info(_, _) ->
ok.
handle_command(?KV_PUT_REQ{bkey=BKey,
object=Object,
req_id=ReqId,
start_time=StartTime,
options=Options},
Sender, State=#state{idx=Idx}) ->
StartTS = os:timestamp(),
riak_core_vnode:reply(Sender, {w, Idx, ReqId}),
{_Reply, UpdState} = do_put(Sender, BKey, Object, ReqId, StartTime, Options, State),
update_vnode_stats(vnode_put, Idx, StartTS),
{noreply, UpdState};
handle_command(?KV_GET_REQ{bkey=BKey,req_id=ReqId},Sender,State) ->
do_get(Sender, BKey, ReqId, State);
handle_command(#riak_kv_listkeys_req_v2{bucket=Input, req_id=ReqId, caller=Caller}, _Sender,
State=#state{async_folding=AsyncFolding,
key_buf_size=BufferSize,
mod=Mod,
modstate=ModState,
idx=Idx}) ->
case Input of
{filter, Bucket, Filter} ->
ok;
Bucket ->
Filter = none
end,
BufferMod = riak_kv_fold_buffer,
case Bucket of
'_' ->
{ok, Capabilities} = Mod:capabilities(ModState),
AsyncBackend = lists:member(async_fold, Capabilities),
case AsyncFolding andalso AsyncBackend of
true ->
Opts = [async_fold];
false ->
Opts = []
end,
BufferFun =
fun(Results) ->
UniqueResults = lists:usort(Results),
Caller ! {ReqId, {kl, Idx, UniqueResults}}
end,
FoldFun = fold_fun(buckets, BufferMod, Filter, undefined),
ModFun = fold_buckets;
_ ->
{ok, Capabilities} = Mod:capabilities(Bucket, ModState),
AsyncBackend = lists:member(async_fold, Capabilities),
case AsyncFolding andalso AsyncBackend of
true ->
Opts = [async_fold, {bucket, Bucket}];
false ->
Opts = [{bucket, Bucket}]
end,
BufferFun =
fun(Results) ->
Caller ! {ReqId, {kl, Idx, Results}}
end,
Extras = fold_extras_keys(Idx, Bucket),
FoldFun = fold_fun(keys, BufferMod, Filter, Extras),
ModFun = fold_keys
end,
Buffer = BufferMod:new(BufferSize, BufferFun),
FinishFun =
fun(Buffer1) ->
riak_kv_fold_buffer:flush(Buffer1),
Caller ! {ReqId, Idx, done}
end,
case list(FoldFun, FinishFun, Mod, ModFun, ModState, Opts, Buffer) of
{async, AsyncWork} ->
{async, {fold, AsyncWork, FinishFun}, Caller, State};
_ ->
{noreply, State}
end;
handle_command(?KV_DELETE_REQ{bkey=BKey}, _Sender, State) ->
do_delete(BKey, State);
handle_command(?KV_VCLOCK_REQ{bkeys=BKeys}, _Sender, State) ->
{reply, do_get_vclocks(BKeys, State), State};
handle_command(#riak_core_fold_req_v1{} = ReqV1,
Sender, State) ->
%% Use make_fold_req() to upgrade to the most recent ?FOLD_REQ
handle_command(riak_core_util:make_newest_fold_req(ReqV1), Sender, State);
handle_command(?FOLD_REQ{foldfun=FoldFun, acc0=Acc0,
forwardable=_Forwardable, opts=Opts}, Sender, State) ->
%% The riak_core layer takes care of forwarding/not forwarding, so
%% we ignore forwardable here.
%%
%% The function in riak_core used for object folding expects the
%% bucket and key pair to be passed as the first parameter, but in
%% riak_kv the bucket and key have been separated. This function
%% wrapper is to address this mismatch.
FoldWrapper = fun(Bucket, Key, Value, Acc) ->
FoldFun({Bucket, Key}, Value, Acc)
end,
do_fold(FoldWrapper, Acc0, Sender, Opts, State);
%% entropy exchange commands
handle_command({hashtree_pid, Node}, _, State=#state{hashtrees=HT}) ->
%% Handle riak_core request forwarding during ownership handoff.
case node() of
Node ->
%% Following is necessary in cases where anti-entropy was enabled
%% after the vnode was already running
case HT of
undefined ->
State2 = maybe_create_hashtrees(State),
case State2#state.hashtrees of
undefined ->
{reply, {error, wrong_node}, State2};
_ ->
{reply, {ok, State2#state.hashtrees}, State2}
end;
_ ->
{reply, {ok, HT}, State}
end;
_ ->
{reply, {error, wrong_node}, State}
end;
handle_command({rehash, Bucket, Key}, _, State=#state{mod=Mod, modstate=ModState}) ->
case do_get_binary(Bucket, Key, Mod, ModState) of
{ok, Bin, _UpdModState} ->
update_hashtree(Bucket, Key, Bin, State);
_ ->
%% Make sure hashtree isn't tracking deleted data
delete_from_hashtree(Bucket, Key, State)
end,
{noreply, State};
handle_command({refresh_index_data, BKey, OldIdxData}, Sender,
State=#state{mod=Mod, modstate=ModState}) ->
{Bucket, Key} = BKey,
{ok, Caps} = Mod:capabilities(Bucket, ModState),
IndexCap = lists:member(indexes, Caps),
case IndexCap of
true ->
{Exists, RObj, IdxData, ModState2} =
case do_get_term(BKey, Mod, ModState) of
{{ok, ExistingObj}, UpModState} ->
{true, ExistingObj, riak_object:index_data(ExistingObj),
UpModState};
{{error, _}, UpModState} ->
{false, undefined, [], UpModState}
end,
IndexSpecs = riak_object:diff_index_data(OldIdxData, IdxData),
{Reply, ModState3} =
case Mod:put(Bucket, Key, IndexSpecs, undefined, ModState2) of
{ok, UpModState2} ->
ok = riak_kv_stat:update(vnode_index_refresh),
{ok, UpModState2};
{error, Reason, UpModState2} ->
{{error, Reason}, UpModState2}
end,
case Exists of
true ->
update_hashtree(Bucket, Key, RObj, State);
false ->
delete_from_hashtree(Bucket, Key, State)
end,
riak_core_vnode:reply(Sender, Reply),
{noreply, State#state{modstate=ModState3}};
false ->
{reply, {error, {indexes_not_supported, Mod}}, State}
end;
handle_command({fold_indexes, FoldIndexFun, Acc}, Sender, State=#state{mod=Mod, modstate=ModState}) ->
{ok, Caps} = Mod:capabilities(ModState),
case lists:member(indexes, Caps) of
true ->
{async, AsyncWork} = Mod:fold_indexes(FoldIndexFun, Acc, [async_fold], ModState),
FinishFun = fun(FinalAcc) ->
riak_core_vnode:reply(Sender, FinalAcc)
end,
{async, {fold, AsyncWork, FinishFun}, Sender, State};
false ->
{reply, {error, {indexes_not_supported, Mod}}, State}
end;
%% Commands originating from inside this vnode
handle_command({backend_callback, Ref, Msg}, _Sender,
State=#state{mod=Mod, modstate=ModState}) ->
Mod:callback(Ref, Msg, ModState),
{noreply, State};
handle_command({mapexec_error_noretry, JobId, Err}, _Sender, #state{mrjobs=Jobs}=State) ->
NewState = case dict:find(JobId, Jobs) of
{ok, Job} ->
Jobs1 = dict:erase(JobId, Jobs),
#mrjob{target=Target} = Job,
gen_fsm:send_event(Target, {mapexec_error_noretry, self(), Err}),
State#state{mrjobs=Jobs1};
error ->
State
end,
{noreply, NewState};
handle_command({mapexec_reply, JobId, Result}, _Sender, #state{mrjobs=Jobs}=State) ->
NewState = case dict:find(JobId, Jobs) of
{ok, Job} ->
Jobs1 = dict:erase(JobId, Jobs),
#mrjob{target=Target} = Job,
gen_fsm:send_event(Target, {mapexec_reply, Result, self()}),
State#state{mrjobs=Jobs1};
error ->
State
end,
{noreply, NewState};
handle_command(?KV_VNODE_STATUS_REQ{},
_Sender,
State=#state{idx=Index,
mod=Mod,
modstate=ModState,
vnodeid=VId}) ->
BackendStatus = {backend_status, Mod, Mod:status(ModState)},
VNodeStatus = [BackendStatus, {vnodeid, VId}],
{reply, {vnode_status, Index, VNodeStatus}, State};
handle_command({reformat_object, BKey}, _Sender, State) ->
{Reply, UpdState} = do_reformat(BKey, State),
{reply, Reply, UpdState};
handle_command({fix_incorrect_index_entry, {done, ForUpgrade}}, _Sender,
State=#state{mod=Mod, modstate=ModState}) ->
case Mod:mark_indexes_fixed(ModState, ForUpgrade) of %% only defined for eleveldb backend
{ok, NewModState} ->
{reply, ok, State#state{modstate=NewModState}};
{error, _Reason} ->
{reply, error, State}
end;
handle_command({fix_incorrect_index_entry, Keys, ForUpgrade},
_Sender,
State=#state{mod=Mod,
modstate=ModState}) ->
Reply =
case Mod:fix_index(Keys, ForUpgrade, ModState) of
{ok, _UpModState} ->
ok;
{ignore, _UpModState} ->
ignore;
{error, Reason, _UpModState} ->
{error, Reason};
{reply, Totals, _UpModState} ->
Totals
end,
{reply, Reply, State};
handle_command({get_index_entries, Opts},
Sender,
State=#state{mod=Mod,
modstate=ModState0}) ->
ForUpgrade = not proplists:get_value(downgrade, Opts, false),
BufferSize = proplists:get_value(batch_size, Opts, 1),
{ok, Caps} = Mod:capabilities(ModState0),
case lists:member(index_reformat, Caps) of
true ->
ModState = Mod:set_legacy_indexes(ModState0, not ForUpgrade),
Status = Mod:fixed_index_status(ModState),
case {ForUpgrade, Status} of
{true, true} -> {reply, done, State};
{_, _} ->
BufferMod = riak_kv_fold_buffer,
ResultFun =
fun(Results) ->
% Send result batch and wait for acknowledgement
% before moving on (backpressure to avoid flooding caller).
BatchRef = make_ref(),
riak_core_vnode:reply(Sender, {self(), BatchRef, Results}),
Monitor = riak_core_vnode:monitor(Sender),
receive
{ack_keys, BatchRef} ->
erlang:demonitor(Monitor, [flush]);
{'DOWN', Monitor, process, _Pid, _Reason} ->
throw(index_reformat_client_died)
end
end,
Buffer = BufferMod:new(BufferSize, ResultFun),
FoldFun = fun(B, K, Buf) -> BufferMod:add({B, K}, Buf) end,
FinishFun =
fun(FinalBuffer) ->
BufferMod:flush(FinalBuffer),
riak_core_vnode:reply(Sender, done)
end,
FoldOpts = [{index, incorrect_format, ForUpgrade}, async_fold],
case list(FoldFun, FinishFun, Mod, fold_keys, ModState, FoldOpts, Buffer) of
{async, AsyncWork} ->
{async, {fold, AsyncWork, FinishFun}, Sender, State};
_ ->
{noreply, State}
end
end;
false ->
lager:error("Backend ~p does not support incorrect index query", [Mod]),
{reply, ignore, State}
end.
%% @doc Handle a coverage request.
%% More information about the specification for the ItemFilter
%% parameter can be found in the documentation for the
%% {@link riak_kv_coverage_filter} module.
handle_coverage(?KV_LISTBUCKETS_REQ{item_filter=ItemFilter},
_FilterVNodes,
Sender,
State=#state{async_folding=AsyncFolding,
bucket_buf_size=BufferSize,
mod=Mod,
modstate=ModState}) ->
%% Construct the filter function
Filter = riak_kv_coverage_filter:build_filter(ItemFilter),
BufferMod = riak_kv_fold_buffer,
Buffer = BufferMod:new(BufferSize, result_fun(Sender)),
FoldFun = fold_fun(buckets, BufferMod, Filter, undefined),
FinishFun = finish_fun(BufferMod, Sender),
{ok, Capabilities} = Mod:capabilities(ModState),
AsyncBackend = lists:member(async_fold, Capabilities),
case AsyncFolding andalso AsyncBackend of
true ->
Opts = [async_fold];
false ->
Opts = []
end,
case list(FoldFun, FinishFun, Mod, fold_buckets, ModState, Opts, Buffer) of
{async, AsyncWork} ->
{async, {fold, AsyncWork, FinishFun}, Sender, State};
_ ->
{noreply, State}
end;
handle_coverage(#riak_kv_listkeys_req_v3{bucket=Bucket,
item_filter=ItemFilter},
FilterVNodes, Sender, State) ->
%% v3 == no backpressure
ResultFun = result_fun(Bucket, Sender),
Opts = [{bucket, Bucket}],
handle_coverage_keyfold(Bucket, ItemFilter, ResultFun,
FilterVNodes, Sender, Opts, State);
handle_coverage(?KV_LISTKEYS_REQ{bucket=Bucket,
item_filter=ItemFilter},
FilterVNodes, Sender, State) ->
%% v4 == ack-based backpressure
ResultFun = result_fun_ack(Bucket, Sender),
Opts = [{bucket, Bucket}],
handle_coverage_keyfold(Bucket, ItemFilter, ResultFun,
FilterVNodes, Sender, Opts, State);
handle_coverage(#riak_kv_index_req_v1{bucket=Bucket,
item_filter=ItemFilter,
qry=Query},
FilterVNodes, Sender, State) ->
%% v1 == no backpressure
handle_coverage_index(Bucket, ItemFilter, Query,
FilterVNodes, Sender, State, fun result_fun/2);
handle_coverage(?KV_INDEX_REQ{bucket=Bucket,
item_filter=ItemFilter,
qry=Query},
FilterVNodes, Sender, State) ->
%% v2 = ack-based backpressure
handle_coverage_index(Bucket, ItemFilter, Query,
FilterVNodes, Sender, State, fun result_fun_ack/2).
prepare_index_query(#riak_kv_index_v3{term_regex=RE} = Q) when
RE =/= undefined ->
{ok, CompiledRE} = re:compile(RE),
Q#riak_kv_index_v3{term_regex=CompiledRE};
prepare_index_query(Q) ->
Q.
%% @doc Batch size for results is set to 2i max_results if that is less
%% than the default size. Without this the vnode may send back to the FSM
%% more items than could ever be sent back to the client.
buffer_size_for_index_query(#riak_kv_index_v3{max_results=N}, DefaultSize)
when is_integer(N), N < DefaultSize ->
N;
buffer_size_for_index_query(_Q, DefaultSize) ->
DefaultSize.
handle_coverage_index(Bucket, ItemFilter, Query,
FilterVNodes, Sender,
State=#state{mod=Mod,
key_buf_size=DefaultBufSz,
modstate=ModState},
ResultFunFun) ->
{ok, Capabilities} = Mod:capabilities(Bucket, ModState),
IndexBackend = lists:member(indexes, Capabilities),
case IndexBackend of
true ->
%% Update stats...
ok = riak_kv_stat:update(vnode_index_read),
ResultFun = ResultFunFun(Bucket, Sender),
BufSize = buffer_size_for_index_query(Query, DefaultBufSz),
Opts = [{index, Bucket, prepare_index_query(Query)},
{bucket, Bucket}, {buffer_size, BufSize}],
%% @HACK
%% Really this should be decided in the backend
%% if there was a index_query fun.
FoldType = case riak_index:return_body(Query) of
true -> fold_objects;
false -> fold_keys
end,
handle_coverage_fold(FoldType, Bucket, ItemFilter, ResultFun,
FilterVNodes, Sender, Opts, State);
false ->
{reply, {error, {indexes_not_supported, Mod}}, State}
end.
%% Convenience for handling both v3 and v4 coverage-based key fold operations
handle_coverage_keyfold(Bucket, ItemFilter, Query,
FilterVNodes, Sender, State,
ResultFunFun) ->
handle_coverage_fold(fold_keys, Bucket, ItemFilter, Query,
FilterVNodes, Sender, State, ResultFunFun).
%% Until a bit of a refactor can occur to better abstract
%% index operations, allow the ModFun for folding to be declared
%% to support index operations that can return objects
handle_coverage_fold(FoldType, Bucket, ItemFilter, ResultFun,
FilterVNodes, Sender, Opts0,
State=#state{async_folding=AsyncFolding,
idx=Index,
key_buf_size=DefaultBufSz,
mod=Mod,
modstate=ModState}) ->
%% Construct the filter function
FilterVNode = proplists:get_value(Index, FilterVNodes),
Filter = riak_kv_coverage_filter:build_filter(Bucket, ItemFilter, FilterVNode),
BufferMod = riak_kv_fold_buffer,
BufferSize = proplists:get_value(buffer_size, Opts0, DefaultBufSz),
Buffer = BufferMod:new(BufferSize, ResultFun),
Extras = fold_extras_keys(Index, Bucket),
FoldFun = fold_fun(keys, BufferMod, Filter, Extras),
FinishFun = finish_fun(BufferMod, Sender),
{ok, Capabilities} = Mod:capabilities(Bucket, ModState),
AsyncBackend = lists:member(async_fold, Capabilities),
Opts = case AsyncFolding andalso AsyncBackend of
true ->
[async_fold | Opts0];
false ->
Opts0
end,
case list(FoldFun, FinishFun, Mod, FoldType, ModState, Opts, Buffer) of
{async, AsyncWork} ->
{async, {fold, AsyncWork, FinishFun}, Sender, State};
_ ->
{noreply, State}
end.
%% While in handoff, vnodes have the option of returning {forward,
%% State}, or indeed, {forward, Req, State} which will cause riak_core
%% to forward the request to the handoff target node. For riak_kv, we
%% issue a put locally as well as forward it in case the vnode has
%% already handed off the previous version. All other requests are
%% handled locally and not forwarded since the relevant data may not
%% have yet been handed off to the target node. Since we do not
%% forward deletes it is possible that we do not clear a tombstone
%% that was already handed off. This is benign as the tombstone will
%% eventually be re-deleted. NOTE: this makes write requests N+M where
%% M is the number of vnodes forwarding.
handle_handoff_command(Req=?KV_PUT_REQ{}, Sender, State) ->
?KV_PUT_REQ{options=Options} = Req,
case proplists:get_value(coord, Options, false) of
false ->
{noreply, NewState} = handle_command(Req, Sender, State),
{forward, NewState};
true ->
%% riak_kv#1046 - don't make fake siblings. Perform the
%% put, and create a new request to forward on, that
%% contains the frontier, much like the value returned to
%% a put fsm, then replicated.
#state{idx=Idx} = State,
?KV_PUT_REQ{bkey=BKey,
object=Object,
req_id=ReqId,
start_time=StartTime,
options=Options} = Req,
StartTS = os:timestamp(),
riak_core_vnode:reply(Sender, {w, Idx, ReqId}),
{Reply, UpdState} = do_put(Sender, BKey, Object, ReqId, StartTime, Options, State),
update_vnode_stats(vnode_put, Idx, StartTS),
case Reply of
%% NOTE: Coord is always `returnbody` as a put arg
{dw, Idx, NewObj, ReqId} ->
%% DO NOT coordinate again at the next owner!
NewReq = Req?KV_PUT_REQ{options=proplists:delete(coord, Options),
object=NewObj},
{forward, NewReq, UpdState};
_Error ->
%% Don't forward a failed attempt to put, as you
%% need the successful object
{noreply, UpdState}
end
end;
%% Handle all unspecified cases locally without forwarding
handle_handoff_command(Req, Sender, State) ->
handle_command(Req, Sender, State).
%% callback used by dynamic ring sizing to determine where
%% requests should be forwarded. Puts/deletes are forwarded
%% during the operation, all other requests are not
request_hash(?KV_PUT_REQ{bkey=BKey}) ->
riak_core_util:chash_key(BKey);
request_hash(?KV_DELETE_REQ{bkey=BKey}) ->
riak_core_util:chash_key(BKey);
request_hash(_Req) ->
undefined.
handoff_starting({_HOType, TargetNode}=_X, State=#state{handoffs_rejected=RejectCount}) ->
MaxRejects = app_helper:get_env(riak_kv, handoff_rejected_max, 6),
case MaxRejects =< RejectCount orelse ?YZ_SHOULD_HANDOFF(_X) of
true ->
{true, State#state{in_handoff=true, handoff_target=TargetNode}};
false ->
{false, State#state{in_handoff=false, handoff_target=undefined, handoffs_rejected=RejectCount + 1 }}
end.
%% @doc Optional callback that is exported, but not part of the behaviour.
handoff_started(SrcPartition, WorkerPid) ->
case maybe_get_vnode_lock(SrcPartition, WorkerPid) of
ok ->
FoldOpts = [{iterator_refresh, true}],
{ok, FoldOpts};
max_concurrency -> {error, max_concurrency}
end.