-
Notifications
You must be signed in to change notification settings - Fork 1
/
fib.lean
242 lines (225 loc) · 4.91 KB
/
fib.lean
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
import data.list.range
import data.list.join
@[reducible]
def fibonacci : ℕ → ℕ
| 0 := 0
| 1 := 1
| (n+2) := fibonacci n + fibonacci (n+1)
open nat list
---
@[reducible]
def fib_sum (n : ℕ) : ℕ :=
((range n).map fibonacci).sum
@[reducible]
def fib_odd_sum (n : ℕ) : ℕ :=
((range n).map (λ m, fibonacci (2*m + 1))).sum
@[reducible]
def fib_even_sum (n : ℕ) : ℕ :=
((range n).map (λ m, fibonacci (2*m))).sum
---
theorem fib_odd_sum_eq : ∀ (n : ℕ),
fib_odd_sum n = fibonacci (2*n)
| 0 := rfl
| (n+1) := by rw [fib_odd_sum,
sum_range_succ,
←fib_odd_sum,
fib_odd_sum_eq,
mul_add,
mul_one,
fibonacci]
---
theorem fib_even_sum_eq : ∀ {n : ℕ} (h : n > 0),
fib_even_sum n + 1 = fibonacci (2*n - 1)
| 0 h := (gt_irrefl 0 h).elim
| 1 _ := rfl
| (n+2) _ :=
have H : fib_even_sum (n+1) + 1 = fibonacci (2*(n+1) - 1) :=
fib_even_sum_eq (succ_pos n),
begin
rw [fib_even_sum,
sum_range_succ,
←fib_even_sum,
add_right_comm,
H,
mul_add,
mul_one,
mul_add],
change fibonacci (2*n + 1) + fibonacci (2*n + 1 + 1) =
fibonacci (2*n + 1 + 2),
rw [←fibonacci],
end
---
theorem fib_sum_eq : ∀ (n : ℕ),
fib_sum n + 1 = fibonacci (n+1)
| 0 := rfl
| (n+1) :=
begin
rw [fibonacci,
←fib_sum_eq n],
simp [range_succ, fib_sum,
add_left_comm, add_comm],
end
inductive bee : Type
| queen : bee
| worker : bee
| drone : bee
open bee list
instance : has_repr bee :=
⟨λ s, match s with
| queen := "Q"
| worker := "W"
| drone := "D"
end⟩
---
namespace bee
def parents : bee → list bee
| queen := [queen, drone]
| worker := [queen, drone]
| drone := [queen]
def ancestors (b : bee) : ℕ → list bee
| 0 := [b]
| (n+1) := ((ancestors n).map parents).join
---
def tree_json : bee → ℕ → string
| b 0 := "{\"name\":\"" ++ repr b ++ "\"}"
| b (n+1) := "{\"name\":\"" ++ repr b ++ "\",\"children\":[" ++
string.intercalate "," (b.parents.map (λ p, p.tree_json n)) ++ "]}"
---
lemma drone_ancestors_concat : ∀ (n : ℕ),
drone.ancestors (n+2) = drone.ancestors (n+1) ++ drone.ancestors n
| 0 := rfl
| (n+1) := begin
change ((ancestors _ (n+2)).map _).join = _,
conv { to_lhs,
rw [drone_ancestors_concat n,
map_append,
join_append], },
refl,
end
---
theorem drone_ancestors_length_eq_fib_succ : ∀ (n : ℕ),
(drone.ancestors n).length = fibonacci (n+1)
| 0 := rfl
| 1 := rfl
| (n+2) := begin
rw [drone_ancestors_concat,
length_append,
drone_ancestors_length_eq_fib_succ n,
drone_ancestors_length_eq_fib_succ (n+1),
add_comm],
refl,
end
end bee
---
inductive car : Type
| rabbit : car
| cadillac : car
open car list nat
instance : has_repr car :=
⟨λ s, match s with
| rabbit := "R"
| cadillac := "C"
end⟩
---
namespace car
@[reducible]
def size : car → ℕ
| rabbit := 1
| cadillac := 2
@[reducible]
def sum_size (cs : list car) : ℕ :=
(cs.map size).sum
lemma sum_size_cons (c : car) (cs : list car) :
sum_size (c :: cs) = sum_size cs + c.size :=
by simp only [sum_size, sum_cons, map, add_comm]
---
@[reducible]
def packings : ℕ → list (list car)
| 0 := [[]]
| 1 := [[rabbit]]
| (n+2) := (packings (n+1)).map (cons rabbit) ++
(packings n).map (cons cadillac)
---
theorem num_packings_eq_fib : ∀ (n : ℕ),
(packings n).length = fibonacci (n+1)
| 0 := rfl
| 1 := rfl
| (n+2) :=
begin
simp [packings, fibonacci, add_left_comm, add_comm],
rw [num_packings_eq_fib n,
num_packings_eq_fib (n+1),
add_left_comm,
add_right_inj,
fibonacci],
end
---
theorem packings_size : ∀ {n : ℕ} {cs : list car} (h : cs ∈ packings n),
sum_size cs = n
| 0 cs h :=
begin
rw mem_singleton.1 h,
refl,
end
| 1 cs h :=
begin
rw mem_singleton.1 h,
refl,
end
| (n+2) cs h :=
begin
simp [packings] at h,
rcases h with ⟨cs', h₁, h₂⟩ | ⟨cs', h₁, h₂⟩,
all_goals { rw [←h₂,
sum_size_cons,
size,
packings_size h₁], },
end
---
lemma car_size_ne_zero (c : car) : size c ≠ 0 :=
by cases c; contradiction
lemma sum_size_zero : ∀ {cs : list car} (h : sum_size cs = 0),
cs = []
| [] _ := rfl
| (c::cs) h :=
begin
exfalso,
rw [sum_size_cons,
add_eq_zero_iff] at h,
exact car_size_ne_zero c h.2,
end
---
lemma sum_size_one : ∀ {cs : list car} (h : sum_size cs = 1),
cs = [rabbit]
| [] h := by contradiction
| (rabbit::cs) h :=
begin
rw [sum_size_cons] at h,
simp,
exact sum_size_zero (succ.inj h),
end
| (cadillac::cs) h :=
begin
rw [sum_size_cons] at h,
have : sum_size cs + 1 = 0 := succ.inj h,
contradiction,
end
---
theorem all_packings : ∀ {n : ℕ} {cs : list car} (h : sum_size cs = n),
cs ∈ packings n
| 0 cs h := by simp [packings, sum_size_zero h]
| 1 cs h := by simp [packings, sum_size_one h]
| (n+2) [] h := by contradiction
| (n+2) (rabbit::cs) h :=
begin
rw [sum_size_cons,
add_left_inj 1] at h,
simp [packings, all_packings, h],
end
| (n+2) (cadillac::cs) h :=
begin
rw [sum_size_cons,
add_left_inj 2] at h,
simp [packings, all_packings, h],
end
end car