-
Notifications
You must be signed in to change notification settings - Fork 0
/
Tidal5.scd
1319 lines (1197 loc) · 62.3 KB
/
Tidal5.scd
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program. If not, see <https://www.gnu.org/licenses/>.
// MIDI out startup
(
var server = server ? Server.default;
server.options.numBuffers = 1024 * 16; // increase this if you need to load more samples
server.options.memSize = 8192 * 64; // increase this if you get "alloc failed" messages
server.options.maxNodes = 1024 * 32; // increase this if you are getting drop outs and the message "too many nodes"
server.options.numInputBusChannels= 0; // to avoid issues of sample rate mismatch
// boot the server and start SuperDirt
server.waitForBoot {
~dirt = SuperDirt.start(path:"/Users/bgold/tidal/samples/*", numOrbits:4);
// MIDIClient.init; // uncomment this and the next line for MIDI output
// ~midiOut = MIDIOut.newByName("IAC Driver", "Bus 1");
}
)
~dirt.soundLibrary.addMIDI(\midi, ~midiOut);
// MIDI->OSC bridge (may not be current)
(
var server = server ? Server.default;
server.options.numBuffers = 1024 * 16; // increase this if you need to load more samples
server.options.memSize = 8192 * 64; // increase this if you get "alloc failed" messages
server.options.maxNodes = 1024 * 32; // increase this if you are getting drop outs and the message "too many nodes"
server.options.numInputBusChannels= 0;
// boot the server and start SuperDirt
server.waitForBoot {
~dirt = SuperDirt.start(path:"/Users/bgold/tidal/samples/*", numOrbits:4);
MIDIClient.init;
MIDIIn.connectAll;
~notes=[];
~oscSendAddress = NetAddr("localhost", 6010);
// ~midiHandler = MIDIFunc.cc( {|val, num, chan, src|
// ~oscSendAddress.sendMsg('/ctrl', num, val.asInteger);
// postln(num.asString + " " + val.asString + " " + chan.asString +" " + src.asString);
// }, nil, nil, nil);
MIDIFunc.cc({|val, num, chan, src| ~oscSendAddress.sendMsg('/ctrl', num, val/127.0);}, nil, nil, nil);
MIDIFunc.noteOn({|veloc, num, chan, src| ~notes=~notes.add(num); ~notes=~notes.sort({|a,b| a>b}).reverse; ~oscSendAddress.sendMsg('/ctrl', "notes", format("%", ~notes-60)); ~notes.postln;});
MIDIFunc.noteOff({|veloc, num, chan, src| ~notes=~notes.takeThese({|x| x==num}); ~oscSendAddress.sendMsg('/ctrl', "notes", format("%", ~notes-60)); ~notes.postln;});
}
)
( // global looper? pretty glitchy
var server = server ? Server.default;
~recBus.free;
~recBuf.free;
~dirt.orbits[0].outBus = 0;
//
~recBus = Bus.audio(server,2);
~recBuf = Buffer.alloc(server, server.sampleRate * 10, 2);
~dirt.orbits[0].outBus = ~recBus;
Ndef(\r, { |rec = 0|
var sig = In.ar(~recBus, 2);
RecordBuf.ar(sig, ~recBuf, run:rec > 0, trigger:rec);
Out.ar(0, sig);
});
SynthDef(\gloop, { |out, begin, end, sustain, speed, accelerate, pan|
var sound;
var env = EnvGen.ar(Env.linen(0.05, 0.9, 0.05), timeScale:sustain, doneAction:2);
var ind = Sweep.ar(1, BufSampleRate.ir(~recBuf));
ind = (ind * speed) + (begin * BufSampleRate.ir(~recBuf));
sound = BufRd.ar(2,~recBuf, ind);
OffsetOut.ar(out,DirtPan.ar(3.0*sound, ~dirt.numChannels, pan, env));
}).add;
)
Ndef(\r).set(\rec, 1);
Ndef(\r).set(\rec, 0);
~dirt.loadSoundFiles("/Users/bgold/Desktop")
~dirt.postSampleInfo
~dirt.orderModules([\lpf, \bpf]);
~dirt.orderModules([\wrap, \shape]); // swapped from default
~dirt.orderModules([\shape, \wrap]); // back to default
(
var diversions = (); // make a dictionary of functions
~diversions = diversions; // make it available out of scope
// use the "diversion" key as a hook for playing the synth
// return nil (unless you want the default action to also happen)
~dirt.orbits[0].defaultParentEvent[\diversion] = { diversions[~s].value };
)
(
~diversions[\order] = {
~dirt.orderModules([\sound, ~before.asSymbol, ~after.asSymbol]);
};
)
( // this bit should show all "instrument" synthDefs
var keys = SynthDescLib.global.synthDescs.keys;
keys = keys.select( {|k,i|
var notSys = "system_".matchRegexp(k.asString).not;
var notDirt = "dirt_".matchRegexp(k.asString).not;
notSys && notDirt;
});
keys.asList.sort.do{|x| postln(x)};
nil;
)
( // this bit should show all "effect" synthDefs, and maybe a few others, assuming they start with "dirt_"
// this is a bit less useful since it doesn't really hint at Tidal keywords
var keys = SynthDescLib.global.synthDescs.keys;
keys = keys.select( {|k,i| "dirt_".matchRegexp(k.asString);});
keys.asList.sort.do{|x| postln(x)};
nil;
)
Server.local.options
~dirt.modules.collect({|x| x.name})
/// optional sidechaining from efairbanks, orbit 0 comps orbit 1
(
~modBus.free;
~carBus.free;
~dirt.orbits[0].outBus = 0;
~dirt.orbits[1].outBus = 0;
// --- //
~modBus = Bus.audio(s, numChannels:2); // assuming stereo, expand if needed
~carBus = Bus.audio(s, numChannels:2);
~dirt.orbits[0].outBus = ~modBus; // play into that bus.
~dirt.orbits[1].outBus = ~carBus;
Ndef(\x, {
var modBus = In.ar(~modBus, 2);
var carBus = In.ar(~carBus, 2);
var out = modBus+carBus;
//carBus = FreeVerb.ar(carBus, 0.9, 0.8, 0.8);
out = Compander.ar(carBus, modBus, -30.dbamp, 1, 0.01, 0.01, 0.07)+modBus;
//out = Compander.ar(out, out, -15.dbamp, 1, 0.2);
Out.ar(0, out);
})
)
(
SynthDef(\superpad, {|out, sustain, pan, accelerate, freq, voice|
var sound, env, chop, fb, fr, cc;
env = EnvGen.ar(Env.linen(0.4, 0.2, 0.4), timeScale:sustain, doneAction:2);
freq = freq * XLine.ar(1, exp(accelerate), sustain);
fr = Line.ar(2.05, 1.95, sustain, mul:[1.01, 0.99]);
sound = SinOscFB.ar(freq/fr, 4).range(freq-10, freq+10);
fb = Line.ar(0.5, 0.8, sustain);
sound = Mix.ar(SinOscFB.ar(sound*[0.48, 0.745, 1, 3.2], fb, mul:[0.3, 0.2, 1, 0.2]));
chop = Saw.ar(freq + SinOsc.ar(1/sustain).range(-2,2));
cc = EnvGen.ar(Env.perc(0.5, 0.5, curve:1), timeScale:sustain, levelScale:-0.2, levelBias:0.2);
sound = sound * (chop < cc);
sound = BLowPass4.ar(BLowPass4.ar(sound, 8000, 1.5), 7500, 2.5);
sound = LeakDC.ar(sound);
sound = Splay.ar(sound, 0.5, levelComp:true); // TODO: multichannel
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
)
////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
( /////// CONSIDER THE FOLLOWING /////////////
var server = server ? Server.default;
var numChannels = ~dirt.numChannels;
var synthbuf = Buffer.alloc(server, server.sampleRate * 4, 1);
var recbuf = Array.fill(9, {|x| Buffer.alloc(server, server.sampleRate*4,1)});
var notebus = Bus.control(s,1);
var dronebus = Bus.control(s,5);
var ringfunc = {|a,b| a*a+b;};
var samplebuf = Buffer.read(server, "/Users/bgold/tidal/samples/rave/AREUREADY.wav");
var fxbus = Bus.audio(s,2);
var sinbuf = Buffer.alloc(server, server.sampleRate, 1);
SynthDef(\noop, {}).add;
// input with big gain
SynthDef(\in, { |out, sustain = 1, speed = 1, begin = 0, end = 1, pan, accelerate, offset|
var sound, rate, phase;
var env = EnvGen.ar(Env.linen(0.05, 0.9, 0.05), timeScale:sustain, doneAction:2);
phase = Line.ar(begin, end, sustain);
rate = (begin + 1) * (speed + Sweep.ar(1, accelerate));
sound = (SoundIn.ar(0) - SoundIn.ar(1));
sound = tanh(10.0*sound);
OffsetOut.ar(out,
DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\out, {|out, sustain=1, pan, begin, end,loop=1|
var sound, phase;
var env = EnvGen.ar(Env.linen(0.05, 0.8, 0.15), timeScale:sustain, doneAction:2);
phase = LFSaw.ar(loop/sustain, 1).range(begin,end);
sound = BufRd.ar(1, synthbuf, phase);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superclassic, {|out, sustain, pan, accelerate, freq, voice|
var sound, fenv, env, env2;
env = EnvGen.ar(Env.linen(0.05, 0.9, 0.05), timeScale:sustain, doneAction:2);
env2 = EnvGen.ar(Env.linen(clip(0.03*sustain, 0.03, 0.1), 0.9*sustain, 0.07*sustain));
freq = freq * XLine.ar(1, exp(accelerate), sustain);
sound = Pulse.ar(freq + [1,-1]);
sound = Integrator.ar(env2 * PulseDivider.ar(sound, 2), 0.995);
// sound = sound + Integrator.ar(PulseDivider.ar(sound, 2), 0.995);
sound = sound + sound.product;
sound = LeakDC.ar(sound);
sound = 1.5*atan(sound*0.3);
// sound = 0.3*atan(sound);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env))
}).add;
SynthDef(\superharm, {|out, sustain, pan, accelerate, freq, voice, lfo=0.5, decay, pitch1=1, pitch2=1|
var sound, menv, env, es, os, as, fenv;
menv = EnvGen.ar(Env.perc(0.05, 1.5), timeScale:sustain, doneAction:2);
env = Array.fill(7, {EnvGen.ar(Env.perc(ExpRand(0.01, 0.05), ExpRand(0.5, 1.5)), timeScale:sustain)});
freq = freq * XLine.ar(1, exp(accelerate), sustain);
es = freq * [2,4,6,8,12,16,22] * pitch1;
os = freq * [3,5,7,11,17,19,29] * pitch2;
as = [10, 7, 5, 4, 3, 2, 1, 1]/100;
es = SinOsc.ar(es, mul:as);
es = BLowPass4.ar(es, 5*freq, 0.3) * env;
os = SinOsc.ar(os, mul:as);
os = BLowPass4.ar(os, 5*freq, 0.3) * env;
sound = SinOsc.ar(freq, mul:menv*0.5) + Mix.ar( SelectX.ar(voice*SinOsc.kr(5, mul:0.5, add:0.5), [es, os]) );
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, 1))
}).add;
SynthDef(\supermod, {|out, sustain, pan, accelerate, freq, voice, lfo=0.5, decay, detune, pitch2=1.5|
var sound, osc1, osc2, env, f2, fm;
env = EnvGen.ar(Env.linen(0.05, 0.9, 0.05), timeScale:sustain, doneAction:2);
freq = freq * XLine.ar(1, exp(accelerate), sustain);
f2 = freq * pitch2 + detune + 0.01;
fm = SinOsc.ar(0.8).linexp(-1,1, 1/(1+lfo), 1+lfo);
osc2 = SelectX.ar(voice, [Impulse.ar(f2), SinOsc.ar(f2), VarSaw.ar(f2), Pulse.ar(f2), Saw.ar(f2)]).linexp(-1,1,1/fm,fm);
osc1 = SelectX.ar(voice, [SinOsc.ar(freq*osc2), VarSaw.ar(freq*osc2), Pulse.ar(freq*osc2), Saw.ar(freq*osc2), Impulse.ar(freq*osc2)]);
sound = osc1;
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env))
}).add;
SynthDef(\synthdev, {|out, sustain, pan, freq|
var env = EnvGen.ar(Env.linen(0.01, 0.95, 0.04), timeScale:sustain, doneAction:2);
var fenv = EnvGen.ar(Env.perc(0.05, 1.5), timeScale:sustain);
var sound = Mix.ar(Pulse.ar(freq + [-1,0,1], [0.5, 0.2+SinOsc.kr(4,0,0.2,0.2), 0.8+SinOsc.kr(4,0.5,0.2,0.2)]));
sound = RLPF.ar(sound, fenv * [800, 1100, 1300] + 15, [0.5,0.3, 0.4]);
sound = Splay.ar(sound, 0.5);
sound = sound + DelayL.ar(sound, 0.1, SinOsc.ar(0.1, [0, 0.25, 0.5], 0.005, 0.01));
OffsetOut.ar(out, DirtPan.ar(0.35 * sound, ~dirt.numChannels, pan, env))
}).add;
SynthDef(\synthdev2, {|out, sustain, pan, freq|
var env = EnvGen.ar(Env.linen(0.01, 0.95, 0.04), timeScale:sustain, doneAction:2);
var sound = Pulse.ar(freq + LPF.ar(Pulse.ar(220, 0.5, freq/8, 0), freq), LPF.ar(Pulse.ar(110, 0.5, 0.2, 0.5), freq));
sound = LPF.ar(LPF.ar(sound, 8000), 8100);
sound = sound + DelayL.ar(sound, 0.1, LPF.ar(Pulse.ar(0.1, [0.4, 0.6], 0.001, 0.01), 60));
OffsetOut.ar(out, DirtPan.ar(0.35 * sound, ~dirt.numChannels, pan, env))
}).add;
SynthDef(\synthdev3, {|out, sustain, pan, freq|
var env = EnvGen.ar(Env.linen(0.01, 0.95, 0.04), timeScale:sustain, doneAction:2);
var sound, o1, o2, o2p;
o2p = LocalIn.ar(1);
o1 = LPF.ar(Pulse.ar(0.99*freq+o2p, 0.4+(o2p*0.1)), 4000);
o2 = LPF.ar(Pulse.ar(1.01*freq+o1, 0.6+(o1*0.1)), 4000);
LocalOut.ar(o2);
sound = o1+o2;
sound = sound + DelayL.ar(sound, 0.1, 1/[1100,1350]);
sound = Latch.ar(sound, Pulse.ar([8000,8001]));
sound = LPF.ar(sound, 8000);
OffsetOut.ar(out, DirtPan.ar(0.35 * sound, ~dirt.numChannels, pan, env))
}).add;
{
var wave = Mix.ar(SinOsc.ar([1,2,3,0.5]));
wave = LeakDC.ar(wave * wave - wave, 0.9995);
BufWr.ar(wave, sinbuf, Phasor.ar(0, 1, 0, BufFrames.kr(sinbuf)),0);
0;
}.play;
SynthDef(\synthdev4, {|out, sustain, pan, freq|
var env = EnvGen.ar(Env.linen(0.01, 0.95, 0.04), timeScale:sustain, doneAction:2);
var penv = EnvGen.ar(Env.perc(0.02, 2, 44100), timeScale:sustain);
var sound, scan;
scan = SinOsc.ar(freq) + (0.2*VarSaw.ar(freq*0.75, [0, 0.5], Line.ar(0.3,0,sustain)));
sound = BufRd.ar(1, sinbuf, scan * penv, interpolation:1);
sound = 0.5*LPF.ar(LPF.ar(sound, 8000), 8100);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env))
}).add;
SynthDef(\supertrip, {|out, pan, freq, sustain, accelerate|
var env, fb, sound, aa, bb;
freq = freq * XLine.ar(1, exp(accelerate), sustain) * (0.9 * PitchShift.ar(LocalIn.ar(1), 0.2, 8.0, 0.5) + 1.0);
env = EnvGen.ar(Env.linen(0.1, 0.8, 0.1), timeScale:sustain, doneAction:2);
aa = LFPulse.ar(freq*2.001, width:0.5);
bb = LFPulse.ar(freq*3.002, width:0.3);
sound = SetResetFF.ar(aa, bb);
sound = 2.0 * LeakDC.ar(sound);
LocalOut.ar(sound);
OffsetOut.ar(out, DirtPan.ar(Splay.ar([sound, sound+aa-bb], 0.4), ~dirt.numChannels, pan, env));
}).add;
SynthDef(\supernonlin, {|out, pan, freq, sustain, voice, accelerate|
var env, fb, sound;
freq = freq * XLine.ar(1, exp(accelerate), sustain);
env = EnvGen.ar(Env.linen(0.1, 0.8, 0.1), timeScale:sustain, doneAction:2);
sound = SinOscFB.ar(freq, 0.5);
sound = WeaklyNonlinear.ar(sound, reset:0, freq:freq, alpha:0.005, xexponent:1, beta:-1);
sound = LagUD.ar(sound, 1/12000, 1/140);
sound = DelayL.ar(sound, 0.1, 0.030);
sound = LagUD.ar(sound, 1/200, 1/8000);
sound = LeakDC.ar(sound);
sound = atan(sound*3);
// sound = SinOscFB.ar(freq, sound.range(0,1));
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superdeep, {|out, pan, freq, sustain, voice, accelerate|
var env, fb, sound;
freq = freq * XLine.ar(1, exp(accelerate), sustain);
env = EnvGen.ar(Env.linen(0.1, 0.8, 0.1), timeScale:sustain, doneAction:2);
sound = VarSaw.ar(freq, 0, LocalIn.ar() * (voice/2) + 0.5);
sound = LagUD.ar(sound.clip2(0.9), 1/440, 1/8000);
LocalOut.ar(sound);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
// OffsetOut.ar(out, DirtPan.ar([sound, DelayC.ar(sound, 0.2, 0.001)], ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superdeep2, {|out, pan, freq, sustain, accelerate|
var env, sound;
freq = freq * XLine.ar(1, exp(accelerate), sustain);
env = EnvGen.ar(Env.linen(0.05, 0.9, 0.05), timeScale:sustain, doneAction:2);
sound = VarSaw.ar(freq, 0, 0, mul:0.5) - VarSaw.ar(freq+(0.8*sustain), 0.1, 0, mul:0.5);
sound = LagUD.ar(sound, 1/2040, 1/8000);
sound = RLPFD.ar(sound, (sqrt(freq/1440.0) * 1440).clip(20,15000), 0.2, 0.2, mul:3);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superbass, {|out, pan, freq, sustain, detune, accelerate|
var sound, env, fenv, fd;
freq = freq * XLine.ar(1, exp(accelerate), sustain);
env = EnvGen.ar(Env.linen(0.1, 0.8, 0.1), timeScale:sustain, doneAction:2);
fenv = EnvGen.ar(Env.perc(0.2,2, 2), timeScale:sustain);
fd = 0.01 + detune;
sound = Mix.ar(SawDPW.ar(freq*[1-fd,1+fd], [-0.5, 0.5]));
sound = 3.0*RLPFD.ar(sound, (4256*((freq/4256)**0.5)*fenv).clip(20,20000), 0.2);
sound = sound + (1.0 * clip(0.5*LPF.ar(sound, freq), -0.25,0.25) );
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superbell, {|out, pan, freq, sustain, accelerate|
var sound, aenv, freqmults, amps, ringtimes;
freq = freq * XLine.ar(1, exp(accelerate), sustain);
aenv = EnvGen.ar(Env.perc(0.01, 2, 1, -3), timeScale:sustain, doneAction:2);
freqmults = [1.0 , 1.26624044,
1.53254558, 1.79888688, 2.06525043, 2.33162862, 2.59801696,
2.86441263, 3.13081377, 3.39721908, 3.66362766];
amps = Array.fill(11, {|i| exp(-1.0*i/11)});
ringtimes = Array.fill(11, {|i| 0.3 + (i*0.3) + (i*i/4.0)});
sound = DynKlank.ar(`[ freqmults, amps, ringtimes], Impulse.ar(0.1), freqscale:freq);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv));
}).add;
SynthDef(\superwide, {|out, pan, freq, sustain, accelerate|
var sound, mod, aenv, fenv, samp, trig;
freq = freq * XLine.ar(1, exp(accelerate), sustain);
aenv = EnvGen.ar(Env.linen(0.05, 0.85, 0.1, 1, 'lin'), timeScale:sustain, doneAction:2);
sound = LagUD.ar(VarSaw.ar(freq, [0,0.1], 0.01), 1.0/900, 1.0/200)
- LagUD.ar(VarSaw.ar(freq*1.01, [0.5,0.67], 0.03), 1.0/900, 1.0/200);
sound = LeakDC.ar(sound);
sound = RLPF.ar(RLPF.ar(sound, freq*7, 1/5.5), freq*3, 1/1.2);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv));
}).add;
SynthDef(\superblip2, {|out, pan, freq, sustain|
var sound, mod, aenv, fenv, samp, trig;
aenv = EnvGen.ar(Env.linen(0.05, 0.85, 0.1, 1, 'lin'), timeScale:sustain, doneAction:2);
sound = Blip.ar(freq+Blip.ar(freq*1.98, 30, freq/5), 20 * Blip.ar(freq/2.01, 2).range(0,1));
sound = LPF.ar(sound, 4*freq + Blip.ar(freq/32, 5).range(0,freq));
sound = tanh(5.0*sound);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv));
}).add;
SynthDef(\superrand, {|out, pan, freq, sustain|
var sound, mod, aenv, fenv, samp, trig;
aenv = EnvGen.ar(Env.linen(0.05, 0.85, 0.1, 1, 'lin'), timeScale:sustain, doneAction:2);
sound = Mix.ar(Impulse.ar(freq, Array.fill(50, {|i| Rand(0,1)}), Array.fill(50, {|i| Rand(-1,1)}) ));
sound = LPF.ar(sound, 13000);
sound = 0.5*atan(5*sound);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv));
}).add;
SynthDef(\supercombo, {|out, pan, freq, sustain, voice|
var sound, aenv, shift, switch;
aenv = EnvGen.ar(Env.linen(0.05, 0.85, 0.1, 1, 'lin'), timeScale:sustain, doneAction:2);
shift = 0.2 / sustain;
switch = voice.linexp(0, 1, 0.5, 2);
sound = SelectX.ar(SinOsc.ar(freq*switch).range(0,1), [SinOsc.ar(freq + shift), Saw.ar(freq - shift)]);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv))
}).add;
SynthDef(\supersync2, {|out, pan, freq, sustain|
var sound, mod, aenv, fenv, samp, trig;
aenv = EnvGen.ar(Env.linen(0.05, 0.85, 0.1, 1, 'lin'), timeScale:sustain, doneAction:2);
// samp = Mix.ar(SinOsc.ar([20,30,440,800,1100], [0.1, 0.2,0,0.5,0], [0.3, 0.3, 1, 0.5, 0.3]));
samp = Mix.ar(Saw.ar((freq*[3.5, 4.5]+[200, 605])));
BufWr.ar(samp, sinbuf, Phasor.ar(0, BufRateScale.kr(sinbuf), 0, BufFrames.kr(sinbuf)));
trig = Mix.ar(Impulse.ar(freq*[0.99,1.01]));
sound = BufRd.ar(1, sinbuf, Phasor.ar(trig, BufRateScale.kr(sinbuf), 0, BufFrames.kr(sinbuf)));
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv));
}).add;
// tried a local buffer but it clicks and pops sometimes (running out of samples to read?)
SynthDef(\supersync3, {|out, pan, freq, sustain|
var sound, mod, aenv, fenv, samp, trig;
aenv = EnvGen.ar(Env.linen(0.05, 0.85, 0.1, 1, 'lin'), timeScale:sustain, doneAction:2);
fenv = EnvGen.ar(Env.perc(0.2, 0.7, 1, -1), timeScale:sustain);
samp = 0.5*Mix.ar(Pulse.ar([freq*1.2, freq*3.14, 800, 1100, 2100], XLine.ar(0.5, 0.2, 0.01)));
BufWr.ar(samp, sinbuf, Phasor.ar(0, 0.25, 0, BufFrames.kr(sinbuf)));
trig = Mix.ar(Impulse.ar(freq*[1.001,0.999]));
sound = BufRd.ar(1, sinbuf, Phasor.ar(trig, 1, 0, BufFrames.kr(sinbuf), Line.ar(0,40,sustain)));
// sound = BufRd.ar(1, sinbuf, Phasor.ar(trig, 1, 0, BufFrames.kr(sinbuf)));
sound = LeakDC.ar(sound);
sound = LPF.ar(sound, 8000);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv));
}).add;
SynthDef(\superscratch, {|out, pan, freq, sustain, accelerate, detune=0|
var sound;
var env = EnvGen.ar(Env.linen(0.05, 0.8, 0.15), timeScale:sustain, doneAction:2);
freq = freq * XLine.ar(1, exp(accelerate), sustain);
sound = Dust2.ar(freq);
sound = Mix.ar(Resonz.ar(sound, freq*[1.1, 2.5+detune, 5, 23], 0.1, mul:10));
sound = CombL.ar(sound, 0.2, XLine.ar(0.0001, 0.00011, sustain), 0.01);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superx1, {|out, pan, freq, sustain, accelerate, detune=0|
var sound;
var env = EnvGen.ar(Env.linen(0.05, 0.8, 0.15), timeScale:sustain, doneAction:2);
freq = freq * XLine.ar(1, exp(accelerate), sustain);
sound = Saw.ar(freq * (detune/100+1.01)) - Saw.ar(freq * (-1*detune/100+0.99));
sound = RLPF.ar(sound, (freq*64).clip(5,20000), 0.5);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superx2, {|out, pan, freq, sustain, accelerate,detune=0, voice=0|
var sound, vcut;
var env = EnvGen.ar(Env.linen(0.05, 0.8, 0.15), timeScale:sustain, doneAction:2);
freq = freq * XLine.ar(1, exp(accelerate), sustain);
vcut = voice.linexp(0,1,1,0.1);
sound = Saw.ar(freq) + Saw.ar(1.5*freq*(detune/100+1), 0.2) + Pulse.ar(freq/2.0*(detune/100+1), 0.5, 0.5);
sound = tanh(5.0*sound/vcut);
sound = RLPF.ar(sound, (freq*16*vcut).clip(20,20000), freq.linexp(20,4000,0.3,0.5));
sound = 0.5*RLPF.ar(sound, (freq*24*vcut).clip(20,20000), freq.linexp(40,8000,0.3,1.0));
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superx3, {|out, pan, freq, sustain, accelerate, voice=0, pitch1, pitch2=4, lfo=0|
var sound;
var env = EnvGen.ar(Env.linen(0.05, 0.8, 0.15), timeScale:sustain, doneAction:2);
freq = freq * XLine.ar(1, exp(accelerate), sustain);
sound = Saw.ar(freq * 1.01) - Saw.ar(freq * 0.99) + Pulse.ar(freq/1.98, 0.1, 0.2) - Pulse.ar(freq/2.02, 0.11, 0.2);
sound = RLPF.ar(sound, freq*4, 0.3);
sound = Notch.ar(sound, freq*1.5 * (SinOsc.ar(freq*0.67).linexp(-1,1,0.5,1.5)), 0.2);
sound = tanh(2*sound);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superx4, {|out, pan, freq, sustain, accelerate, voice=0, pitch1, pitch2=4, lfo=0|
var sound, local, localcv, lfowave;
var env = EnvGen.ar(Env.linen(0.05, 0.8, 0.15), timeScale:sustain, doneAction:2);
freq = freq * XLine.ar(1, exp(accelerate), sustain);
local = LocalIn.ar(1);
localcv = LocalIn.kr(1);
sound = Pulse.ar(freq*local/15+freq, local/8.0+0.125);
LocalOut.ar(sound);
lfowave = SinOsc.kr(localcv*1.5 + (freq/4.0));
LocalOut.kr(lfowave);
sound = RLPF.ar(sound, freq*lfowave.linexp(-1,1,12,13), 0.1);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
// burninates the cpu
// SynthDef(\superspec, {|out, pan, freq, sustain, accelerate, voice=0, pitch1, pitch2=4, lfo=0|
// var sound, sound2, lfowave;
// var env = EnvGen.ar(Env.linen(0.05, 0.8, 0.15), timeScale:sustain, doneAction:2);
// freq = freq * XLine.ar(1, exp(accelerate), sustain);
// lfowave = 1.0 - SinOsc.kr(pitch2).range(0, lfo);
// sound = Splay.arFill(21, {|x| DynKlang.ar(
// `[Array.series(12,1+((x-10)/(315*voice+35)))+Array.rand2(12,0.01),
// exp(-0.5*((x-10)/3.0)**2) ! 12,
// Array.rand2(12,pi)], freq)/ 21}, spread:0.3, levelComp:false);
// sound = BHiShelf.ar(sound, 800*lfowave, 1, -20);
// sound2 = DynKlang.ar(`[Array.series(12,1), sqrt(1.0/Array.series(12,1)), Array.rand2(12,pi)], freq*(1.0+pitch1))/4.0;
// sound2 = RLPF.ar(sound2, freq*(2+pitch1)*lfowave, 0.5);
// sound = sound + sound2;
// OffsetOut.ar(out, DirtPan.ar(0.2*sound, ~dirt.numChannels, pan, env));
// }).add;
// SynthDef(\superspecfft, {|out, pan, freq, sustain, speed, detune, accelerate, voice, pitch1|
// var snd, buf, chain, magsphases;
// var lb = LocalBuf(1024);
// var env = EnvGen.ar(Env.linen(0.05, 0.8, 0.15), timeScale:sustain, doneAction:2);
// snd = WhiteNoise.ar(1);
// chain = FFT(lb, snd);
// magsphases = UnpackFFT(chain, 1024);
// magsphases = magsphases.collect({|x,i|
// x * cos( i*20/freq * pi)**2
// // x * exp(-0.5 * ((i-(freq/20))/10.0)**2)
// });
// chain = PackFFT(chain, 1024, magsphases);
// // chain = chain.pvcollect(1024, {|mag, phase, bin|
// // var fftf = (bin) * 44100.0/4096;
// // var g = exp(-0.5 * (((fftf-440)/5.0)**2));
// // [mag*g, phase];
// // });
// snd = IFFT(chain);
// OffsetOut.ar(out, DirtPan.ar(snd, ~dirt.numChannels, pan, env));
// }).add;
// from efairbanks
SynthDef(\workinprogress, {
|out, sustain = 1, freq = 440, begin=0, end=1, pan, accelerate|
var line = Line.ar(begin, end, sustain, doneAction:2);
var env = Env([0, 1, 0], [0.05, 0.5], curve:[1,-1]);
var envGen = IEnvGen.ar(env, line*env.times.sum);
var sound = Mix.ar(Array.fill(20,{|i|Pulse.ar(ExpRand.new(20.0,2000.0),0.1)}));
var fs = Array.fill(10, {|i| i+1});
sound = Mix.ar(BPF.ar(sound,DC.ar(fs**1.262)*freq, (4/1000))*DC.ar(1.0/(fs**1.5)));
OffsetOut.ar(out, DirtPan.ar(10.0*sound, ~dirt.numChannels, pan, envGen));
}).add;
SynthDef(\superds, {|out, pan, freq, sustain, accelerate, detune, voice|
var sound, env, glide;
env = EnvGen.ar(Env.linen(0.05, 0.8, 0.15), timeScale:sustain, doneAction:2);
glide = Line.kr(1, 1+accelerate, sustain);
sound = Splay.ar(Pulse.ar(freq*[-1*detune/100+0.99,detune/100+1.01]*glide, voice/3+0.5, mul:0.7), 0.3, levelComp:false);
sound = 0.5 * LPF.ar(sound, 8000);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\super1, {|out, pan, freq, sustain, voice=0|
var sound, env, fenv, mod;
env = EnvGen.ar(Env.linen(0.2, 0.6, 0.2), timeScale:sustain, doneAction:2);
fenv = EnvGen.ar(Env.perc(0.1, 2.0, 1, [1,-1]), timeScale:sustain);
mod = Lag.kr(LFPulse.kr(8.0/sustain, width:0.2).range(0.02,1), 0.1);
sound = Splay.ar(VarSaw.ar(freq*[0.99,1.01], [0,0.5], 0.7), 0.3, levelComp:false);
sound = 0.5 * LPF.ar(sound, (freq*12*fenv*mod+280));
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
// interesting pitch changes
SynthDef(\super2, {|out, pan, freq, sustain, speed|
var sound, env, fenv, mod1, mod2;
mod1 = LFPulse.kr(1.0*speed, 0.5, mul:4) + LFPulse.kr(2.0*speed, 0.25, mul:2) + LFPulse.kr(4.0*speed, 0, mul:1);
mod1 = 2.0 ** (mod1/4.0);
mod2 = Lag.kr(LFPulse.kr(8.0*speed, width:0.33).range(0.02,1), 0.1);
env = EnvGen.ar(Env.linen(0.2, 0.6, 0.2), timeScale:sustain, doneAction:2);
fenv = EnvGen.ar(Env.perc(0.1, 1.0, 1, [1,-1]), timeScale:sustain);
sound = Lag.kr(mod2, 0.5)*1.2*Splay.ar(VarSaw.ar(mod1*freq*[0.99,1.01], [0,0.5], 0.7), 0.3, levelComp:false);
sound = LPF.ar(Mix.ar(VarSaw.ar(freq * [0.75, 1.0, 1.5, 2.0], 0, [0.4, 0.3 ,0.2, 0.1], mul:0.5)), freq*8*fenv*mod2+1) + sound;
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
// screechy fm
SynthDef(\super3, {|out, pan, freq, sustain, speed|
var sound, env, fenv, mod1, mod2, ff, ww;
env = EnvGen.ar(Env.linen(0.2, 0.6, 0.2), timeScale:sustain, doneAction:2);
fenv = EnvGen.ar(Env.perc(0.1, 2.0, 1, [1,-1]), timeScale:sustain);
ff = freq * Mix.ar(Pulse.ar(freq / [1.1,2.2,3.3], 0.5).exprange(0.9,1.0/0.9));
ww = Mix.ar(Pulse.ar([1,2,3,4]*5.0, 0.5).range(0.4,0.6));
sound = Pulse.ar(ff, ww);
sound = Mix.ar(RLPF.ar(sound, freq * fenv * [1,2,4,13] + 1, 0.5));
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
// I like this one
// voice [-1,1]
SynthDef(\super4, {|out, pan, freq, sustain, voice, pitch1|
var sound, env, fenv, mod1, mod2;
env = EnvGen.ar(Env.linen(0.1, 0.7, 0.2, 1, [3,-3]), timeScale:sustain, doneAction:2);
fenv = EnvGen.ar(Env.perc(0.2, 2.0, 1, [4,0]), timeScale:sustain);
sound = LagUD.ar(Pulse.ar(freq, Line.ar(0.5,0.3,sustain)+(voice/0.7)), [5,1]/4000, [1,5]/4000);
mod1 = Lag.ar(ToggleFF.ar(sound)*2-1, 1/3000);
mod2 = Fold.ar(Fold.ar(DelayN.ar(sound, 0.2, 0.001))*2-1)*2-1;
sound = (sound + mod1 + mod2)*0.2;
sound = RHPF.ar(RLPF.ar(sound, 2024.0*fenv.linexp(0,1,10**(pitch1-1),1), 1/Line.ar(1,4,sustain)), 64.0, 1/3);
sound = Splay.ar(sound, 0.7);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\super5, {|out, pan, freq, sustain, speed, detune, accelerate, voice, pitch1, slidedelay|
var sound, env, fenv, mod1, mod2, basefreq,det, pitchenv;
pitchenv = EnvGen.ar(Env.pairs([[0,1],[slidedelay,1],[1, 1+accelerate]], 0), timeScale:sustain);
// basefreq = speed * freq * Line.kr(1, 1+accelerate, sustain);
basefreq = speed * freq * pitchenv;
det = [0.005, - 0.005] * (detune+1) + 1.0;
env = EnvGen.ar(Env.linen(0.0, 0.8, 0.2, 1, [3,-3]), timeScale:sustain, doneAction:2);
fenv = EnvGen.ar(Env.perc(0.001, 2.0, 1, [4,0]), timeScale:sustain);
sound = LagUD.ar(Pulse.ar(basefreq*det, Line.ar([0.7,0.0],0.3,sustain)+(voice/0.7)), [5,3,1]/4000, [1,3,5]/4000);
mod2 = Fold.ar(Fold.ar(DelayN.ar(sound, 0.2, 0.001))*2-1)*2-1;
sound = mod2;
sound = RHPF.ar(RLPF.ar(sound, 2024.0*fenv.linexp(0,1,10**(pitch1-1.2),1), 1/Line.ar(2,4,sustain)), freq, 1/5);
sound = Splay.ar(sound, 0.4);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superd, {|out, pan, freq, sustain|
var sound, env, fenv, lfreq, lgain, lpan, lag, locals;
env = EnvGen.ar(Env.linen(0.01, 0.95, 0.04), timeScale:sustain, doneAction:2);
fenv = EnvGen.ar(Env.perc(0.02, 2, 1, [1,-1]), timeScale:sustain);
sound = Splay.ar(VarSaw.ar(freq*[0.99,1.01], [0,0.2], 0.98), 0.4, levelComp:false);
sound = 0.5 * LPF.ar(sound, freq*10*fenv+800);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\dronec, {|n=0, gain=1, pan=0.5, speed, sustain|
Out.kr(dronebus, [n, gain, pan, speed, sustain]);
}).add;
SynthDef(\drone, {|out, pan, freq, sustain|
var sound, env, fenv, lfreq, lgain, lpan, lag, locals;
env = EnvGen.ar(Env.linen(0.005, 0.99, 0.005), timeScale:sustain, doneAction:2);
locals = In.kr(dronebus, 5);
fenv = EnvGen.ar(Env.perc(0.02, 2, 1, [1,-1]), gate:Changed.kr(locals[0]), timeScale:locals[4]);
lag = 0.5 * locals[4] / locals[3];
lfreq = freq * Lag.kr(2.0 ** (locals[0]/12), lag);
lgain = 1.0 * Lag.kr(locals[1], lag);
lpan = pan + Lag.kr(locals[2], lag);
sound = Splay.ar(VarSaw.ar(lfreq*[0.99,1.01], [0,0.2], 0.98), 0.4, levelComp:false);
sound = LPF.ar(sound, freq*10*fenv+800);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, lpan, env*lgain));
}).add;
SynthDef(\superf, {|out, pan, freq, sustain|
var ctls, mods, chans, env;
env = EnvGen.ar(Env.linen(0.01, 0.95, 0.04), timeScale:sustain, doneAction:2);
ctls = [
// freq, phase, amp
[freq, 0, 1],
[freq, 0.5, 1],
[freq *4 , 0, 1],
[freq * 33/32, 0, 1],
[LFNoise2.kr(0.5).exprange(3, 800), 0, 1],
[LFNoise2.kr(0.5).exprange(0.3, 10), 0, 1]
];
mods = [
[0.2, 0, 1, LFNoise1.kr(0.5).exprange(0.1,1), 0, 0],
[0, 0.2, 1, LFNoise1.kr(0.5).exprange(0.1,1), 0, 0],
[0, 0, 0.2, 0.5, 0, 0.1],
[0.1, 0.1, 2, 0, 0, 0.1],
0!6,
[0, 0, 3, 0, 1, 0]
];
chans = FM7.ar(ctls, mods).slice([0, 1]) * -12.dbamp;
OffsetOut.ar(out, DirtPan.ar(chans, ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superfff, {|out, pan, freq, sustain|
var sound;
var aenv = EnvGen.ar(Env.perc(0.01, 0.99, 1, -1), timeScale:sustain, doneAction:2);
sound = SinOsc.ar(freq);
sound = ringfunc.value(sound, SinOsc.ar(freq-40));
sound = tanh(sound/2.5);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv));
}).add;
// FUTURE???
SynthDef(\superpsaw, {|out, pan, freq, sustain, detune=0, voice=0|
var sound, mod, aenv, fenv;
aenv = EnvGen.ar(Env.linen(0.05, 0.9, 0.05, 1, 'lin'), timeScale:sustain, doneAction:2);
fenv = EnvGen.ar(Env.perc(0.1, 0.9, 1, -1), timeScale:sustain);
sound = Splay.arFill(4, {|n| VarSaw.ar(freq*(0.01*n+0.985)*(detune/12+1), Rand(0,1), 0.01+voice)}, 0.4);
sound = RLPF.ar(sound, freq*(5+voice)*fenv, 1.5);
sound = sin(sound*2)/1.6;
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv));
}).add;
// trying some phase sync stuff
// kind of brassy?
SynthDef(\supersync, {|out, pan, freq, sustain|
var sound, mod, aenv, fenv;
aenv = EnvGen.ar(Env.linen(0.1, 0.8, 0.1, 1, 'lin'), timeScale:sustain, doneAction:2);
fenv = EnvGen.ar(Env.perc(0.2, 0.7, 1, -1), timeScale:sustain);
sound = Splay.ar(SyncSaw.ar(freq, [1800, 803, 500, 499, 800, 1810]), 0.5);
sound = sound + ([0.3,-0.3] * DelayC.ar(sound, 0.1, Line.ar(1,0.5,sustain)*0.005));
sound = RLPF.ar(sound, clip(freq*7*fenv, 20, 15000), 1.5);
sound = sin(sound*2)/2;
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv));
}).add;
// build in some distortion?
SynthDef(\superdrop, {|out, sustain=1, pan, freq, accelerate=0, pitch1=4, voice=0,lfo=0|
var sound, basefreq, aenv, fenv, menv, ind, m1, m2, filtrange;
basefreq = freq * Line.kr(1, 1+accelerate, sustain);
aenv = EnvGen.ar(Env.linen(0.05, 0.9, 0.05, 1, 'lin'), timeScale:sustain, doneAction:2);
menv = XLine.ar(4, 1, sustain/3);
sound = Saw.ar(basefreq * menv * [0.99, 1, 1.01]);
sound = Splay.ar(sound);
sound = sound * Pulse.ar(4*basefreq*menv, 0.3);
sound = tanh(1.5*sin(1.5*sound));
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv))
}).add;
// maybe turn into a nice pad and rename
SynthDef(\superdub5, {|out, sustain=1, pan, freq, accelerate=0, pitch1=4, voice=0,lfo=0|
var sound, basefreq, aenv, fenv, menv, ind, m1, m2, filtrange;
aenv = EnvGen.ar(Env.linen(0.05, 0.9, 0.05, 1, 'lin'), timeScale:sustain, doneAction:2);
menv = EnvGen.ar(Env.linen(0.3, 0.2, 0.5), timeScale:sustain);
basefreq = freq * Line.kr(1, 1+accelerate, sustain);
m1 = SinOsc.ar(basefreq*2) * basefreq/8;
m2 = SinOsc.ar(basefreq + m1*4) * basefreq*2 * menv;
sound = Splay.ar(VarSaw.ar(basefreq+m2 * [0.99,1,1.01], 0, 0.2*menv+0.1));
sound = (sound*(50*voice+5)).clip(-1,1)*0.5;
sound = HPF.ar(LeakDC.ar(sound), 60);
sound = 0.5*LFTri.ar(basefreq) + sound;
sound = sin(2*sound);
filtrange = clip(menv*basefreq*12+1200, 2, 20000);
sound = LPF.ar(sound, LFTri.kr(pitch1).range(filtrange*(1-lfo), filtrange));
OffsetOut.ar(out, DirtPan.ar(sound*aenv, ~dirt.numChannels, pan, 1))
}).add;
// pops a bit, could be nice if fixed
SynthDef(\superdub6, {|out, sustain=1, pan, freq, accelerate=0, pitch1=4, voice=0,lfo=0,detune=0.008|
var sound, basefreq, aenv, fenv, menv, ind, m1, m2, filtrange, detarr;
aenv = EnvGen.ar(Env.linen(0.05, 0.9, 0.05, 1, 'lin'), timeScale:sustain, doneAction:2);
menv = EnvGen.ar(Env.linen(0.4, 0.6, 0.0, 1, 1), timeScale:sustain);
basefreq = 2**(Lag.kr(In.kr(notebus,1),sustain));
ReplaceOut.kr(notebus, log2(freq));
basefreq = basefreq * Line.kr(1, 1+accelerate, sustain);
detarr = Array.interpolation(3,1-detune,1+detune);
sound = Splay.ar(Pulse.ar(basefreq * detarr, detarr-0.5)) + Splay.ar(VarSaw.ar(basefreq, 0, [0.1,0.2,0.3])* 0.5);
sound = sound - CombN.ar(sound, 0.2, 0.010*Line.kr(1,1.5,sqrt(sustain)), 0.1);
sound = LPF.ar(sound, menv*3000);
sound = sin(sound*20/sqrt(freq));
sound = HPF.ar(LeakDC.ar(sound), 60);
sound = BPeakEQ.ar(sound, XLine.kr(30, 3000, 1), 0.1, -20);
sound = BPeakEQ.ar(sound, XLine.kr(5000, 60, 1), 0.15, -20);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv))
}).add;
// not what the name says
SynthDef(\superacid, {|out, speed=1, sustain=1, decay=0, pan, freq, accelerate=0, voice=0.0, slide=0,
pitch1=500, pitch2=1500|
var sound, basefreq, aenv, fenv, glide;
aenv = EnvGen.ar(Env.perc(0.01, 1, 1, 'lin'), timeScale:sustain, doneAction:2);
fenv = EnvGen.ar(Env.perc(0.01, 1+decay, 1, 'lin'), timeScale:sustain);
glide = EnvGen.ar(Env.perc(0.05, 0.5, 1, \lin), timeScale:sustain) * (-1*slide/4) + 1;
basefreq = freq * glide * Line.kr(1, 1+accelerate, sustain);
sound = VarSaw.ar(basefreq, 0) - VarSaw.ar(basefreq, voice/2+0.5);
sound = 2.0*RLPFD.ar(sound, pitch2*fenv+pitch1, 0.5, 1);
sound = 0.5*tanh(10.0*sound);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, aenv))
}).add;
SynthDef(\superwobble, {|out, sustain=1, pan, speed=1, accelerate, freq, decay=0,
pitch1=4000, lfo=0.5, pitch2=4, slide=0|
var env = EnvGen.ar(Env.pairs([[0,0],[0.07,1],[0.2,1-decay],[0.95,1-decay],[1,0]], -1), timeScale:sustain, doneAction:2);
var glide = EnvGen.ar(Env.perc(0.05, 0.2, 1, \lin), timeScale:sustain) * (-1*slide/4) + 1;
var basefreq = freq * glide * Line.kr(1, 1+accelerate, sustain) * [0.99, 1.01];
var sound = LPF.ar(Pulse.ar(basefreq), basefreq*4) + Saw.ar(1.99*basefreq) + Saw.ar(3.98*basefreq);
sound = 0.6*LPF.ar(sound, pitch1*SinOsc.kr(pitch2/(sustain),3.5).exprange(1,10.0**(-2.0*lfo)));
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
// pulse?
SynthDef(\superpulse, {|out, sustain=1, pan, speed=1, accelerate, freq, decay=0, slide=1 |
var env = EnvGen.ar(Env.pairs([[0,0],[0.07,1],[0.2,1-decay],[0.95,1-decay],[1,0]], -1), timeScale:sustain, doneAction:2);
var basefreq = freq * Line.kr(1, 1+accelerate, sustain) * [0.99, 1.01];
var sound = Blip.ar(basefreq, 64) + Impulse.ar(basefreq) + Saw.ar(basefreq);
sound = BHiShelf.ar(sound, 1200, 10, -8);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
// original idea - http://www.attackmagazine.com/technique/synth-secrets/detuned-pad/
SynthDef(\superzzz, {|out, sustain=1, pan, freq, detune=1 |
var sound, env, freqs, osc1, osc2;
env = EnvGen.ar(Env.linen(0.05, 0.9, 0.05), timeScale:sustain, doneAction:2);
freqs = freq * ([0, 0.01*Rand(-1,1), 0.009*Rand(-1,1), 0.011*Rand(-1,1)]*detune + 1.0);
osc1 = DelayC.ar( LFSaw.ar(freqs, Rand(0,2pi)) , 0.2, freqs.reciprocal * SinOsc.ar(Rand(3,4), Rand(0,2pi)).range(0.9,1));
osc2 = DelayC.ar( LFSaw.ar(freqs/2*Rand(0.99,1.01), Rand(0,2pi)), 0.2, freqs.reciprocal * SinOsc.ar(Rand(2,3), Rand(0,2pi)).range(0.9,1));
sound = BLowPass4.ar(osc2, SinOsc.ar(Rand(2,4)).range(800,900), 1) + osc1;
sound= 0.7*tanh(0.3*Mix.ar(sound));
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
// trying out some synth voice stuff, right now starts with 'a' and glides to vowel with formants at pitch1,pitch2 (default 'i')
SynthDef(\supervoice, {|out, sustain=1, pan, freq, pitch1=240, pitch2=2400|
var sound, env, p1, p2;
env = EnvGen.ar(Env.linen(0.1, 0.8, 0.1), timeScale:sustain, doneAction:2);
sound = Impulse.ar(freq);
p1 = XLine.kr(850, pitch1, sustain*0.5);
p2 = XLine.kr(1610, pitch2, sustain*0.5);
sound = 0.5*DynKlank.ar(`[[p1, p2], nil, nil], sound, decayscale:0.01);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
// write a signal into a delay, tap it at multiple times
// I think this messes up if more than one is playing at a time
SynthDef(\superbuf, {|out, sustain=1, pan, freq|
var sound, env, tapPhase, tap1, tap2, tap3, sl, sr;
// env = EnvGen.ar(Env.perc(0.005, 1, 1, 1), timeScale:sustain, doneAction:2);
env = EnvGen.ar(Env.linen(0.005, 0.8, 0.195, 1, 1), timeScale:sustain, doneAction:2);
sound = Mix.ar(VarSaw.ar(freq, [0, 0.5, 1], Line.kr(0,1,sustain)));
tapPhase = DelTapWr.ar(synthbuf, sound);
#tap1, tap2, tap3 = DelTapRd.ar(synthbuf, tapPhase,
[0.1, 0.27, 0.303] * Line.kr(0.48,0.52,sustain) * 0.3 * sustain, // tap times
1, // no interp
[1.0, 0.6, 0.4] // muls for each tap
);
sl = sound+tap2;
sr = tap1 + tap3;
OffsetOut.ar(out, DirtPan.ar(Splay.ar([sl, sr],0.4, 0.3), ~dirt.numChannels, pan, env));
}).add;
SynthDef(\supercross, {|out, speed=1, sustain=1, decay=0, pan, freq, accelerate=0, voice=0.0, detune=0.0,
pitch1=1, pitch2=2, vcoegint=0|
var env = EnvGen.ar(Env.pairs([[0,0],[0.03,1],[0.2,1-decay],[0.95,1-decay],[1,0]], -1), timeScale:sustain, doneAction:2);
var basefreq1 = pitch1 * freq * Line.kr(1, 1+accelerate, sustain);
var basefreq2 = pitch2 * freq * Line.kr(1, 1+accelerate, sustain);
var sound, sa, sb, loop, rlo, rhi;
rlo = 1.0 - (0.9 * vcoegint);
rhi = 1.0 + (0.9 * vcoegint);
loop = LocalIn.ar(1);
basefreq1 = clip(basefreq1 * loop.range(rlo,rhi), 2, 20000); // FM mod from osc 2
sa = SelectX.ar(voice, [
VarSaw.ar(basefreq1, 0, 0.5) - VarSaw.ar(basefreq1+detune, 0, 0.2),
SinOsc.ar(basefreq1+detune,0.1) * loop.range(rlo,1), // ring mod for sine,
LFTri.ar(basefreq1, 0) + LFTri.ar(basefreq1+detune, 0.1) * 0.5,
Pulse.ar(basefreq1+detune, LPF.ar(loop.range(rlo/2,rhi/2), 50)) * 0.5 // mod pulse width for square
]);
basefreq2 = clip(basefreq2 * sa.range(rlo,rhi), 2, 20000); // FM mod from osc 1
sb = SelectX.ar(voice, [
VarSaw.ar(basefreq2-detune, 0.2, 0.2) - VarSaw.ar(basefreq2-detune, 0.2, 0.3),
SinOsc.ar(basefreq2-detune,0.3) * sa.range(rlo,1), // ring mod for sine
LFTri.ar(basefreq2-detune, 0.3) + LFTri.ar(basefreq2-detune, 0.2) * 0.5,
Pulse.ar(basefreq2-detune, LPF.ar(sa.range(rlo/2,rhi/2), 50) ) * 0.5
]);
LocalOut.ar(DelayN.ar(sb,0.2, Line.ar(0,0.5,sustain)/basefreq1));
sound = sa+sb;
sound = 0.5*LPF.ar(sound, XLine.ar(1,0.01,sustain, 12000));
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env))
}).add;
// probably way too complicated, this synth has it's own set of filters, controllable with new parameters
// voice: 0 - saw, 1 - square (can go past 1 for noisy overdrive)
// slide: initial pitch glide, can be used to fake portamento
// decay: 0 is minimal decay, 1 will quickly decay to silence (you can also use the global release param for a different shape)
// sfcutoff, sfresonance, sfenv, sfattack, sfrelease: filter params for this synth only
// the envelope shape for this synth is different from the global filter envelope
// pitch1: advanced params for tweaking lowpass and bandpass frequencies
// something I still don't like - CLEAN UP AND FIX
SynthDef(\super302, {|out, speed=1, sustain=1, decay=0, pan, freq, accelerate=0, voice=0.0, slide=0,
pitch1=1,sfattack=0, sfrelease=0, sfenv=0, sfcutoff=1000, sfresonance=0|
var sound, glide, basefreq, env, env2, resq, loresq;
env = EnvGen.ar(Env.new([1e-6,1,(1-decay)*0.5,1e-6], [0.03, 0.9, 0.07], 'exp'), timeScale:sustain, doneAction:2);
// env2= EnvGen.ar(Env.perc(sfattack, sfrelease, 1, [-4,4]));
env2 = EnvGen.ar(Env.linen(sfattack, 0, sfrelease));
glide = EnvGen.ar(Env.perc(0.05, 0.5, 1, \lin), timeScale:sustain) * (-1*slide/4) + 1;
basefreq = freq * glide * Line.kr(1, 1+accelerate, sustain);
sound = tanh(VarSaw.ar(basefreq, 0, 0.98)+PinkNoise.ar(0.01*exp(voice))*(voice*50+1));
resq = 1.0 + (26 * sfresonance);
// loresq = 1.0 + (26*4.67*sfresonance);
loresq = 1.0 + (26*sfresonance);
// sound = BPF.ar(sound, clip(sfcutoff/10*pitch2+(sfenv/10*env2*pitch2), 20,11000),
// rq:2.9-(2.8*vcfegint));
// sound = sound * (1.2 + (1.2*vcfegint));
sound = BMoog.ar(sound, clip(sfcutoff+(sfenv*env2)/2, 20, 11000), q:sfresonance, mode:2, saturation:0.99);
sound = RHPF.ar(sound, clip(sfcutoff/100*pitch1+(sfenv/10000*env2*pitch1), 8,8000), rq:1/loresq);
sound = RLPF.ar(sound, clip(sfcutoff+(sfenv*env2), 20, 11000), rq:1/clip(resq*1000/sfcutoff,1,52));
//sound = ((sfresonance * sound)**3 + sound) / (max(1,sfresonance)**3);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env))
}).add;
SynthDef(\superlagcomp, {|out, speed=1, sustain=1, decay=0, pan, freq, accelerate=0, voice=0.2|
var env = EnvGen.ar(Env.pairs([[0,0],[0.03,1],[0.2,1-decay],[0.95,1-decay],[1,0]], -1), timeScale:sustain, doneAction:2);
var basefreq = freq * Line.kr(1, 1+accelerate, sustain);
var sound, sa,sb, sl, sr;
sa = Saw.ar(basefreq) + Saw.ar(basefreq*1.011);
sb = Saw.ar(clip(basefreq*4.0+(freq/5*sa),5,20000)) + Saw.ar(clip(basefreq*4.021*(1+voice)+(freq/5*sa), 5, 20000));
sound = LPF.ar(sa > sb, clip(freq*(voice+1),5,20000));
sa = sa * sb.range(0.5,1);
sound = (sound * sa) + ((1-sound) * sb) + BlitB3Tri.ar(basefreq, 0.99, 0.99, 0.2);
sl = 0.5 * sound;
sr = 0.5 * DelayN.ar(sound, 0.2, Line.ar(0.01,0.02,sustain));
OffsetOut.ar(out, DirtPan.ar([sl,sr], ~dirt.numChannels, pan, env));
}).add;
SynthDef(\superphase, {|out, speed=1, sustain=1, decay=0, pan, freq, accelerate=0, voice=0 |
var env = EnvGen.ar(Env.pairs([[0,0],[0.07,1],[0.2,1-decay],[0.95,1-decay],[1,0]], -1), timeScale:sustain, doneAction:2);
var basefreq = freq * Line.kr(1, 1+accelerate, sustain);
var fadj = [0.005, 0.007] * (voice+1) + 1.0;
var fadj2 = 1.0 - ([0.005, 0.007] * (voice+1));
var sound = Saw.ar(basefreq*fadj[0]) - DelayC.ar(Saw.ar(basefreq*fadj[1]), 0.2, SinOsc.kr(0.5).range(0.2,0.4)/basefreq);
var fenv = EnvGen.ar(Env.perc(0.01, 2, 1, 2), timeScale:sustain);
sound = sound + Saw.ar(basefreq*fadj2[0]) - DelayC.ar(Saw.ar(basefreq*fadj2[1]), 0.2, SinOsc.kr(0.5).range(0.2,0.4)/basefreq);
sound = sound + PMOsc.ar(basefreq, basefreq*1.01, Line.kr(6.28,0));
sound = sound - BAllPass.ar(sound, XLine.kr(4400,44,sustain), 2);
sound = MoogFF.ar(sound/2, fenv*XLine.kr(10000, 500/speed+(basefreq/2), sustain), 1);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env))
}).add;
SynthDef(\superblip, {|out, sustain=1, pan, freq|
var env = EnvGen.ar(Env.perc(0.050, 0.900, 1, -2), timeScale:sustain, doneAction:2);
var sound = Pulse.ar(freq, Line.kr(0,1,sustain), 0.5);
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
// experimental
SynthDef(\fx, {|out, freq, pan, sustain|
var sound, env;
sound = In.ar(fxbus, ~dirt.numChannels);
env = EnvGen.ar(Env.linen(0.1, 0.7, 0.1), timeScale:sustain, doneAction:2);
sound = Mix.ar(DelayL.ar(sound, 2.0, [0.3, 0.5, 0.7, 0.9]));
OffsetOut.ar(out, DirtPan.ar(sound, ~dirt.numChannels, pan, env));
}).add;
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
//// CUSTOM EFFECTS //////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////
~dirt.addModule('lpg', {|dirtEvent| dirtEvent.sendSynth("dirt_lpg" ++ ~dirt.numChannels,
[lpg: ~lpg, lpga: ~lpga, lpgr: ~lpgr, lpgg: ~lpgg, lpgres: ~lpgres, out: ~out])}, {~lpg.notNil});
SynthDef("dirt_lpg"++~dirt.numChannels, {|out, lpg, lpga=0.001, lpgr=0.010, lpgg=1.0, lpgres=0|
var in = In.ar(out, ~dirt.numChannels);
// var gate = Amplitude.ar(in*lpgg, lpga, lpgr);
var gate = LagUD.ar(Amplitude.ar(in*lpgg, 0.001, 0.001), lpga, lpgr);
var filt = RLPF.ar(in, gate.expexp(-60.dbamp, 0.dbamp, 20, 20000), 1.0 - lpgres);
ReplaceOut.ar(out, SelectX.ar(lpg, [in, filt]));
}).add;
~dirt.addModule('whammy', {|dirtEvent| dirtEvent.sendSynth("dirt_whammy" ++ ~dirt.numChannels,
[whammy: ~whammy, whammyshift: ~whammyshift, whammyfreq: ~whammyfreq, whammydelay: ~whammydelay, sustain: ~sustain, out: ~out])}, {~whammy.notNil});
SynthDef("dirt_whammy"++~dirt.numChannels, {|out, whammy, whammyshift, whammyfreq, whammydelay, sustain|
var in = In.ar(out, ~dirt.numChannels);
var transpose = whammyshift + (12.0 * (whammyshift < 1e-6));
var grainsize = 1.0 / (whammyfreq + (5.7 * (whammyfreq < 1e-6))); // 0.075 is a bit faster
var grainfreq = XLine.ar(transpose.midiratio * 1.02, transpose.midiratio, sustain) / grainsize; // transpose / grainsize
var deltime = whammydelay + (0.02 * (whammydelay < 1e-6)); // 0.05 down to zero?
var sig = in;
sig = DelayC.ar(sig, 1, LFSaw.ar(grainfreq, [1,0]) * grainsize / (-2.0) + deltime);
sig = sig * SinOsc.ar(grainfreq, [-1.0,1.0]*pi/2).linlin(-1,1,0,1);
sig = LeakDC.ar(sig);
ReplaceOut.ar(out, SelectX.ar(whammy/2.0, [in, sig]));
}).add;
~dirt.addModule('schmidt', {|dirtEvent| dirtEvent.sendSynth("dirt_schmidt" ++ ~dirt.numChannels,
[schmidt: ~schmidt, out: ~out])}, {~schmidt.notNil});
SynthDef("dirt_schmidt"++~dirt.numChannels, {|out, schmidt|
var in = In.ar(out, ~dirt.numChannels);
var sig = in * Schmidt.ar(in, -0.1, 0.1);
ReplaceOut.ar(out, SelectX.ar(schmidt, [in, sig]));
}).add;
~dirt.addModule('zpulse', {|dirtEvent| dirtEvent.sendSynth("dirt_zpulse" ++ ~dirt.numChannels,
[zpulse: ~zpulse, out: ~out])}, {~zpulse.notNil});
SynthDef("dirt_zpulse"++~dirt.numChannels, {|out, zpulse|
var in = In.ar(out, ~dirt.numChannels);
var sig = Blip.ar(ZeroCrossing.ar(in), numharm:5, mul:Amplitude.ar(in, 0,0));
ReplaceOut.ar(out, SelectX.ar(zpulse, [in, sig]));
}).add;
~dirt.addModule('enc', {|dirtEvent| dirtEvent.sendSynth("dirt_enc" ++ ~dirt.numChannels,
[enc: ~enc, out: ~out])}, {~enc.notNil});
SynthDef("dirt_enc"++~dirt.numChannels, {|out, enc|
var sig = In.ar(out, ~dirt.numChannels);
/*var fs = [250, 300, 450, 610, 810, 1100, 1300, 1700];*/
var fs = [60, 270, 200, 350] *.x [3, 7, 11, 17, 29, 41];
var cutoff = clip(fs/100, 30, 60);