-
-
Notifications
You must be signed in to change notification settings - Fork 149
/
project_tree.clj
164 lines (144 loc) · 5.19 KB
/
project_tree.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
(ns clojure-lsp.feature.project-tree
(:require
[clojure-lsp.queries :as q]
[clojure-lsp.shared :as shared]
[clojure.java.io :as io]))
(defn ^:private root-node [db]
(let [source-paths (:source-paths (:settings db))
project-root (io/file (str (shared/uri->path (:project-root-uri db))))]
{:name (.getName project-root)
:type :project
:nodes (concat
(mapv (fn [source-path]
{:name (shared/relativize-filepath source-path (.getCanonicalPath project-root))
:final false
:type :source-path})
(sort source-paths))
[{:name "External dependencies"
:id :external-dependencies
:final false
:type :library}])}))
(defn ^:private source-path-node [node db]
(let [source-path-uri (shared/filename->uri (shared/absolute-path (:name node) db) db)
namespace-definitions (q/find-all-path-namespace-definitions db source-path-uri)]
{:name (:name node)
:type (:type node)
:nodes (mapv
(fn [namespace-definition]
{:name (str (:name namespace-definition))
:uri (:uri namespace-definition)
:final false
:type :ns})
(sort-by :name namespace-definitions))}))
(defn ^:private external-dependencies-node [node db]
(let [uris (keys (q/external-analysis db))
jars (set (keep (fn [uri]
(second (re-find #"(.+)!/|::.*" uri)))
uris))]
{:name (:name node)
:type (:type node)
:id (:id node)
:nodes (mapv
(fn [jar-uri]
{:name (second (re-find (re-pattern (str ".+" (System/getProperty "file.separator") "(.+.jar$)")) jar-uri))
:detail jar-uri
:uri jar-uri
:final false
:type :jar})
jars)}))
(defn ^:private jar-node [node db]
(let [ns-definitions (q/find-all-path-namespace-definitions db (:uri node))
java-class-definitions (q/find-all-path-java-class-definitions db (:uri node))]
{:name (:name node)
:type (:type node)
:detail (:detail node)
:uri (:uri node)
:nodes (keep
(fn [element]
(case (:bucket element)
:namespace-definitions
{:name (str (:name element))
:uri (:uri element)
:final false
:type :ns}
:java-class-definitions
{:name (str (:class element))
:uri (:uri element)
:final true
:type :class}))
(concat ns-definitions java-class-definitions))}))
(defn ^:private ns-node [node db]
(let [var-definitions (q/find-var-definitions db (:uri node) true)]
{:name (:name node)
:type (:type node)
:uri (:uri node)
:nodes (mapv
(fn [element]
(shared/assoc-some
{:name (str (:name element))
:uri (:uri element)
:range (shared/->range element)
:final true
:type (q/element->symbol-kind element)}
:detail (when (:private element) "private")))
var-definitions)}))
(defn nodes [db current-node]
(cond
(not current-node)
(root-node db)
(= :source-path (:type current-node))
(source-path-node current-node db)
(and (= :library (:type current-node))
(= "external-dependencies" (:id current-node)))
(external-dependencies-node current-node db)
(= :jar (:type current-node))
(jar-node current-node db)
(= :ns (:type current-node))
(ns-node current-node db)))
(comment
;; workspace/projectTree/nodes - no args
{:name "clojure_sample"
:type :project
:nodes [{:name "src/main/clojure"
:uri "/user/project/src/main/clojure"
:final false
:type :source-path}
{:name "test/main/clojure"
:final false
:type :source-path}
{:name "External dependencies"
:id "external-dependencies"
:final false
:type :library}]}
;; workspace/projectTree/nodes - source-path
{:nodes [{:name "foo.bar"
:uri "file:///..."
:final false
:type :ns}]}
;; workspace/projectTree/nodes - external-dependencies
{:nodes [{:name "guava.jar"
:uri "jar://...."
:final false
:type :jar}]}
;; workspace/projectTree/nodes - jar with uri X
{:nodes [{:name "bla.Foo"
:uri "jar://...."
:detail "jar://...."
:final true
:type :class}]}
;; or
{:nodes [{:name "foo.bar"
:uri "jar://...."
:final false
:type :ns}]}
;; workspace/projectTree/nodes - ns
{:nodes [{:name "some-function"
:uri "file:///..."
:range {:start {:line 1 :character 2}
:end {:line 2 :character 3}}
:final true
:type :function
;; or :type :variable
;; or :type :class
;; or :type :interface
}]})