test function of Property type class is not available

[marcellussiegburg]

I would like to run (all) my tests using QuickCheck and SmallCheck using Hspec. I Thought it might be helpful to run both test cases using the same Spec structure as when running test cases with either of them.

My idea was to create a library which handles the importing of QuickCheck and SmallCheck (and maybe other testing libraries) and reexports an unique interface for running both. The implementation is very simple.
That is why I present the basic code here (including a Spec example):

{-# LANGUAGE TypeFamilies #-}
{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE FlexibleContexts #-}
module Data.ListSpec where

import qualified Test.QuickCheck       as QC
import qualified Test.SmallCheck       as SC
import qualified Test.Hspec.SmallCheck as SC
import           Test.Hspec            hiding (it)
import qualified Test.Hspec            as Hspec

spec :: Spec
spec = do
  describe "length" $
    it "is higher for longer lists" $ property $ \ xs ->
      not (null xs) ==> length xs > length (tail (xs :: [Int]))

it descr p = do
  Hspec.it (descr ++ " (SC)") $ SC.property p
  Hspec.it (descr ++ " (QC)") $ QC.property p

infixr 0 ==>
(==>) :: (SC.Testable m prop, QC.Testable prop)
  => Bool -> prop -> (SC.Property m, QC.Property)
cond ==> p = (cond SC.==> p, cond QC.==> p)

property :: (SC.Testable IO prop, QC.Testable prop)
  => prop -> (SC.Property IO, QC.Property)
property p = (SC.property p, QC.property p)

instance QC.Testable (SC.Property m, QC.Property) where
  property (_, p) = QC.property p

instance (Monad m, m ~ n) => SC.Testable n (SC.Property m, QC.Property) where
  test (p, _) = SC.test p

Unfortunately it is not possible to implement the last Testable instance for SmallCheck as function test is not being exported. Thus, my suggestion is to export it and rerelease SmallCheck. I understand the Test.SmallCheck.Property module (and its function test) is internal. If it is required to stress this, I would suggest renaming this module to Test.SmallCheck.Internal.Property, exporting the test function and making it a visible module of the package.

Of course I am open to suggestions to achieve my goal (without code duplication) otherwise.

[UnkindPartition]

Does the above work for you? If so, I'll make a release.

[UnkindPartition]

Also, you are aware of hspec-smallcheck, right?

[marcellussiegburg]

Yes, it does work. Thanks in advance for the release.
Yes, I am aware of hspec-smallcheck. That is why I use the library in the code above (import of Test.Hspec.SmallCheck).

[UnkindPartition]

Got it — just wasn't sure what problem you were solving.

Released as v1.1.2.