forked from opendistro-for-elasticsearch/sql
-
Notifications
You must be signed in to change notification settings - Fork 0
/
OpenDistroPPLParser.g4
339 lines (275 loc) · 7.83 KB
/
OpenDistroPPLParser.g4
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
/*
* Copyright 2019 Amazon.com, Inc. or its affiliates. All Rights Reserved.
*
* Licensed under the Apache License, Version 2.0 (the "License").
* You may not use this file except in compliance with the License.
* A copy of the License is located at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* or in the "license" file accompanying this file. This file is distributed
* on an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either
* express or implied. See the License for the specific language governing
* permissions and limitations under the License.
*/
parser grammar OpenDistroPPLParser;
options { tokenVocab=OpenDistroPPLLexer; }
root
: pplStatement? EOF
;
/** statement */
pplStatement
: searchCommand (PIPE commands)*
;
/** commands */
commands
: whereCommand | fieldsCommand | renameCommand | statsCommand | dedupCommand | sortCommand | evalCommand | headCommand
| topCommand | rareCommand;
searchCommand
: (SEARCH)? fromClause #searchFrom
| (SEARCH)? fromClause logicalExpression #searchFromFilter
| (SEARCH)? logicalExpression fromClause #searchFilterFrom
;
whereCommand
: WHERE logicalExpression
;
fieldsCommand
: FIELDS (PLUS | MINUS)? wcFieldList
;
renameCommand
: RENAME renameClasue (COMMA renameClasue)*
;
statsCommand
: STATS
(PARTITIONS EQUAL partitions=integerLiteral)?
(ALLNUM EQUAL allnum=booleanLiteral)?
(DELIM EQUAL delim=stringLiteral)?
statsAggTerm (COMMA statsAggTerm)*
(byClause)?
(DEDUP_SPLITVALUES EQUAL dedupsplit=booleanLiteral)?
;
dedupCommand
: DEDUP
(number=integerLiteral)?
fieldList
(KEEPEMPTY EQUAL keepempty=booleanLiteral)?
(CONSECUTIVE EQUAL consecutive=booleanLiteral)?
;
sortCommand
: SORT sortbyClause
;
evalCommand
: EVAL evalClause (COMMA evalClause)*
;
headCommand
: HEAD
(KEEPLAST EQUAL keeplast=booleanLiteral)?
(WHILE LT_PRTHS whileExpr=logicalExpression RT_PRTHS)?
(number=integerLiteral)?
;
topCommand
: TOP
(number=integerLiteral)?
fieldList
(byClause)?
;
rareCommand
: RARE
fieldList
(byClause)?
;
/** clauses */
fromClause
: SOURCE EQUAL tableSource
| INDEX EQUAL tableSource
;
renameClasue
: orignalField=wcFieldExpression AS renamedField=wcFieldExpression
;
byClause
: BY fieldList
;
sortbyClause
: sortField (COMMA sortField)*
;
evalClause
: fieldExpression EQUAL expression
;
/** aggregation terms */
statsAggTerm
: statsFunction (AS alias=wcFieldExpression)?
;
/** aggregation functions */
statsFunction
: statsFunctionName LT_PRTHS valueExpression RT_PRTHS #statsFunctionCall
| COUNT LT_PRTHS RT_PRTHS #countAllFunctionCall
| percentileAggFunction #percentileAggFunctionCall
;
statsFunctionName
: AVG | COUNT | SUM | MIN | MAX
;
percentileAggFunction
: PERCENTILE '<' value=integerLiteral '>' LT_PRTHS aggField=fieldExpression RT_PRTHS
;
/** expressions */
expression
: logicalExpression
| comparisonExpression
| valueExpression
;
logicalExpression
: comparisonExpression #comparsion
| NOT logicalExpression #logicalNot
| left=logicalExpression OR right=logicalExpression #logicalOr
| left=logicalExpression (AND)? right=logicalExpression #logicalAnd
| left=logicalExpression XOR right=logicalExpression #logicalXor
| booleanExpression #booleanExpr
;
comparisonExpression
: left=valueExpression comparisonOperator right=valueExpression #compareExpr
| valueExpression IN valueList #inExpr
;
valueExpression
: left=valueExpression binaryOperator right=valueExpression #binaryArithmetic
| LT_PRTHS left=valueExpression binaryOperator
right=valueExpression RT_PRTHS #parentheticBinaryArithmetic
| primaryExpression #valueExpressionDefault
;
primaryExpression
: evalFunctionCall
| fieldExpression
| literalValue
;
booleanExpression
: booleanFunctionCall
;
/** tables */
tableSource
: qualifiedName
;
/** fields */
fieldList
: fieldExpression (COMMA fieldExpression)*
;
wcFieldList
: wcFieldExpression (COMMA wcFieldExpression)*
;
sortField
: (PLUS | MINUS)? sortFieldExpression
;
sortFieldExpression
: fieldExpression
| AUTO LT_PRTHS fieldExpression RT_PRTHS
| STR LT_PRTHS fieldExpression RT_PRTHS
| IP LT_PRTHS fieldExpression RT_PRTHS
| NUM LT_PRTHS fieldExpression RT_PRTHS
;
fieldExpression
: qualifiedName
;
wcFieldExpression
: wcQualifiedName
;
/** functions */
evalFunctionCall
: evalFunctionName LT_PRTHS functionArgs RT_PRTHS
;
/** boolean functions */
booleanFunctionCall
: conditionFunctionBase LT_PRTHS functionArgs RT_PRTHS
;
evalFunctionName
: mathematicalFunctionBase
| dateAndTimeFunctionBase
| textFunctionBase
| conditionFunctionBase
;
functionArgs
: (functionArg (COMMA functionArg)*)?
;
functionArg
: valueExpression
;
mathematicalFunctionBase
: ABS | CEIL | CEILING | CONV | CRC32 | E | EXP | FLOOR | LN | LOG | LOG10 | LOG2 | MOD | PI |POW | POWER
| RAND | ROUND | SIGN | SQRT | TRUNCATE
| trigonometricFunctionName
;
trigonometricFunctionName
: ACOS | ASIN | ATAN | ATAN2 | COS | COT | DEGREES | RADIANS | SIN | TAN
;
dateAndTimeFunctionBase
: ADDDATE | DATE | DATE_ADD | DATE_SUB | DAY | DAYNAME | DAYOFMONTH | DAYOFWEEK | DAYOFYEAR | FROM_DAYS
| HOUR | MICROSECOND | MINUTE | MONTH | MONTHNAME | QUARTER | SECOND | SUBDATE | TIME | TIME_TO_SEC
| TIMESTAMP | TO_DAYS | YEAR | WEEK | DATE_FORMAT
;
/** condition function return boolean value */
conditionFunctionBase
: LIKE
| ISNULL | ISNOTNULL
;
textFunctionBase
: SUBSTR | SUBSTRING | TRIM | LTRIM | RTRIM | LOWER | UPPER | CONCAT | CONCAT_WS | LENGTH | STRCMP
;
/** operators */
comparisonOperator
: EQUAL | NOT_EQUAL | LESS | NOT_LESS | GREATER | NOT_GREATER | REGEXP
;
binaryOperator
: PLUS | MINUS | STAR | DIVIDE | MODULE
;
/** literals and values*/
literalValue
: intervalLiteral
| stringLiteral
| integerLiteral
| decimalLiteral
| booleanLiteral
;
intervalLiteral
: INTERVAL valueExpression intervalUnit
;
stringLiteral
: DQUOTA_STRING | SQUOTA_STRING
;
integerLiteral
: (PLUS | MINUS)? INTEGER_LITERAL
;
decimalLiteral
: (PLUS | MINUS)? DECIMAL_LITERAL
;
booleanLiteral
: TRUE | FALSE
;
intervalUnit
: MICROSECOND | SECOND | MINUTE | HOUR | DAY | WEEK | MONTH | QUARTER | YEAR | SECOND_MICROSECOND
| MINUTE_MICROSECOND | MINUTE_SECOND | HOUR_MICROSECOND | HOUR_SECOND | HOUR_MINUTE | DAY_MICROSECOND
| DAY_SECOND | DAY_MINUTE | DAY_HOUR | YEAR_MONTH
;
valueList
: LT_PRTHS literalValue (COMMA literalValue)* RT_PRTHS
;
qualifiedName
: ident (DOT ident)* #identsAsQualifiedName
;
wcQualifiedName
: wildcard (DOT wildcard)* #identsAsWildcardQualifiedName
;
ident
: (DOT)? ID
| BACKTICK ident BACKTICK
| BQUOTA_STRING
| keywordsCanBeId
;
wildcard
: ident (MODULE ident)* (MODULE)?
| SINGLE_QUOTE wildcard SINGLE_QUOTE
| DOUBLE_QUOTE wildcard DOUBLE_QUOTE
| BACKTICK wildcard BACKTICK
;
keywordsCanBeId
: D // OD SQL and ODBC special
| statsFunctionName
| TIMESTAMP | DATE | TIME
| FIRST | LAST
;