tagof(<tag name>:) in a switch statement bug

[Daniel-Cortez]

This bug was originally discovered by @ziggi.

#include <console>
#include <float>

stock PrintInt(i)
    printf("int: %d\n", i);

stock PrintFloat(Float:f)
    printf("float: %f\n", f);

stock PrintBool(bool:b)
    printf("bool: %s\n", (b)?("true"):("false"));

stock Print({_, Float, bool}:arg, arg_tag=tagof(arg))
{
    switch(arg_tag)
    {
        case tagof(Float:):             // Line 17
            PrintFloat(Float:arg);
        case tagof(bool:):
            PrintBool(bool:arg);
        default:
            PrintInt(_:arg);
    }
}

main()
{
    print("--Function overloading emulation test--\n");
    Print(1);
    Print(1.0);
    Print(true);
}

When I try to compile this the compiler shows a bunch of error messages:

test.p(17) : error 081: expression with tag override must appear between parentheses
test.p(17) : error 029: invalid expression, assumed zero
test.p(19) : warning 217: loose indentation
test.p(19) : error 014: invalid statement; not in switch
test.p(19) : warning 215: expression has no effect
test.p(19) : error 001: expected token: ";", but found ":"
test.p(19) : error 029: invalid expression, assumed zero
test.p(19) : fatal error 107: too many error messages on one line
6 Errors.
Compilation aborted.

But if I put the tagof expressions into parentheses...

        case (tagof(Float:)):               // Line 17
            PrintFloat(Float:arg);
        case (tagof(bool:)):
            PrintBool(bool:arg);

... the code compiles and works normally.

[Daniel-Cortez]

Another bug related to the tagof operator:

#include <console>
#include <float>

stock PrintInt(i)
    printf("int: %d\n", i);

stock PrintFloat(Float:f)
    printf("float: %f\n", f);

stock PrintBool(bool:b)
    printf("bool: %s\n", (b)?("true"):("false"));

stock Print({_, Float, bool}:arg, arg_tag=tagof(arg))
{
    switch(arg_tag)
    {
        case (tagof(_:)):
            PrintInt(_:arg);
        case (tagof(Float:)):
            PrintFloat(Float:arg);
        case (tagof(bool:)):
            PrintBool(bool:arg);
    }
}

main()
{
    print("--Function overloading emulation test--\n");
    Print(1);
    Print(1.0);
    Print(true);
}

Output:

--Function overloading emulation test--
float: 1.00000
bool: true

Note the lack of the "int: 1" line.
I added some debug output to Print and main and commented out the remaining code in Print:

stock Print({_, Float, bool}:arg, arg_tag=tagof(arg))
{
    printf("arg_tag = %d\n", arg_tag);
    /*
    switch(arg_tag)
    {
        case (tagof(_:)):
            PrintInt(_:arg);
        case (tagof(Float:)):
            PrintFloat(Float:arg);
        case (tagof(bool:)):
            PrintBool(bool:arg);
    }
    */
}

main()
{
    print("--Function overloading emulation test--\n");
    printf("tagof(_:) = %d\n", tagof(_:));
    printf("tagof(Float:) = %d\n", tagof(Float:));
    printf("tagof(bool:) = %d\n", tagof(bool:));
    Print(1);
    Print(1.0);
    Print(true);
}

And here's what I got:

--Function overloading emulation test--
tagof(_:) = -(
tagof(Float:) = -1073741822
tagof(bool:) = -2147483647
arg_tag = 0
arg_tag = -1073741822
arg_tag = -2147483647

-( is supposed to be -2147483648 (which is another bug that is well known in the SA-MP community; not sure if it was reported here though).
So that means that tagof(_:) is -2147483648, but if I pass an integer to the Print function, arg_tag becomes 0 for some reason. For the other tags everything works normally.

[compuphase]

The bug is that tagof(_:) should be 0, not -2147483648.
The other issue is that -2147483648 cannot be printed; this is a bug in printf().

[compuphase]

Fixed in commit a25041a