-
Notifications
You must be signed in to change notification settings - Fork 106
/
async.clj
175 lines (147 loc) · 4.62 KB
/
async.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
(ns manifold.stream.async
{:no-doc true}
(:require
[manifold.deferred :as d]
[clojure.core.async :as a]
[manifold.stream
[graph :as g]
[core :as s]]
[manifold
[executor :as executor]
[utils :as utils]])
(:import
[java.util.concurrent.atomic
AtomicReference]))
(s/def-source CoreAsyncSource
[ch ^AtomicReference last-take]
(isSynchronous [_] false)
(description [this]
{:source? true
:drained? (s/drained? this)
:type "core.async"})
(close [_]
(a/close! ch))
(take [this default-val blocking?]
(if blocking?
(let [x (a/<!! ch)]
(if (nil? x)
(do
(.markDrained this)
default-val)
x))
(let [d (d/deferred)
d' (.getAndSet last-take d)
f (fn [_]
(a/take! ch
(fn [msg]
(d/success! d
(if (nil? msg)
(do
(.markDrained this)
default-val)
msg)))))]
(if (d/realized? d')
(f nil)
(d/on-realized d' f f))
d)))
(take [this default-val blocking? timeout timeout-val]
(let [d (d/deferred)
d' (.getAndSet last-take d)
;; if I don't take this out of the goroutine, core.async OOMs on compilation
mark-drained #(.markDrained this)
f (fn [_]
(a/go
(let [result (a/alt!
ch ([x] (if (nil? x)
(do
(mark-drained)
default-val)
x))
(a/timeout timeout) timeout-val
:priority true)]
(d/success! d result))))]
(if (d/realized? d')
(f nil)
(d/on-realized d' f f))
(if blocking?
@d
d))))
(s/def-sink CoreAsyncSink
[ch ^AtomicReference last-put]
(isSynchronous [_] false)
(description [this]
{:sink? true
:closed? (s/closed? this)
:type "core.async"})
(close [this]
(utils/with-lock lock
(if (s/closed? this)
false
(do
(.markClosed this)
(let [d (.get last-put)
f (fn [_] (a/close! ch))]
(d/on-realized d
(fn [_] (a/close! ch))
nil)
true)))))
(put [this x blocking?]
(assert (not (nil? x)) "core.async channel cannot take `nil` as a message")
(utils/with-lock lock
(cond
(s/closed? this)
(if blocking?
false
(d/success-deferred false))
blocking?
(try
(a/>!! ch x)
true)
:else
(let [d (d/deferred)
d' (.getAndSet last-put d)
f (fn [_]
(a/go
(d/success! d
(boolean
(a/>! ch x)))))]
(if (d/realized? d')
(f nil)
(d/on-realized d' f f))
d))))
(put [this x blocking? timeout timeout-val]
(if (nil? timeout)
(.put this x blocking?)
(assert (not (nil? x)) "core.async channel cannot take `nil` as a message"))
(utils/with-lock lock
(if (s/closed? this)
(if blocking?
false
(d/success-deferred false))
(let [d (d/deferred)
d' (.getAndSet last-put d)
f (fn [_]
(a/go
(let [result (a/alt!
[[ch x]] true
(a/timeout timeout) timeout-val
:priority true)]
(d/success! d result))))]
(if (d/realized? d')
(f nil)
(d/on-realized d' f f))
(if blocking?
@d
d))))))
(extend-protocol s/Sinkable
clojure.core.async.impl.channels.ManyToManyChannel
(to-sink [ch]
(->CoreAsyncSink
ch
(AtomicReference. (d/success-deferred true)))))
(extend-protocol s/Sourceable
clojure.core.async.impl.channels.ManyToManyChannel
(to-source [ch]
(->CoreAsyncSource
ch
(AtomicReference. (d/success-deferred true)))))