/
dizworld.s
2831 lines (2728 loc) · 68.5 KB
/
dizworld.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; dizworld Mode 7 demo
;
; Demonstrating 4 practical uses of Mode 7
; Select - Toggle aspect ratio correction
; A - Rotate background around a pivot point. (Suitable for bosses.)
; D-pad to scroll.
; L/R to scale.
; Start to pause the spin.
; B - Rotate around player. (Overhead level).
; D-pad to rotate or move.
; L/R to scale.
; X - Tilted view. (TODO)
; L/R to adjust tilt.
; D-pad to move.
; Y - Flying view. (TODO)
; D-pad to rotate or move.
; L/R to raise/lower.
; Start to toggle horizon glow.
;
; rainwarrior 2022
; http://rainwarrior.ca
.p816
.a8
.i8
;
; =============================================================================
; Header
;
.segment "HEADER"
.byte "DIZWORLD MODE 7 DEMO "
.byte $31 ; map mode (HiROM, FastROM)
.byte $00 ; cartridge type (ROM only)
.byte $08 ; 2mbit (256k)
.byte $00 ; RAM size
.byte $01 ; destination code (north america)
.byte $00 ; dev ID (not $33 to prevent indication of v3 header)
.byte $00 ; mask ROM version
.word $0000 ; checksum
.word $FFFF ; checksum complement
; native vectors
.assert (.loword(*)=$FFE0), error, "native vectors misplaced"
.word $FFFF
.word $FFFF
.word .loword(vector_irq) ; COP
.word .loword(vector_irq) ; BRK
.word .loword(vector_irq) ; ABORT
.word .loword(vector_nmi)
.word .loword(vector_reset)
.word .loword(vector_irq)
; emulation vectors
.assert (.loword(*)=$FFF0), error, "emulation vectors misplaced"
.word $FFFF
.word $FFFF
.word .loword(vector_irq) ; COP
.word .loword(vector_irq) ; BRK
.word .loword(vector_irq) ; ABORT
.word .loword(vector_nmi)
.word .loword(vector_reset)
.word .loword(vector_irq)
;
; =============================================================================
; RAM
;
.segment "ZEROPAGE" ; < $100
gamepad: .res 2
lastpad: .res 2
newpad: .res 2
nmi_ready: .res 1
nmi_count: .res 1
mode: .res 1
pause: .res 1 ; pauses animation
aspect: .res 1 ; 8:7 aspect correction
angle: .res 1 ; for spinning modes
scale: .res 2 ; for uniform scale
scale2: .res 4 ; for separate axis scale
posx: .res 6 ; position for some modes with subpixel precision
posy: .res 6
player_tile: .res 1 ; player sprite tile
cosa: .res 2 ; sincos result
sina: .res 2
math_a: .res 4 ; multiply/divide/math input terms 16 or 32-bit
math_b: .res 4
math_p: .res 8 ; product/quotient
math_r: .res 8 ; remainder
temp: .res 16
det_r: .res 4 ; storage for 1 / AD-BC (16.16f)
texelx: .res 2 ; input/result for coordinate transforms
texely: .res 2
screenx: .res 2
screeny: .res 2
nmi_bgmode: .res 1
nmi_hofs: .res 2
nmi_vofs: .res 2
nmi_m7t: .res 8
nmi_m7x: .res 2
nmi_m7y: .res 2
nmi_cgwsel: .res 1
nmi_cgadsub: .res 1
nmi_bg2hofs: .res 2
nmi_bg2vofs: .res 2
nmi_tm: .res 1
new_hdma_en: .res 1 ; HDMA channel enable at next update
nmi_hdma_en: .res 1 ; HDMA channel enable currently
oamp_i: .res 2 ; OAM printing
oamp_x: .res 1
oamp_y: .res 1
; perspective
; inputs
pv_buffer: .res 1 ; 0/1 selects double buffer
pv_l0: .res 1 ; first scanline
pv_l1: .res 1 ; last scanline + 1
pv_sh: .res 2 ; vertical texel distance from l0 to l1
pv_s0: .res 2 ; horizontal texel distance at l0
pv_s1: .res 2 ; horizontal texel distance at l1
; temporaries
pv_zr: .res 2 ; interpolated 1/Z
pv_zr_inc: .res 2 ; zr increment per line
pv_scale: .res 4 ; 8-bit scale of a/b/c/d
pv_negate: .res 1 ; negation of a/b/c/d
.segment "LORAM" ; <$2000
oam: .res 512+32
.segment "HIRAM" ; $FE bank < $8000
new_hdma: .res 16 * 8 ; HDMA channel settings to apply at next update
nmi_hdma: .res 16 * 8 ; HDMA channel settings current
; HDMA double-buffer for perspective
.align 256 ; (alignment not needed but is easier to debug)
pv_hdma_ab0: .res 1024 ; Mode 7 matrix AB
pv_hdma_cd0: .res 1024 ; Mode 7 matrix CD
pv_hdma_bgm0: .res 16 ; background mode
pv_hdma_tm0: .res 16 ; background enable
pv_hdma_abi0: .res 16 ; indirection for AB
pv_hdma_cdi0: .res 16 ; indirection for CD
pv_hdma_col0: .res 16 ; fixed colour for horizon fade (indirect)
.align 256 ; (not needed)
pv_hdma_ab1: .res 1024
pv_hdma_cd1: .res 1024
pv_hdma_bgm1: .res 16
pv_hdma_tm1: .res 16
pv_hdma_abi1: .res 16
pv_hdma_cdi1: .res 16
pv_hdma_col1: .res 16
PV_HDMA_STRIDE = pv_hdma_ab1 - pv_hdma_ab0
.segment "RODATA" ; for data needed by code
.import __RODATA_LOAD__
.import __RODATA_SIZE__
.assert (^__RODATA_LOAD__) = (^(__RODATA_LOAD__ + __RODATA_SIZE__)), error, "RODATA cannot cross a bank"
BANK_RODATA = ^__RODATA_LOAD__
;
; =============================================================================
; START stub for bank $00 dispatch
;
.segment "START"
vector_irq:
; not used
rti
vector_nmi:
jml nmi
vector_reset:
sei
clc
xce ; disable 6502 emulation
lda #0
phk ; K = 0
plb ; DB = 0
sta a:$004200 ; NMI off
jml reset
;
; =============================================================================
; MAIN segment: flat HiROM space for more code, bulk data, etc.
;
.segment "MAIN"
; if the assert happens, add some padding or an align to keep these from crossing a bank
.macro BANKCHECK label_
.assert (^(*-1))=(^(label_)), error, "BANKCHECK fail."
.endmacro
.align $10000
bin_vram: ; 64k block to initialize vram in one shot
; mode 7 block (nmt+chr interleaved), 32k at VRAM 0
md7_bg: .incbin "bg.md7"
; sprites, 16k aligned
.align $4000
chr_fg: .incbin "fg.chr"
; mode 1 sky chr, 4k aligned
.align $1000
chr_sky: .incbin "sky.chr"
; mode 1 sky nmt, 2k aligned
.align $800
nmt_sky: .incbin "sky.nmt"
BANKCHECK bin_vram
VRAM_CHR_FG = (chr_fg -bin_vram)>>1
VRAM_CHR_SKY = (chr_sky-bin_vram)>>1
VRAM_NMT_SKY = (nmt_sky-bin_vram)>>1
.align $10000 ; next bank
; palettes
pal_bg: .incbin "bg.pal"
pal_fg: .incbin "fg.pal"
BANKCHECK pal_bg
; for clearing
byte00: .byte $00
byteE0: .byte $E0
byteAA: .byte $AA
;
; =============================================================================
; LOPRG stuff for the first bank (mapped at $C00000)
;
; used for all code in this demo program
.segment "LOPRG"
;
; =============================================================================
; NMI
;
nmi:
; save registers
rep #$30
.a16
.i16
pha
phx
phy
phb
phd
sep #$30
.a8
.i8
lda #$00
pha
plb ; set data bank $00 for hardware access
lda z:nmi_ready ; no pending update
bne :+
jmp @exit
:
cmp #2 ; 2 = begin blanking
bne :+
lda #$8F
sta a:$2100 ; force blanking on
stz z:nmi_hdma_en ; disable HDMA
stz z:nmi_ready
jmp @exit
:
; update
; 1. copy new HDMA settings
rep #$30
.a16
.i16
phb
ldx #.loword(new_hdma)
ldy #.loword(nmi_hdma)
lda #(16*8)-1
mvn #^new_hdma,#^nmi_hdma
plb
sep #$20
.a8
lda z:new_hdma_en
sta z:nmi_hdma_en
; 2. apply other settings
lda z:nmi_bgmode
sta a:$2105 ; BGMODE
lda z:nmi_hofs+0
sta a:$210D ; BG1HOFS / M7HOFS
lda z:nmi_hofs+1
sta a:$210D
lda z:nmi_vofs+0
sta a:$210E ; BG1VOFS / M7VOFS
lda z:nmi_vofs+1
sta a:$210E
lda z:nmi_m7t+0
sta a:$211B ; M7A
lda z:nmi_m7t+1
sta a:$211B
lda z:nmi_m7t+2
sta a:$211C ; M7B
lda z:nmi_m7t+3
sta a:$211C
lda z:nmi_m7t+4
sta a:$211D ; M7C
lda z:nmi_m7t+5
sta a:$211D
lda z:nmi_m7t+6
sta a:$211E ; M7D
lda z:nmi_m7t+7
sta a:$211E
lda z:nmi_m7x+0
sta a:$211F ; M7E
lda z:nmi_m7x+1
sta a:$211F
lda z:nmi_m7y+0
sta a:$2120 ; M7F
lda z:nmi_m7y+1
sta a:$2120
lda z:nmi_cgwsel
sta a:$2130 ; CGWSEL
lda z:nmi_cgadsub
sta a:$2131 ; CGADSUB
lda z:nmi_bg2hofs+0
sta a:$210F ; BG2HOFS
lda z:nmi_bg2hofs+1
sta a:$210F
lda z:nmi_bg2vofs+0
sta a:$2110 ; BG2VOFS
lda z:nmi_bg2vofs+1
sta a:$2110
lda z:nmi_tm
sta a:$212C ; TM
; 3. OAM DMA
stz a:$2102
stz a:$2103
lda #%00000010 ; increment, 1-regiter (x2)
sta a:$4300
lda #$04 ; $2104
sta a:$4301
lda #<oam
sta a:$4302
lda #>oam
sta a:$4303
lda #^oam
sta a:$4304
lda #<(512+32)
sta a:$4305
lda #>(512+32)
sta a:$4306
lda #$01
sta a:$420B ; DMA
; force blanking off
lda #$0F
sta a:$2100
stz z:nmi_ready
; next field
@exit:
; copy HDMA settings and execute
rep #$30
.a16
.i16
phb
ldx #.loword(nmi_hdma)
ldy #$4300
lda #(16*8)-1
mvn #^nmi_hdma,#^004300
plb
sep #$20
.a8
lda z:nmi_hdma_en
sta a:$420C
; count frames
inc z:nmi_count
; restore registers
rep #$30
.a16
.i16
pld
plb
ply
plx
pla
rti
.a8
.i8
;
; =============================================================================
; Startup
;
reset:
rep #$30
.a16
.i16
ldx #$01FF
txs ; setup stack
jml :+ ; setup PC
:
lda #$0000
tcd ; set DP to zero page
; "standard" init
sep #$30
.a8
.i8
lda #$8f
sta a:$2100
stz a:$2101
stz a:$2102
stz a:$2103
stz a:$2105
stz a:$2106
stz a:$2107
stz a:$2108
stz a:$2109
stz a:$210A
stz a:$210B
stz a:$210C
stz a:$210D
stz a:$210D
stz a:$210E
stz a:$210E
stz a:$210F
stz a:$210F
stz a:$2110
stz a:$2110
stz a:$2111
stz a:$2111
stz a:$2112
stz a:$2112
stz a:$2113
stz a:$2113
stz a:$2114
stz a:$2114
lda #$80
sta a:$2115
stz a:$2116
stz a:$2117
stz a:$211A
stz a:$211B
lda #$01
sta a:$211B
stz a:$211C
stz a:$211C
stz a:$211D
stz a:$211D
stz a:$211E
lda #$01
sta a:$211E
stz a:$211F
stz a:$211F
stz a:$2120
stz a:$2120
stz a:$2121
stz a:$2123
stz a:$2124
stz a:$2125
stz a:$2126
stz a:$2127
stz a:$2128
stz a:$2129
stz a:$212A
stz a:$212B
stz a:$212C
stz a:$212D
stz a:$212E
stz a:$212F
lda #$30
sta a:$2130
stz a:$2131
lda #$E0
sta a:$2132
stz a:$2133
stz a:$4200
lda #$FF
sta a:$4201
stz a:$4202
stz a:$4203
stz a:$4204
stz a:$4205
stz a:$4206
stz a:$4207
stz a:$4208
stz a:$4209
stz a:$420A
stz a:$420B
stz a:$420C
;stz a:$420D ; SlowROM
lda #1
sta a:$420D ; FastROM
; clear RAM
lda #0
sta f:$7E0000 ; 0 byte to pattern-fill with MVN
sta f:$7F0000
rep #$30
.a16
.i16
phb
ldx #0
ldy #1
lda #$10000-2
mvn #$7E,#$7E
ldx #0
ldy #1
lda #$10000-2
mvn #$7F,#$7F
plb
sep #$30
.a8
.i8
; load vram
stz $2116 ; VMADD $0000
stz $2117
lda #%00000001 ; 2-register
sta a:$4300
lda #$18 ; $2118 VMDATA
sta a:$4301
lda #<bin_vram
sta a:$4302
lda #>bin_vram
sta a:$4303
lda #^bin_vram
sta a:$4304
stz a:$4305
stz a:$4306 ; 64k bytes
lda #$01
sta a:$420B ; DMA
; load palettes
stz a:$2121 ; CGADD $00
lda #%00000010 ; 1-register
sta a:$4300
lda #$22 ; $2122 CGDATA
sta a:$4301
lda #<pal_bg
sta a:$4302
lda #>pal_bg
sta a:$4303
lda #^pal_bg
sta a:$4304
stz a:$4305
lda #>256
sta a:$4306 ; 256 bytes
lda #$01
sta a:$420B ; DMA
lda #<pal_fg
sta a:$4302
lda #>pal_fg
sta a:$4303
lda #^pal_fg
sta a:$4304
stz a:$4305
lda #>256
sta a:$4306 ; 256 bytes
lda #$01
sta a:$420B ;DMA
; setup OAM
lda #$E0
sta a:oam+0
rep #$30
.a16
.i16
ldx #.loword(oam+0)
ldy #.loword(oam+1)
lda #(512-2)
mvn #^oam,#^oam ; fill with E0
sep #$30
.a8
.i8
lda #$AA
sta oam+512 ; first 4 sprites are 32x32
; setup PPU addresses
lda #((>VRAM_NMT_SKY) & $FC)
sta a:$2108 ; BG2SC nametable, 1-screen
lda #(VRAM_CHR_SKY >> 12) << 4
sta a:$210B ; BG12NBA
lda #((VRAM_CHR_FG >> 13) | $20)
sta a:$2101 ; OBJSEL 8x8 + 32x32 sprites
lda #$11
sta z:nmi_tm ; TM OBJ + BG1 main-screen
stz a:$212D ; TS empty sub-screen
; begin
jmp run
;
; =============================================================================
; main loop
;
run:
.a8
.i8
; enable NMI and auto-joypad
lda a:$4210 ; RDNMI
lda #$81
sta a:$4200 ; NMITIMEN
rep #$20
sep #$10
.a16
.i8
jsr oamp_start
jmp @set_mode_y
@loop:
; post a render update
jsr oamp_finish
ldx #1
stx z:nmi_ready
wai
:
ldx z:nmi_ready
bne :-
jsr oamp_start
; read controllers
lda z:gamepad
sta z:lastpad
; wait for auto-read to finish
:
lda a:$4212 ; HBVJOY (+RDIO)
and #1
bne :-
lda a:$4218 ; JOY1
sta z:gamepad
eor z:lastpad
and z:gamepad
sta z:newpad
; pausing
lda z:newpad
and #$1000 ; start
beq :+
lda z:pause
eor #1
tax
stx z:pause
:
; aspect ratio correction
lda z:newpad
and #$2000 ; select
beq :+
lda z:aspect
eor #1
tax
stx z:aspect
:
; switch mode
lda z:newpad
and #$0080 ; A
bne @set_mode_a
lda z:newpad
and #$8000 ; B
bne @set_mode_b
lda z:newpad
and #$0040 ; X
bne @set_mode_x
lda z:newpad
and #$4000 ; Y
bne @set_mode_y
; dispatch mode
ldx z:mode
beq @mode_a
cpx #1
beq @mode_b
cpx #2
beq @mode_x
cpx #3
beq @mode_y
; fallthrough?
ldx #0
stx z:mode
@mode_a:
jsr mode_a
jmp @loop
@mode_b:
jsr mode_b
jmp @loop
@mode_x:
jsr mode_x
jmp @loop
@mode_y:
jsr mode_y
jmp @loop
@set_mode_a:
ldx #0
stx z:mode
jsr set_mode_a
jmp @loop
@set_mode_b:
ldx #1
stx z:mode
jsr set_mode_b
jmp @loop
@set_mode_x:
ldx #2
stx z:mode
jsr set_mode_x
jmp @loop
@set_mode_y:
ldx #3
stx z:mode
jsr set_mode_y
jmp @loop
;
; =============================================================================
; OAM sprites
;
oam_sprite_clear: ; move 4 sprites offscreen
.i8
ldx #$E0
stx a:oam+1+( 0)
stx a:oam+1+( 4)
stx a:oam+1+( 8)
stx a:oam+1+(12)
rts
oam_sprite: ; A = tile, X = OAM start index (x4), screenx,screeny location
.a16
tay
lda z:screenx
sec
sbc #16
sta z:temp+0
lda z:screeny
sec
sbc #32
sta z:temp+2
php
sep #$20
.a8
tya
sta a:oam+2, X
lda z:screenx+1
bne @skip
lda z:screeny+1
bne @skip
lda z:screeny+0
cmp #$E0
bcs @skip
lda z:temp+0
sta a:oam+0, X
lda z:temp+2
sta a:oam+1, X
lda #$30 ; high priority, palette 0, no flip
sta a:oam+3, X
; transfer X high bit to high table
txa
lsr
lsr
pha
and #3
tax ; X = 0-3 shifts needed
pla
lsr
lsr
tay ; Y = high oam entry
lda a:oam+512, Y
and f:@hoam_mask, X
sta a:oam+512, Y
lda z:temp+1
and #1 ; high bit of adjusted x
ora #2 ; 32x32 sprite size
cpx #0
beq :++
:
asl
asl
dex
bne :-
:
ora a:oam+512, Y
sta a:oam+512, Y
plp
rts
@skip:
lda #$E0
sta oam+1, X
plp
rts
@hoam_mask:
.byte %11111100
.byte %11110011
.byte %11001111
.byte %00111111
;
; =============================================================================
; OAM printing
;
OAMP_X = 24 ; starting position for OAM printing
OAMP_Y = 168
OAMP_I = 4*4 ; skip first 4 sprites
oamp_start:
.a16
.i8
lda #OAMP_I
sta z:oamp_i
ldx #OAMP_X
stx z:oamp_x
ldx #OAMP_Y
stx z:oamp_y
rts
oamp_finish:
php
sep #$20
rep #$10
.a8
.i16
ldx z:oamp_i
lda #$E0
:
sta a:oam+1, X
inx
inx
inx
inx
cpx #512
bcc :-
plp
oamp_return: ; carriage return
.a16
.i8
ldx #OAMP_X
stx z:oamp_x
lda #0
ldx z:oamp_y
txa
clc
adc #8
tax
stx z:oamp_y
rts
oamp_char_:
.a8
.i16
ldx z:oamp_i
sta a:oam+2, X
lda z:oamp_y
sta a:oam+1, X
lda z:oamp_x
sta a:oam+0, X
clc
adc #8
sta z:oamp_x
lda #$30 ; priority 3
sta a:oam+3, X
inx
inx
inx
inx
stx z:oamp_i
rts
oamp_space: ; skips a space
.a16
.i8
ldx z:oamp_x
txa
clc
adc #8
tax
stx z:oamp_x
rts
oamp_alpha: ; A = ascii capital letter to print
php
sep #$20
rep #$10
.a8
.i16
clc
adc #$CA-'A'
jsr oamp_char_
plp
rts
oamp_alpha_space: ; alpha + space
jsr oamp_alpha
jmp oamp_space
oamp_hex8: ; A = value to print in hex
php
sep #$20
rep #$10
.a8
.i16
pha
lsr
lsr
lsr
lsr
ora #$C0
jsr oamp_char_
pla
and #$0F
ora #$C0
jsr oamp_char_
plp
rts
oamp_hex16: ; A = 16-bit value to print in hex
.a16
pha
xba
jsr oamp_hex8
pla
jmp oamp_hex8
oamp_hex16_space:
jsr oamp_hex16
jmp oamp_space
;
; =============================================================================
; Math
;
; summary of available subroutines:
; inputs: math_a, math_b, A register
; outputs: math_p, math_r, A register
; values are unsigned (u16), signed (s16), either (16) or fixed point (8.8)
; .a16 .i8 DB=0 assumed
;
; umul16: u16 a * u16 b = u32 p clobbers A/X/Y
; smul16: s16 a * s16 b = 32 p, clobbers A/X/Y
; mul16t: 16 a * 16 b = 16 A/p (truncated) clobbers A/X/Y
; smul16f: s8.8 a * s8.8 b = s8.8 A = s16.16 p clobbers A/X/Y
; smul32f_16f: s24.8 a * s8.8 b = s8.8 A = s8.24 p clobbers A/X/Y,a,b
; smul32ft: s24.8 a * s16.16 b = s8.8 A = s16.24 r clobbers A/X/Y,a,b,temp0-13
;
; udiv16: u16 a / u16 b = u16 p % u16 r clobbers A/X (DB any)
; udiv32: u32 a / u32 b = u32 p % u32 r clobbers A/X (DB any)
; recip16f: 1 / s8.8 A = s8.8 A = s16.16 p clobbers A/X,a,b (DB any)
;
; sign: A = value, returns either 0 or $FFFF preserves flags (.i8/.i16 allowed, DB any)
; sincos: A = angle 0-255, result in cosa/sina clobbers A/X (DB any)
; TODO time these routines and give estimates
; unsigned 16-bit multiply, 32-bit result
; Written by 93143: https://forums.nesdev.org/viewtopic.php?p=280089#p280089
umul16: ; math_a x math_b = math_p, clobbers A/X/Y
; DB = 0
.a16
.i8
ldx z:math_a+0
stx a:$4202
ldy z:math_b+0
sty a:$4203 ; a0 x b0 (A)
ldx z:math_b+1
stz z:math_p+2
lda a:$4216
stx a:$4203 ; a0 x b1 (B)
sta z:math_p+0 ; 00AA
ldx z:math_a+1
lda a:$4216
stx a:$4202
sty a:$4203 ; a1 x b0 (C)
clc
adc z:math_p+1 ; 00AA + 0BB0 (can't set carry because high byte was 0)
ldy z:math_b+1
adc a:$4216
sty a:$4203 ; a1 x b1 (D)
sta z:math_p+1 ; 00AA + 0BB0 + 0CC0
lda z:math_p+2
bcc :+
adc #$00FF ; if carry, increment top byte
:
adc a:$4216
sta z:math_p+2 ; 00AA + 0BB0 + 0CC0 + DD00
rts
; signed 16-bit multiply, 32-bit result, clobbers A/X/Y
smul16:
; DB = 0
.a16
.i8
jsr umul16
; A = math_p+2
; X = math_a+1
; Y = math_b+1
cpx #$80
bcc :+
;sec
sbc z:math_b ; sign extend math_a: (-1 << 16) x math_b
:
cpy #$80
bcc :+