forked from archlinux/svntogit-packages
-
Notifications
You must be signed in to change notification settings - Fork 0
/
PKGBUILD
80 lines (64 loc) · 1.83 KB
/
PKGBUILD
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgbase=nautilus
pkgname=(nautilus libnautilus-extension libnautilus-extension-docs)
pkgver=43.2
pkgrel=1
epoch=1
pkgdesc="Default file manager for GNOME"
url="https://wiki.gnome.org/Apps/Files"
arch=(x86_64)
license=(GPL)
depends=(libgexiv2 gdk-pixbuf2 gst-plugins-base-libs gnome-desktop-4 gvfs dconf
tracker3 tracker3-miners gnome-autoar libadwaita libportal-gtk4
libcloudproviders)
makedepends=(gobject-introspection git gi-docgen meson appstream-glib)
checkdepends=(python-gobject)
source=("nautilus::git+ssh://git@github.com/bryango/nautilus-typeahead.git#branch=$pkgver")
sha256sums=('SKIP')
prepare() {
cd nautilus
}
build() {
local meson_options=(
-D docs=true
-D packagekit=false
)
arch-meson nautilus build "${meson_options[@]}"
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
_pick() {
local p="$1" f d; shift
for f; do
d="$srcdir/$p/${f#$pkgdir/}"
mkdir -p "$(dirname "$d")"
mv "$f" "$d"
rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
done
}
package_nautilus() {
depends+=(libnautilus-extension.so)
optdepends=('nautilus-sendto: Send files via mail extension')
groups=(gnome)
meson install -C build --destdir "$pkgdir"
cd "$pkgdir"
_pick libne usr/include
_pick libne usr/lib/{girepository-1.0,libnautilus-extension*,pkgconfig}
_pick libne usr/share/gir-1.0
_pick ldocs usr/share/doc
}
package_libnautilus-extension() {
pkgdesc="Extension interface for Nautilus"
depends=(glib2 gcc-libs)
provides=(libnautilus-extension.so)
mv libne/* "$pkgdir"
}
package_libnautilus-extension-docs() {
pkgdesc="Extension interface for Nautilus (documentation)"
depends=()
mv ldocs/* "$pkgdir"
}
# vim:set sw=2 sts=-1 et: