BUILD.bazel

load("@bazel_skylib//:bzl_library.bzl", "bzl_library")
load(
    "@cgrindel_rules_bazel_integration_test//bazel_integration_test:bazel_integration_test.bzl",
    "integration_test_utils",
)
load(
    "@cgrindel_rules_updatesrc//updatesrc:updatesrc.bzl",
    "updatesrc_update_all",
)
load("//:bazel_versions.bzl", "SUPPORTED_BAZEL_VERSIONS")
load("//bzlformat:bzlformat.bzl", "bzlformat_missing_pkgs", "bzlformat_pkg")

bzlformat_pkg(name = "bzlformat")

updatesrc_update_all(
    name = "update_all",
    targets_to_run = [
        "//doc:update",
        "//:bzlformat_missing_pkgs_fix",
    ],
)

bzlformat_missing_pkgs(
    name = "bzlformat_missing_pkgs",
)

# MARK: - Targets Used By Integration Tests

bzl_library(
    name = "bazel_versions",
    srcs = ["bazel_versions.bzl"],
    visibility = ["//:__subpackages__"],
)

# Provides the *.bazlerc files for the example workspace integration tests.
filegroup(
    name = "shared_bazelrc_files",
    srcs = glob(["*.bazelrc"]),
)

# The example workspaces use local_repository to reference this workspace.
# This target collects all of the files needed for rules_spm to work in the
# child workspaces.
filegroup(
    name = "local_repository_files",
    srcs = [
        "BUILD.bazel",
        "WORKSPACE",
        "//bzlformat:all_files",
        "//bzlformat/internal:all_files",
        "//tools:all_files",
        "//tools/missing_pkgs:all_files",
    ],
)

filegroup(
    name = "workspace_integration_test_files",
    srcs = [
        # The example workspaces reference the *.bazelrc files in the parent.
        "//:shared_bazelrc_files",

        # The example workspaces use local_repository to reference this
        # workspace.  This target collects all of the files needed for
        # rules_spm to work in the child workspaces.
        "//:local_repository_files",
    ],
    visibility = ["//:__subpackages__"],
)

test_suite(
    name = "all_integration_tests",
    tags = integration_test_utils.DEFAULT_INTEGRATION_TEST_TAGS,
    tests = [
        "//examples:integration_tests",
        "//tests/tools_tests/missing_pkgs_tests:integration_tests",
    ],
    visibility = ["//:__subpackages__"],
)