-
-
Notifications
You must be signed in to change notification settings - Fork 149
/
restructure_keys.clj
220 lines (207 loc) · 11.1 KB
/
restructure_keys.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
(ns clojure-lsp.feature.restructure-keys
(:require
[clojure-lsp.queries :as q]
[clojure-lsp.refactor.edit :as edit]
[clojure-lsp.shared :as shared]
[rewrite-clj.node :as n]
[rewrite-clj.zip :as z]))
(set! *warn-on-reflection* true)
(defn ^:private map-to-restructure [zloc uri db]
(when zloc
(let [{:keys [row col]} (meta (z/node zloc))
def-elem (q/find-definition-from-cursor db uri row col)
loc (or (when (and def-elem
(= :locals (:bucket def-elem)))
(when-let [up-loc (-> zloc
edit/to-top
(edit/find-at-pos (:row def-elem) (:col def-elem))
z/up)]
(cond-> up-loc
(= :vector (z/tag up-loc)) z/up)))
zloc)]
(when (seq (q/find-locals-under-form db uri (meta (z/node loc))))
(cond
(z/map? loc) {:replace-loc loc
:map-loc loc}
(z/namespaced-map? loc) (let [qualifier-loc (z/down loc)
{:keys [auto-resolved? prefix]} (z/node qualifier-loc)]
{:replace-loc loc
:map-loc (z/right qualifier-loc)
:map-auto-resolved? auto-resolved?
:map-ns prefix})
:else nil)))))
(defn can-restructure-keys? [zloc uri db]
(boolean (map-to-restructure zloc uri db)))
(defn ^:private z-children-seq [loc]
(->> loc
z/down
(iterate z/right)
(take-while (complement z/end?))))
(defn ^:private z-of-list [children]
(reduce z/append-child
(z/of-node (n/list-node []))
children))
(defn ^:private z-of-map [map-entries]
(reduce (fn [loc [k v]]
(z/assoc loc k v))
(z/of-node (n/map-node []))
map-entries))
(defn ^:private z-of-symbol [element-name]
(z/of-node (n/token-node element-name)))
(defn ^:private loc-kw-name [key-loc]
(let [key-sexpr (z/sexpr key-loc)]
(when (keyword? key-sexpr)
(name key-sexpr))))
(defn ^:private reference-elems [local-node db uri or-map-pos]
(let [local-meta (meta local-node)
elem (q/find-local-under-cursor db uri (:row local-meta) (:col local-meta))]
(cond->> (q/find-references db elem false)
or-map-pos (remove #(shared/inside? % {:name-row (:row or-map-pos)
:name-col (:col or-map-pos)
:name-end-row (:end-row or-map-pos)
:name-end-col (:end-col or-map-pos)})))))
(defn ^:private restructure-data [key-loc val-loc
db uri
or-map-pos
{:keys [map-ns map-auto-resolved?]}]
(let [key-sexpr (z/sexpr key-loc)]
(cond
;; {:keys [a]} and all its variations
(and (keyword? key-sexpr)
(contains? #{"keys" "syms"} (name key-sexpr)))
(let [k-node (z/node key-loc)
k-ns (namespace (:k k-node))
;; #:prefix{:_/keys [a]} -> (:a element)
ignore-implications? (= k-ns "_")
implied-ns (when-not ignore-implications?
(or k-ns map-ns))
implied-auto-resolved? (when-not ignore-implications?
(or (:auto-resolved? k-node)
map-auto-resolved?))
replace-with (case (name key-sexpr)
"keys"
(fn [local-node]
(let [local-sexpr (n/sexpr local-node)]
(cond
;; {:keys [::a]} -> (::a element)
;; {:keys [::my-alias/a]} -> (::my-alias/a element)
(:auto-resolved? local-node) local-node
;; {:keys [my-ns/a]} -> (:my-ns/a element)
;; {:keys [:my-ns/a]} -> (:my-ns/a element)
(qualified-ident? local-sexpr) (n/keyword-node (keyword local-sexpr))
;; {:my-ns/keys [a]} -> (:my-ns/a element)
;; #:my-ns{:keys [a]} -> (:my-ns/a element)
;; {::my-alias/keys [a]} -> (::my-alias/a element)
;; #::my-alias{:keys [a]} -> (::my-alias/a element)
implied-ns (n/keyword-node (keyword implied-ns (name local-sexpr)) implied-auto-resolved?)
;; {::keys [a]} -> (::a element)
;; #::{:keys [a]} -> (::a element)
implied-auto-resolved? (n/keyword-node (keyword local-sexpr) true)
;; {:keys [a]} -> (:a element)
:else (n/keyword-node (keyword local-sexpr)))))
"syms"
(fn [local-node]
(let [local-sexpr (n/sexpr local-node)]
(n/quote-node
(cond
;; {:syms [my-ns/a]} -> ('my-ns/a element)
;; {:syms [:my-ns/a]} -> ('my-ns/a element)
(qualified-ident? local-sexpr) (symbol local-sexpr)
;; {:my-ns/syms [a]} -> ('my-ns/a element)
;; #:my-ns{:syms [a]} -> ('my-ns/a element)
implied-ns (symbol implied-ns (name local-sexpr))
;; {:syms [a]} -> ('a element)
:else (symbol local-sexpr))))))]
(->> val-loc
z-children-seq
(map z/node)
(map (fn [local-node]
{:restructure? true
:replace-with (replace-with local-node)
:reference-elems (reference-elems local-node db uri or-map-pos)}))))
;; {a :a}
(symbol? key-sexpr)
[{:restructure? true
:replace-with (z/node val-loc)
:reference-elems (reference-elems (z/node key-loc) db uri or-map-pos)}]
;; {{:keys [a1]} :a}
:else
[{:restructure? false
:keep-key (z/node key-loc)
:keep-val (z/node val-loc)}])))
(defn ^:private restructure-edits
[{:keys [replace-with reference-elems]} element-name default-values]
(let [replacement (z-of-list [replace-with element-name])]
(map (fn [reference-elem]
{:range reference-elem
:loc (if-let [default-val (get default-values (:name reference-elem))]
(z-of-list ['get element-name replace-with default-val])
replacement)})
reference-elems)))
(defn ^:private unshadowed-element-name [db uri replace-loc]
(or (when-let [scope-loc (some-> replace-loc edit/find-op z/up)] ;; defn, let, etc.
(when-let [conflicting-names (->> (q/find-local-usages-under-form db uri (meta (z/node scope-loc)))
(map (comp str :name))
(keep #(re-find #"^element(-\d+)?$" %))
(map second) ;; "-1" or nil if original was just "element"
distinct
seq)]
(symbol
(str "element-"
(->> conflicting-names
(map (fn [dash-num]
(if dash-num
(Long/valueOf (subs dash-num 1))
0)))
(apply max)
inc)))))
'element))
(defn restructure-keys [zloc uri db]
(when-let [{:keys [map-loc replace-loc], :as restructure-config}
(map-to-restructure zloc uri db)]
(let [map-entry-locs (->> map-loc
z-children-seq
(partition 2))
as-loc (some->> map-entry-locs
(filter (fn [[key-loc _]] (= "as" (loc-kw-name key-loc))))
first
second)
or-map-loc (some->> map-entry-locs
(filter (fn [[key-loc _]] (= "or" (loc-kw-name key-loc))))
first
second)
provided-as (some-> as-loc z/sexpr)
element-name (or provided-as (unshadowed-element-name db uri replace-loc))
default-values (some-> or-map-loc z/sexpr)
or-map-pos (some-> or-map-loc z/node meta)
restructure-data (->> map-entry-locs
(remove (fn [[key-loc _]]
(contains? #{"as" "or"} (loc-kw-name key-loc))))
(mapcat (fn [[key-loc val-loc]]
(restructure-data key-loc val-loc
db uri
or-map-pos
restructure-config))))
restructurable-data (filter :restructure? restructure-data)
unrestructurable-data (remove :restructure? restructure-data)]
(when-let [restructure-edits (->> restructurable-data
(mapcat #(restructure-edits % element-name default-values))
seq)]
(conj restructure-edits
(if (seq unrestructurable-data)
;; keep map, removing as much of it as possible, and adding element-name
{:range (meta (z/node map-loc)) ;; not replace-loc, to preserve namespaced maps
:loc (let [map-entries (mapv (juxt :keep-key :keep-val)
unrestructurable-data)
remaining-default-values (->> restructurable-data
(mapcat :reference-elems)
(map :name)
distinct
(reduce dissoc default-values))
map-entries (cond-> map-entries
(seq remaining-default-values)
(conj [:or remaining-default-values]))]
(z-of-map (conj map-entries [:as element-name])))}
;; replace map with element-name
{:range (meta (z/node replace-loc))
:loc (z-of-symbol element-name)}))))))