This repository has been archived by the owner on Feb 27, 2018. It is now read-only.
/
PKGBUILD
67 lines (53 loc) · 1.99 KB
/
PKGBUILD
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
# Maintainer: Xiao-long Chen <chenxiaolong@cxl.epac.to>
# Original Maintainer: György Balló <ballogy@freestart.hu>
# Contributor: thn81 <root@scrat>
pkgbase=libindicator
pkgname=('libindicator' 'libindicator3')
_actual_ver=12.10.2
_extra_ver=+14.04.20140402
pkgver=${_actual_ver}daily14.04.02
pkgrel=1
pkgdesc="A set of symbols and convience functions that all indicators would like to use"
arch=('i686' 'x86_64')
url="https://launchpad.net/libindicator"
license=('GPL')
makedepends=('gtk2' 'gtk3' 'glib2' 'ido')
groups=('unity')
source=("https://launchpad.net/ubuntu/+archive/primary/+files/${pkgbase}_${_actual_ver}${_extra_ver}.orig.tar.gz")
sha512sums=('44ee2e3b1a56f701d4ce7b4793469e85f6ad4f51d0e38a6ced1243509c703c4c1be0ccd326aa28d40c092fb15f0780ef785d58958a3902118af875a392f591f2')
build() {
cd "${srcdir}/${pkgbase}-${_actual_ver}${_extra_ver}"
export CFLAGS="${CFLAGS} -Wno-error=deprecated-declarations"
autoreconf -vfi
[[ -d build-gtk2 ]] || mkdir build-gtk2
pushd build-gtk2
../configure --prefix=/usr --libexecdir=/usr/lib/${pkgbase} --with-gtk=2 --disable-static
export MAKEFLAGS="-j1"
make
popd
[[ -d build-gtk3 ]] || mkdir build-gtk3
pushd build-gtk3
../configure --prefix=/usr --libexecdir=/usr/lib/${pkgbase} --with-gtk=3 --disable-static
make
popd
}
package_libindicator() {
pkgdesc+=" (GTK+ 2 library)"
depends=('cairo' 'gtk2' 'glib2')
cd "${srcdir}/${pkgbase}-${_actual_ver}${_extra_ver}/build-gtk2"
export MAKEFLAGS="-j1"
make DESTDIR="${pkgdir}/" install
}
package_libindicator3() {
pkgdesc+=" (GTK+ 3 library)"
depends=('gtk3' 'glib2' 'ido')
options=(${options[@]} '!emptydirs')
cd "${srcdir}/${pkgbase}-${_actual_ver}${_extra_ver}/build-gtk3"
export MAKEFLAGS="-j1"
make -C libindicator DESTDIR="${pkgdir}/" install
make -C tools DESTDIR="${pkgdir}/" install
# Identical in both packages, but Ubuntu puts it in the GTK 2 package
# Debug
rm -vf "${pkgdir}/usr/share/libindicator/80indicator-debugging"
}
# vim:set ts=2 sw=2 et: