forked from mozilla/gecko-dev
-
Notifications
You must be signed in to change notification settings - Fork 2
/
leak-gauge.pl
executable file
·271 lines (265 loc) · 10.6 KB
/
leak-gauge.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
#!/usr/bin/perl -w
# vim:sw=4:ts=4:et:
# ***** BEGIN LICENSE BLOCK *****
# Version: MPL 1.1/GPL 2.0/LGPL 2.1
#
# The contents of this file are subject to the Mozilla Public License Version
# 1.1 (the "License"); you may not use this file except in compliance with
# the License. You may obtain a copy of the License at
# http://www.mozilla.org/MPL/
#
# Software distributed under the License is distributed on an "AS IS" basis,
# WITHOUT WARRANTY OF ANY KIND, either express or implied. See the License
# for the specific language governing rights and limitations under the
# License.
#
# The Original Code is leak-gauge.pl
#
# The Initial Developer of the Original Code is the Mozilla Foundation.
# Portions created by the Initial Developer are Copyright (C) 2005
# the Initial Developer. All Rights Reserved.
#
# Contributor(s):
# L. David Baron <dbaron@dbaron.org>, Mozilla Corporation (original author)
#
# Alternatively, the contents of this file may be used under the terms of
# either the GNU General Public License Version 2 or later (the "GPL"), or
# the GNU Lesser General Public License Version 2.1 or later (the "LGPL"),
# in which case the provisions of the GPL or the LGPL are applicable instead
# of those above. If you wish to allow use of your version of this file only
# under the terms of either the GPL or the LGPL, and not to allow others to
# use your version of this file under the terms of the MPL, indicate your
# decision by deleting the provisions above and replace them with the notice
# and other provisions required by the GPL or the LGPL. If you do not delete
# the provisions above, a recipient may use your version of this file under
# the terms of any one of the MPL, the GPL or the LGPL.
#
# ***** END LICENSE BLOCK *****
# $Id: leak-gauge.pl,v 1.8 2008/02/08 19:55:03 dbaron%dbaron.org Exp $
# This script is designed to help testers isolate and simplify testcases
# for many classes of leaks (those that involve large graphs of core
# data structures) in Mozilla-based browsers. It is designed to print
# information about what has leaked by processing a log taken while
# running the browser. Such a log can be taken over a long session of
# normal browsing and then the log can be processed to find sites that
# leak. Once a site is known to leak, the logging can then be repeated
# to figure out under what conditions the leak occurs.
#
# The way to create this log is to set the environment variables:
# NSPR_LOG_MODULES=DOMLeak:5,DocumentLeak:5,nsDocShellLeak:5,NodeInfoManagerLeak:5
# NSPR_LOG_FILE=nspr.log (or any other filename of your choice)
# in your shell and then run the program.
# * In a Windows command prompt, set environment variables with
# set VAR=value
# * In an sh-based shell such as bash, set environment variables with
# export VAR=value
# * In a csh-based shell such as tcsh, set environment variables with
# setenv VAR value
#
# Then, after you have exited the browser, run this perl script over the
# log. Either of the following commands should work:
# perl ./path/to/leak-gauge.pl nspr.log
# cat nspr.log | perl ./path/to/leak-gauge.pl
# and it will tell you which of certain core objects leaked and the URLs
# associated with those objects.
# Nobody said I'm not allowed to write my own object system in perl. No
# classes here. Just objects and methods.
sub call {
my $func = shift;
my $obj = shift;
my $funcref = ${$obj}{$func};
&$funcref($obj, @_);
}
# A hash of objects (keyed by the first word of the line in the log)
# that have two public methods, handle_line and dump (to be called using
# call, above), along with any private data they need.
my $handlers = {
"DOMWINDOW" => {
count => 0,
windows => {},
handle_line => sub($$) {
my ($self, $line) = @_;
my $windows = ${$self}{windows};
if ($line =~ /^([0-9a-f]*) (\S*)/) {
my ($addr, $verb, $rest) = ($1, $2, $');
if ($verb eq "created") {
$rest =~ / outer=([0-9a-f]*)$/ || die "outer expected";
my $outer = $1;
${$windows}{$addr} = { outer => $1 };
++${$self}{count};
} elsif ($verb eq "destroyed") {
delete ${$windows}{$addr};
} elsif ($verb eq "SetNewDocument") {
$rest =~ /^ (.*)$/ || die "URI expected";
my $uri = ($1);
${${$windows}{$addr}}{$uri} = 1;
}
}
},
dump => sub ($) {
my ($self) = @_;
my $windows = ${$self}{windows};
foreach my $addr (keys(%{$windows})) {
my $winobj = ${$windows}{$addr};
my $outer = delete ${$winobj}{outer};
print "Leaked " . ($outer eq "0" ? "outer" : "inner") .
" window $addr " .
($outer eq "0" ? "" : "(outer $outer) ") .
"at address $addr.\n";
foreach my $uri (keys(%{$winobj})) {
print " ... with URI \"$uri\".\n";
}
}
},
summary => sub($) {
my ($self) = @_;
my $windows = ${$self}{windows};
print 'Leaked ' . keys(%{$windows}) . ' out of ' .
${$self}{count} . " DOM Windows\n";
}
},
"DOCUMENT" => {
count => 0,
docs => {},
handle_line => sub($$) {
my ($self, $line) = @_;
# This doesn't work; I don't have time to figure out why not.
# my $docs = ${$self}{docs};
my $docs = ${$handlers}{"DOCUMENT"}{docs};
if ($line =~ /^([0-9a-f]*) (\S*)/) {
my ($addr, $verb, $rest) = ($1, $2, $');
if ($verb eq "created") {
${$docs}{$addr} = {};
++${$self}{count};
} elsif ($verb eq "destroyed") {
delete ${$docs}{$addr};
} elsif ($verb eq "ResetToURI" ||
$verb eq "StartDocumentLoad") {
$rest =~ /^ (.*)$/ || die "URI expected";
my $uri = $1;
my $doc_info = ${$docs}{$addr};
${$doc_info}{$uri} = 1;
if (exists(${$doc_info}{"nim"})) {
${$doc_info}{"nim"}{$uri} = 1;
}
}
}
},
dump => sub ($) {
my ($self) = @_;
my $docs = ${$self}{docs};
foreach my $addr (keys(%{$docs})) {
print "Leaked document at address $addr.\n";
foreach my $uri (keys(%{${$docs}{$addr}})) {
print " ... with URI \"$uri\".\n" unless $uri eq "nim";
}
}
},
summary => sub($) {
my ($self) = @_;
my $docs = ${$self}{docs};
print 'Leaked ' . keys(%{$docs}) . ' out of ' .
${$self}{count} . " documents\n";
}
},
"DOCSHELL" => {
count => 0,
shells => {},
handle_line => sub($$) {
my ($self, $line) = @_;
my $shells = ${$self}{shells};
if ($line =~ /^([0-9a-f]*) (\S*)/) {
my ($addr, $verb, $rest) = ($1, $2, $');
if ($verb eq "created") {
${$shells}{$addr} = {};
++${$self}{count};
} elsif ($verb eq "destroyed") {
delete ${$shells}{$addr};
} elsif ($verb eq "InternalLoad" ||
$verb eq "SetCurrentURI") {
$rest =~ /^ (.*)$/ || die "URI expected";
my $uri = $1;
${${$shells}{$addr}}{$uri} = 1;
}
}
},
dump => sub ($) {
my ($self) = @_;
my $shells = ${$self}{shells};
foreach my $addr (keys(%{$shells})) {
print "Leaked docshell at address $addr.\n";
foreach my $uri (keys(%{${$shells}{$addr}})) {
print " ... which loaded URI \"$uri\".\n";
}
}
},
summary => sub($) {
my ($self) = @_;
my $shells = ${$self}{shells};
print 'Leaked ' . keys(%{$shells}) . ' out of ' .
${$self}{count} . " docshells\n";
}
},
"NODEINFOMANAGER" => {
count => 0,
nims => {},
handle_line => sub($$) {
my ($self, $line) = @_;
my $nims = ${$self}{nims};
if ($line =~ /^([0-9a-f]*) (\S*)/) {
my ($addr, $verb, $rest) = ($1, $2, $');
if ($verb eq "created") {
${$nims}{$addr} = {};
++${$self}{count};
} elsif ($verb eq "destroyed") {
delete ${$nims}{$addr};
} elsif ($verb eq "Init") {
$rest =~ /^ document=(.*)$/ ||
die "document pointer expected";
my $doc = $1;
if ($doc ne "0") {
my $nim_info = ${$nims}{$addr};
my $doc_info = ${$handlers}{"DOCUMENT"}{docs}{$doc};
foreach my $uri (keys(%{$doc_info})) {
${$nim_info}{$uri} = 1;
}
${$doc_info}{"nim"} = $nim_info;
}
}
}
},
dump => sub ($) {
my ($self) = @_;
my $nims = ${$self}{nims};
foreach my $addr (keys(%{$nims})) {
print "Leaked content nodes associated with node info manager at address $addr.\n";
foreach my $uri (keys(%{${$nims}{$addr}})) {
print " ... with document URI \"$uri\".\n";
}
}
},
summary => sub($) {
my ($self) = @_;
my $nims = ${$self}{nims};
print 'Leaked content nodes within ' . keys(%{$nims}) . ' out of ' .
${$self}{count} . " documents\n";
}
}
};
while (<>) {
# strip off initial "-", thread id, and thread pointer; separate
# first word and rest
if (/^\-?[0-9]*\[[0-9a-f]*\]: (\S*) ([^\n\r]*)[\n\r]*$/) {
my ($handler, $data) = ($1, $2);
if (defined(${$handlers}{$handler})) {
call("handle_line", ${$handlers}{$handler}, $data);
}
}
}
foreach my $key (keys(%{$handlers})) {
call("dump", ${$handlers}{$key});
}
print "Summary:\n";
foreach my $key (keys(%{$handlers})) {
call("summary", ${$handlers}{$key});
}