-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle.kts
112 lines (100 loc) · 2.83 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
import org.jetbrains.kotlin.gradle.targets.js.webpack.KotlinWebpackConfig
plugins {
kotlin("multiplatform") version "1.9.10"
id("org.jetbrains.dokka") version "1.9.0"
id("maven-publish")
id("signing")
}
group = "io.circul"
version = "1.0.0"
repositories {
mavenCentral()
}
kotlin {
jvm {
jvmToolchain(8)
withJava()
testRuns.named("test") {
executionTask.configure {
useTestNG()
}
}
}
js {
browser {
commonWebpackConfig(Action<KotlinWebpackConfig> {
cssSupport {
enabled.set(true)
}
})
}
}
macosX64()
macosArm64()
linuxX64()
linuxArm64()
mingwX64()
iosX64()
iosArm64()
sourceSets {
getByName("commonMain") {
dependencies {
implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:1.7.3")
}
}
getByName("commonTest") {
dependencies {
implementation(kotlin("test"))
implementation("org.jetbrains.kotlinx:kotlinx-coroutines-test:1.7.3")
}
}
}
}
tasks.register<Jar>("javadocJar") {
archiveClassifier.set("javadoc")
}
publishing {
publications {
named<MavenPublication>("jvm") {
artifact(tasks["javadocJar"])
}
withType<MavenPublication>().all {
pom {
name.set("Catalyst")
description.set("Kotlin coroutines-based retry library")
url.set("https://catalyst.circul.io")
licenses {
license {
name.set("The Apache Software License, Version 2.0")
url.set("http://www.apache.org/licenses/LICENSE-2.0.txt")
}
}
developers {
developer {
id.set("JeremyMWillemse")
name.set("Jeremy Willemse")
email.set("jeremy@willemse.co")
}
}
scm {
url.set("https://github.com/circul-io/Catalyst")
connection.set("scm:git:https://github.com/circul-io/Catalyst.git")
developerConnection.set("scm:git:ssh://github.com/circul-io/Catalyst.git")
}
}
}
}
repositories {
maven {
name = "OSSRH"
url = uri("https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/")
credentials {
username = project.findProperty("ossrhUsername") as String?
password = project.findProperty("ossrhPassword") as String?
}
}
}
}
signing {
sign(publishing.publications)
}