-
Notifications
You must be signed in to change notification settings - Fork 59
/
ns_server_cert.erl
1093 lines (995 loc) · 40.5 KB
/
ns_server_cert.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%% @author Couchbase <info@couchbase.com>
%% @copyright 2013-Present Couchbase, Inc.
%%
%% Use of this software is governed by the Business Source License included
%% in the file licenses/BSL-Couchbase.txt. As of the Change Date specified
%% in that file, in accordance with the Business Source License, use of this
%% software will be governed by the Apache License, Version 2.0, included in
%% the file licenses/APL2.txt.
-module(ns_server_cert).
-include("ns_common.hrl").
-include("cut.hrl").
-include_lib("public_key/include/public_key.hrl").
-export([decode_cert_chain/1,
decode_single_certificate/1,
generate_and_set_cert_and_pkey/0,
this_node_ca/1,
this_node_uses_self_generated_certs/0,
this_node_uses_self_generated_certs/1,
self_generated_ca/0,
set_cluster_ca/1, %% deprecated
load_node_certs_from_inbox/1,
are_certs_loaded/0,
load_CAs_from_inbox/0,
add_CAs/2,
add_CAs/3,
remove_CA/1,
get_warnings/0,
get_subject_fields_by_type/2,
get_sub_alt_names_by_type/2,
get_node_cert_info/1,
tls_server_validation_options/0,
set_generated_ca/1,
validate_pkey/2,
get_chain_info/2,
trusted_CAs/1,
trusted_CAs_pre_NEO/1,
generate_node_certs/1,
filter_nodes_by_ca/2]).
inbox_ca_path() ->
filename:join(path_config:component_path(data, "inbox"), "CA").
inbox_chain_path() ->
filename:join(path_config:component_path(data, "inbox"), "chain.pem").
inbox_pkey_path() ->
filename:join(path_config:component_path(data, "inbox"), "pkey.key").
%% The CA that signed this node's cert.
%% Could be autogenerated or uploaded by user.
this_node_ca(Config) ->
CertProps = ns_config:search(Config, {node, node(), node_cert}, []),
proplists:get_value(ca, CertProps).
this_node_uses_self_generated_certs() ->
this_node_uses_self_generated_certs(ns_config:latest()).
this_node_uses_self_generated_certs(Config) ->
CertProps = ns_config:search(Config, {node, node(), node_cert}, []),
generated == proplists:get_value(type, CertProps).
self_generated_ca() ->
case ns_config:search(cert_and_pkey) of
{value, {CA, _}} -> CA;
%% for 7.0 mixed clusters
{value, {_, CA, _}} -> CA;
false ->
{CA, _} = generate_and_set_cert_and_pkey(false),
CA
end.
self_generated_ca_and_pkey() ->
case ns_config:search(cert_and_pkey) of
{value, {CA, PKey}} -> {CA, PKey};
%% for 7.0 mixed clusters
{value, {_, CA, PKey}} -> {CA, PKey};
false -> generate_and_set_cert_and_pkey(false)
end.
generate_and_set_cert_and_pkey() ->
generate_and_set_cert_and_pkey(true).
generate_and_set_cert_and_pkey(Force) ->
Pair = generate_cert_and_pkey(),
RV = ns_config:run_txn(
fun (Config, SetFn) ->
Existing =
case ns_config:search(Config, cert_and_pkey) of
{value, {_, _, undefined}} -> undefined;
{value, {_, undefined}} -> undefined;
false -> undefined;
{value, OtherPair} -> OtherPair
end,
case (Existing == undefined) or Force of
true -> {commit, SetFn(cert_and_pkey, Pair, Config)};
false -> {abort, Existing}
end
end),
case RV of
{abort, OtherPair} ->
OtherPair;
_ ->
case cluster_compat_mode:is_cluster_NEO() of
true ->
%% If we crash here the new cert will never get to
%% ca_certificates
{ok, _} = add_CAs(generated, element(1, Pair));
false ->
%% It will be added during online upgrade
ok
end,
Pair
end.
generate_cert_and_pkey() ->
StartTS = os:timestamp(),
Args = case ns_config:read_key_fast({cert, use_sha1}, false) of
true ->
["--use-sha1"];
false ->
[]
end,
RV = do_generate_cert_and_pkey(Args, []),
EndTS = os:timestamp(),
Diff = timer:now_diff(EndTS, StartTS),
?log_debug("Generated certificate and private key in ~p us", [Diff]),
RV.
generate_node_certs(Host) ->
{CAPEM, PKeyPEM} = self_generated_ca_and_pkey(),
generate_node_certs(CAPEM, PKeyPEM, Host).
generate_node_certs(_CAPEM, undefined, _Host) ->
no_private_key;
generate_node_certs(CAPEM, PKeyPEM, Host) ->
SANArg =
case misc:is_raw_ip(Host) of
true -> "--san-ip-addrs=" ++ Host;
false -> "--san-dns-names=" ++ Host
end,
%% CN can't be longer than 64 characters. Since it will be used for
%% displaying purposing only, it doesn't make sense to make it even
%% that long
HostShortened = case string:slice(Host, 0, 20) of
Host -> Host;
Shortened -> Shortened ++ "..."
end,
Args = ["--generate-leaf",
"--common-name=Couchbase Server Node (" ++ HostShortened ++ ")",
SANArg],
Env = [{"CACERT", binary_to_list(CAPEM)},
{"CAPKEY", binary_to_list(PKeyPEM)}],
{NodeCert, NodeKey} = do_generate_cert_and_pkey(Args, Env),
{CAPEM, NodeCert, NodeKey}.
do_generate_cert_and_pkey(Args, Env) ->
{Status, Output} = misc:run_external_tool(path_config:component_path(bin, "generate_cert"), Args, Env),
case Status of
0 ->
extract_cert_and_pkey(Output);
_ ->
erlang:exit({bad_generate_cert_exit, Status, Output})
end.
decode_cert_chain(CertPemBin) ->
Certs = split_certs(CertPemBin),
decode_cert_chain(Certs, []).
decode_cert_chain([], Res) -> {ok, lists:reverse(Res)};
decode_cert_chain([Cert | Tail], Res) ->
case decode_single_certificate(Cert) of
{error, _} = Err -> Err;
Der -> decode_cert_chain(Tail, [Der | Res])
end.
decode_single_certificate(CertPemBin) ->
case do_decode_certificates(CertPemBin) of
malformed_cert ->
{error, malformed_cert};
[PemEntry] ->
case validate_cert_pem_entry(PemEntry) of
{ok, {'Certificate', DerCert, not_encrypted}} -> DerCert;
{error, Reason} -> {error, Reason}
end;
[] ->
{error, malformed_cert};
[_|_] ->
{error, too_many_entries}
end.
decode_certificates(CertPemBin) ->
case do_decode_certificates(CertPemBin) of
malformed_cert ->
{error, malformed_cert};
PemEntries ->
lists:foldl(
fun (_E, {error, R}) -> {error, R};
(E, {ok, Acc}) ->
case validate_cert_pem_entry(E) of
{ok, Cert} -> {ok, [Cert | Acc]};
{error, R} -> {error, R}
end
end, {ok, []}, PemEntries)
end.
do_decode_certificates(CertPemBin) ->
try
public_key:pem_decode(CertPemBin)
catch T:E:S ->
?log_error("Unknown error while parsing certificate:~n~p",
[{T, E, S}]),
malformed_cert
end.
validate_cert_pem_entry({'Certificate', _, not_encrypted} = Cert) ->
{ok, Cert};
validate_cert_pem_entry({'Certificate', _, _}) ->
{error, encrypted_certificate};
validate_cert_pem_entry({BadType, _, _}) ->
{error, {invalid_certificate_type, BadType}}.
validate_pkey(PKeyPemBin, PassFun) ->
try public_key:pem_decode(PKeyPemBin) of
[{Type, _, not_encrypted} = Entry] ->
case Type of
'PrivateKeyInfo' ->
try element(1, public_key:pem_entry_decode(Entry)) of
'RSAPrivateKey' -> {ok, Entry};
'DSAPrivateKey' -> {ok, Entry};
Other ->
?log_debug("Invalid pkey type: ~p", [Other]),
{error, {invalid_pkey, Other}}
catch
_:Ex:ST ->
?log_error("Failed to decode pem entry: ~p~n~p",
[Ex, ST]),
{error, malformed_pkey}
end;
'RSAPrivateKey' ->
{ok, Entry};
'DSAPrivateKey' ->
{ok, Entry};
Other ->
?log_debug("Invalid pkey type: ~p", [Other]),
{error, {invalid_pkey, Type}}
end;
[{_Type, _, _CipherInfo} = Entry] ->
try element(1, public_key:pem_entry_decode(Entry, PassFun())) of
'RSAPrivateKey' -> {ok, Entry};
'DSAPrivateKey' -> {ok, Entry};
Other ->
?log_debug("Invalid pkey type: ~p", [Other]),
{error, {invalid_pkey, Other}}
catch
_:_ ->
?log_error("Could not decrypt private key, password might "
"be wrong"),
{error, could_not_decrypt}
end;
[] ->
{error, malformed_pkey};
Other ->
?log_debug("Too many (~p) pkey entries.", [length(Other)]),
{error, too_many_pkey_entries}
catch T:E:S ->
?log_error("Unknown error while parsing private key:~n~p",
[{T, E, S}]),
{error, malformed_pkey}
end.
validate_cert_and_pkey({'Certificate', DerCert, not_encrypted},
PKey, PassphraseFun) ->
case validate_pkey(PKey, PassphraseFun) of
{ok, DerKey} ->
DecodedCert = public_key:pkix_decode_cert(DerCert, otp),
TBSCert = DecodedCert#'OTPCertificate'.tbsCertificate,
PublicKeyInfo = TBSCert#'OTPTBSCertificate'.subjectPublicKeyInfo,
PublicKey = PublicKeyInfo#'OTPSubjectPublicKeyInfo'.subjectPublicKey,
DecodedKey = public_key:pem_entry_decode(DerKey, PassphraseFun()),
Msg = <<"1234567890">>,
Signature = public_key:sign(Msg, sha, DecodedKey),
case public_key:verify(Msg, sha, Signature, PublicKey) of
true ->
ok;
false ->
{error, cert_pkey_mismatch}
end;
Err ->
Err
end.
split_certs(PEMCerts) ->
Begin = <<"-----BEGIN">>,
[<<>> | Parts0] = binary:split(PEMCerts, Begin, [global]),
[<<Begin/binary,P/binary>> || P <- Parts0].
extract_cert_and_pkey(Output) ->
case split_certs(Output) of
[Cert, PKey] ->
case decode_single_certificate(Cert) of
{error, Error} ->
erlang:exit({bad_generated_cert, Cert, Error});
_ ->
%% We assume this function is used for self-generated
%% certs only, hence no password is used
case validate_pkey(PKey, fun () -> undefined end) of
{ok, _} ->
{Cert, PKey};
Err ->
erlang:exit({bad_generated_pkey, PKey, Err})
end
end;
Parts ->
erlang:exit({bad_generate_cert_output, Parts})
end.
attribute_string(?'id-at-countryName') ->
"C";
attribute_string(?'id-at-stateOrProvinceName') ->
"ST";
attribute_string(?'id-at-localityName') ->
"L";
attribute_string(?'id-at-organizationName') ->
"O";
attribute_string(?'id-at-commonName') ->
"CN";
attribute_string(_) ->
undefined.
format_attribute([#'AttributeTypeAndValue'{type = Type,
value = Value}], Acc) ->
case attribute_string(Type) of
undefined ->
Acc;
Str ->
[[Str, "=", format_value(Value)] | Acc]
end.
format_value({utf8String, Utf8Value}) ->
unicode:characters_to_list(Utf8Value);
format_value({_, Value}) when is_list(Value) ->
Value;
format_value(Value) when is_list(Value) ->
Value;
format_value(Value) ->
io_lib:format("~p", [Value]).
format_name({rdnSequence, STVList}) ->
Attributes = lists:foldl(fun format_attribute/2, [], STVList),
lists:flatten(string:join(lists:reverse(Attributes), ", ")).
extract_fields_by_type({rdnSequence, STVList}, Type) ->
[format_value(V) || [#'AttributeTypeAndValue'{type = T, value = V}] <- STVList,
T =:= Type];
extract_fields_by_type(_, _) ->
[].
convert_date(Year, Rest) ->
{ok, [Month, Day, Hour, Min, Sec], "Z"} = io_lib:fread("~2d~2d~2d~2d~2d", Rest),
calendar:datetime_to_gregorian_seconds({{Year, Month, Day}, {Hour, Min, Sec}}).
convert_date({utcTime, [Y1, Y2 | Rest]}) ->
Year =
case list_to_integer([Y1, Y2]) of
YY when YY < 50 ->
YY + 2000;
YY ->
YY + 1900
end,
convert_date(Year, Rest);
convert_date({generalTime, [Y1, Y2, Y3, Y4 | Rest]}) ->
Year = list_to_integer([Y1, Y2, Y3, Y4]),
convert_date(Year, Rest).
get_cert_info({'Certificate', DerCert, not_encrypted}) ->
get_der_info(DerCert).
get_der_info(DerCert) ->
Decoded = public_key:pkix_decode_cert(DerCert, otp),
TBSCert = Decoded#'OTPCertificate'.tbsCertificate,
Subject = format_name(TBSCert#'OTPTBSCertificate'.subject),
Validity = TBSCert#'OTPTBSCertificate'.validity,
NotBefore = convert_date(Validity#'Validity'.notBefore),
NotAfter = convert_date(Validity#'Validity'.notAfter),
{Subject, NotBefore, NotAfter}.
-spec get_subject_fields_by_type(binary(), term()) -> list() | {error, not_found}.
get_subject_fields_by_type(Cert, Type) ->
OtpCert = public_key:pkix_decode_cert(Cert, otp),
TBSCert = OtpCert#'OTPCertificate'.tbsCertificate,
case extract_fields_by_type(TBSCert#'OTPTBSCertificate'.subject, Type) of
[] ->
{error, not_found};
Vals ->
Vals
end.
-spec get_sub_alt_names_by_type(binary(), term()) -> list() | {error, not_found}.
get_sub_alt_names_by_type(Cert, Type) ->
OtpCert = public_key:pkix_decode_cert(Cert, otp),
TBSCert = OtpCert#'OTPCertificate'.tbsCertificate,
TBSExts = TBSCert#'OTPTBSCertificate'.extensions,
Exts = ssl_certificate:extensions_list(TBSExts),
case ssl_certificate:select_extension(?'id-ce-subjectAltName', Exts) of
{'Extension', _, _, Vals} ->
case [N || {T, N} <- Vals, T == Type] of
[] ->
{error, not_found};
V ->
V
end;
_ ->
{error, not_found}
end.
parse_cluster_ca(CA) ->
case decode_single_certificate(CA) of
{error, Error} ->
{error, Error};
RootCertDer ->
try
{Subject, NotBefore, NotAfter} = get_der_info(RootCertDer),
UTC = calendar:datetime_to_gregorian_seconds(
calendar:universal_time()),
case NotBefore > UTC orelse NotAfter < UTC of
true ->
{error, not_valid_at_this_time};
false ->
{ok, [{pem, CA},
{subject, Subject},
{expires, NotAfter}]}
end
catch T:E:S ->
?log_error("Failed to get certificate info:~n~p~n~p",
[RootCertDer, {T, E, S}]),
{error, malformed_cert}
end
end.
%% Deprecated. Can be used in pre-NEO clusters only.
set_cluster_ca(CA) ->
case parse_cluster_ca(CA) of
{ok, Props} ->
NewCert = proplists:get_value(pem, Props),
RV = ns_config:run_txn(
fun (Config, SetFn) ->
CurCerts =
case ns_config:search(Config, cert_and_pkey) of
{value, {NewCert, _}} ->
{error, already_in_use};
{value, {_, _} = Pair} ->
{ok, Pair};
{value, {_, GeneratedCert1, GeneratedKey1}} ->
{ok, {GeneratedCert1, GeneratedKey1}};
false ->
{ok, generate_cert_and_pkey()}
end,
case CurCerts of
{ok, {GeneratedCert, GeneratedKey}} ->
NewCertPKey = {Props, GeneratedCert,
GeneratedKey},
{commit, SetFn(cert_and_pkey, NewCertPKey,
Config)};
{error, Reason} ->
{abort, Reason}
end
end),
case RV of
{commit, _} ->
{ok, Props};
{abort, Reason} ->
{error, Reason};
retry_needed ->
erlang:error(exceeded_retries)
end;
{error, Error} ->
?log_error("Certificate authority validation failed with ~p", [Error]),
{error, Error}
end.
set_generated_ca(CA) ->
ns_config:set(cert_and_pkey, {CA, undefined}),
{ok, _} = add_CAs(generated, CA),
ok.
-record(verify_state, {last_subject, root_cert, chain_len}).
get_subject(Cert) ->
TBSCert = Cert#'OTPCertificate'.tbsCertificate,
format_name(TBSCert#'OTPTBSCertificate'.subject).
verify_fun(Cert, Event, State) ->
Subject = get_subject(Cert),
?log_debug("Certificate verification event:~n~p", [{Subject, Event}]),
case Event of
{bad_cert, invalid_issuer} ->
case State#verify_state.last_subject of
undefined ->
RootOtpCert = public_key:pkix_decode_cert(State#verify_state.root_cert, otp),
RootSubject = get_subject(RootOtpCert),
{fail, {invalid_root_issuer, Subject, RootSubject}};
LastSubject ->
{fail, {invalid_issuer, Subject, LastSubject}}
end;
{bad_cert, Error} ->
?log_error("Certificate ~p validation failed with reason: ~p",
[Subject, Error]),
Trace = erlang:process_info(self(), [current_stacktrace]),
OtpCert = public_key:pkix_decode_cert(State#verify_state.root_cert, otp),
InitValidationState =
pubkey_cert:init_validation_state(OtpCert, State#verify_state.chain_len, []),
?log_debug("Certificate validation trace:~n"
" Initial Context: ~p~n"
" Cert: ~p~n"
" Stack: ~p~n",
[InitValidationState, Cert, Trace]),
{fail, {Error, Subject}};
{extension, Ext} ->
?log_warning(
"Certificate ~p validation spotted an unknown extension:~n~p",
[Subject, Ext]),
{unknown, State};
valid ->
{valid, State#verify_state{last_subject = Subject}};
valid_peer ->
{valid, State}
end.
decode_chain(Chain) ->
try
lists:reverse(public_key:pem_decode(Chain))
catch T:E:S ->
?log_error("Unknown error while parsing certificate chain:~n~p",
[{T, E, S}]),
{error, {bad_chain, malformed_cert}}
end.
validate_chain([]) ->
ok;
validate_chain([Entry | Rest]) ->
case validate_cert_pem_entry(Entry) of
{error, Error} ->
{error, {bad_chain, Error}};
{ok, _} ->
validate_chain(Rest)
end.
validate_chain_signatures([], _Chain) ->
{error, no_ca};
validate_chain_signatures([CAProps | Tail], Chain) ->
CA = proplists:get_value(pem, CAProps),
CAId = proplists:get_value(id, CAProps),
[{'Certificate', RootCertDer, not_encrypted}] = public_key:pem_decode(CA),
DerChain = [Der || {'Certificate', Der, not_encrypted} <- Chain],
State = #verify_state{root_cert = RootCertDer,
chain_len = length(Chain)},
Options = [{verify_fun, {fun verify_fun/3, State}}],
case public_key:pkix_path_validation(RootCertDer, DerChain, Options) of
{ok, _} -> {ok, CA};
{error, Reason} ->
?log_warning("Chain validation failed with root cert #~p: ~p",
[CAId, Reason]),
validate_chain_signatures(Tail, Chain)
end.
decode_and_validate_chain(CAs, Chain) ->
case decode_chain(Chain) of
{error, _} = Err ->
Err;
[] ->
{error, {bad_chain, malformed_cert}};
PemEntriesReversed ->
case validate_chain(PemEntriesReversed) of
{error, _} = Err ->
Err;
ok ->
case validate_chain_signatures(CAs, PemEntriesReversed) of
{error, _} = Err ->
Err;
{ok, ChainCA} ->
[ChainCADecoded] = public_key:pem_decode(ChainCA),
case PemEntriesReversed of
[ChainCADecoded | Rest] -> {ok, ChainCA, Rest};
_ -> {ok, ChainCA, PemEntriesReversed}
end
end
end
end.
get_chain_info(Chain, CA) when is_binary(Chain), is_binary(CA) ->
lists:foldl(
fun (Cert, Acc) ->
{NewSub, _, NewExpiration} = get_cert_info(Cert),
case Acc of
undefined ->
{NewSub, NewExpiration};
{_Sub, Expiration} when Expiration > NewExpiration ->
{NewSub, NewExpiration};
{_Sub, Expiration} ->
{NewSub, Expiration}
end
end, undefined, public_key:pem_decode(CA) ++
lists:reverse(public_key:pem_decode(Chain))).
trusted_CAs(Format) ->
Certs =
case cluster_compat_mode:is_cluster_NEO() of
true ->
case chronicle_kv:get(kv, ca_certificates) of
{ok, {Cs, _}} -> Cs;
{error, not_found} -> []
end;
false ->
trusted_CAs_pre_NEO(ns_config:latest())
end,
SortedCerts = lists:sort(fun (PL1, PL2) ->
Id1 = proplists:get_value(id, PL1),
Id2 = proplists:get_value(id, PL2),
Id1 =< Id2
end, Certs),
case Format of
props ->
SortedCerts;
pem ->
[proplists:get_value(pem, Props) || Props <- SortedCerts];
der ->
lists:map(
fun (Props) ->
Pem = proplists:get_value(pem, Props),
decode_single_certificate(Pem)
end, SortedCerts)
end.
trusted_CAs_pre_NEO(Config) ->
CertAndPKey = ns_config:search(Config, cert_and_pkey),
Extra = [{origin, upgrade}],
SelfGeneratedCAs =
case CertAndPKey of
{value, {_, SGCA, _}} ->
Nodes = ns_node_disco:nodes_wanted(),
ShouldUseSelfGeneratedCA =
lists:any(
fun (N) ->
case ns_config:search(Config, {node, N, node_cert}) of
{value, Props} ->
generated == proplists:get_value(type, Props);
false ->
?log_error("Node ~p doesn't seem to have "
"node_cert key in ns_config", [N]),
true
end
end, Nodes),
case ShouldUseSelfGeneratedCA of
true ->
{ok, [SGCADecoded]} = decode_certificates(SGCA),
[[{id, 0} | cert_props(generated, SGCADecoded, Extra)]];
false ->
[]
end;
{value, {SGCA, _}} ->
{ok, [SGCADecoded]} = decode_certificates(SGCA),
[[{id, 0} | cert_props(generated, SGCADecoded, Extra)]];
false -> []
end,
UploadedCAs =
case CertAndPKey of
{value, {CAProps, _, _}} ->
CA = proplists:get_value(pem, CAProps),
{ok, [CADecoded]} = decode_certificates(CA),
[[{id, 1} | cert_props(uploaded, CADecoded, Extra)]];
_ -> []
end,
UploadedCAs ++ SelfGeneratedCAs.
load_node_certs_from_inbox(PassphraseSettings) ->
case file:read_file(inbox_chain_path()) of
{ok, Chain} ->
case file:read_file(inbox_pkey_path()) of
{ok, PKey} ->
set_node_certificate_chain(Chain, PKey, PassphraseSettings);
{error, Reason} ->
{error, {read_pkey, inbox_pkey_path(), Reason}}
end;
{error, Reason} ->
{error, {read_chain, inbox_chain_path(), Reason}}
end.
are_certs_loaded() ->
case file:read_file(inbox_chain_path()) of
{ok, Chain} ->
CurChain =
proplists:get_value(pem, get_node_cert_info(node()), <<>>),
[CurNodePemEntry | _] = public_key:pem_decode(CurChain),
case public_key:pem_decode(Chain) of
[CurNodePemEntry | _] -> true;
_ -> false
end;
{error, _} ->
false
end.
set_node_certificate_chain(Chain, PKey, PassphraseSettings) ->
case decode_and_validate_chain(trusted_CAs(props), Chain) of
{ok, CAPem, ChainEntriesReversed} ->
%% ChainReversed :: [Int cert,..., Node cert] (without CA)
ChainEntries = lists:reverse(ChainEntriesReversed),
NodeCert = hd(ChainEntries),
ChainPem = public_key:pem_encode(ChainEntries),
PassphraseFun = ns_secrets:get_fresh_pkey_pass(PassphraseSettings),
ValidationRes =
functools:sequence_(
[fun () ->
validate_cert_and_pkey(NodeCert, PKey, PassphraseFun)
end,
fun () ->
validate_otp_server_certs(CAPem, ChainPem, PKey,
PassphraseFun)
end]),
case ValidationRes of
ok ->
ns_ssl_services_setup:set_node_certificate_chain(
CAPem,
ChainPem,
PKey,
PassphraseSettings);
{error, Reason} ->
{error, Reason}
end;
{error, Reason} ->
{error, Reason}
end.
validate_otp_server_certs(CAPem, ChainPem, PKeyPem, PassphraseFun) ->
case cb_dist:external_encryption() of
true ->
with_test_otp_server(
fun (Port) ->
Opts = [{port, Port}],
Node = node(),
case ns_cluster:verify_otp_connectivity(Node, Opts) of
{ok, _} -> ok;
{error, _, Msg} ->
?log_error(
"Could not establish test connection to "
"test otp server at port ~p with reason: ~p",
[Port, Msg]),
Host = misc:extract_node_address(
Node, cb_dist:address_family()),
{error, {test_connection_failed, Host, Msg}}
end
end, CAPem, ChainPem, PKeyPem, PassphraseFun);
false -> ok
end.
with_test_otp_server(Fun, CAPem, ChainPem, PKeyPem, PassphraseFun) ->
[{server, CurrentServerOpts}] = ets:lookup(ssl_dist_opts, server),
CurrentServerOptsWithAF =
[cb_dist:address_family() | CurrentServerOpts],
ChainEntries = public_key:pem_decode(ChainPem),
ChainDer = [D || {'Certificate', D, not_encrypted} <- ChainEntries],
[{KeyType, _, _} = PKeyEntry] = public_key:pem_decode(PKeyPem),
PrivateKey = public_key:pem_entry_decode(PKeyEntry, PassphraseFun()),
{_, KeyDer, _} = public_key:pem_entry_encode(KeyType, PrivateKey),
CAEntries = public_key:pem_decode(CAPem),
CACertsDer = [D || {'Certificate', D, not_encrypted} <- CAEntries],
Erl22Cert = hd(ChainDer),
Erl22CA = tl(ChainDer) ++ CACertsDer,
ServerOpts = lists:map(
fun ({certfile, _}) -> {cert, Erl22Cert};
({keyfile, _}) -> {key, {KeyType, KeyDer}};
({cacertfile, _}) -> {cacerts, Erl22CA};
(O) -> O
end, CurrentServerOptsWithAF),
case ssl:listen(0, ServerOpts) of
{ok, LSocket} ->
Accepter = spawn(fun () ->
{ok, HS} = ssl:transport_accept(LSocket,
30000),
{ok, S} = ssl:handshake(HS, 30000),
receive
stop -> catch ssl:close(S)
after 30000 -> ok
end
end),
try
{ok, {_, Port}} = ssl:sockname(LSocket),
?log_info("Started test server on port ~p for certs "
"validation", [Port]),
Fun(Port)
catch
_:E:ST ->
?log_error("Unexpected exception: ~p~n~p", [E, ST]),
{error, {test_server_error, unexpected_exception}}
after
Accepter ! stop,
catch ssl:close(LSocket)
end;
{error, Reason} ->
{error, {test_server_error, Reason}}
end.
add_CAs(Type, Pem) ->
add_CAs(Type, Pem, []).
add_CAs(Type, Pem, Opts) when is_binary(Pem),
(Type =:= uploaded) or (Type =:= generated) ->
SingleCert = proplists:get_bool(single_cert, Opts),
case decode_certificates(Pem) of
{ok, PemEntries} when SingleCert,
length(PemEntries) > 1 ->
{error, too_many_entries};
{ok, PemEntries} ->
load_CAs([cert_props(Type, E, []) || E <- PemEntries]);
{error, Reason} ->
{error, Reason}
end.
remove_CA(Id) ->
Res =
chronicle_kv:transaction(
kv, [ca_certificates, nodes_wanted],
fun (Snapshot) ->
{CAs, _Rev} = maps:get(ca_certificates, Snapshot,
{[], undefined}),
{Nodes, _NodesRev} = maps:get(nodes_wanted, Snapshot),
case lists:search(lists:member({id, Id}, _), CAs) of
{value, Props} ->
CA = proplists:get_value(pem, Props, <<>>),
%% If a node cert is being uploaded at the same time,
%% it might not be added in ns_config yet by the time
%% we do this check. Because of this race condition it is
%% actually possible that we remove CA that is "in use"
%% by some node. It seems to be pretty hard to avoid this
%% race with node_cert stored in ns_config, as we don't
%% have common chronicle-ns_config transactions.
NodesThatUseCA = filter_nodes_by_ca(Nodes, CA),
case NodesThatUseCA of
[] ->
ToSet = lists:delete(Props, CAs),
{commit, [{set, ca_certificates, ToSet}], Props};
[_ | _] ->
{abort, {error, {in_use, NodesThatUseCA}}}
end;
false ->
{abort, {error, not_found}}
end
end, #{}),
case Res of
{ok, _, Props} -> {ok, Props};
{error, Reason} -> {error, Reason}
end.
filter_nodes_by_ca(Nodes, CAPem) ->
CA = public_key:pem_decode(CAPem),
lists:filter(
fun (N) ->
CProps = ns_config:read_key_fast({node, N, node_cert}, []),
CertCAPem = proplists:get_value(ca, CProps, <<>>),
CA =:= public_key:pem_decode(CertCAPem)
end, Nodes).
load_CAs_from_inbox() ->
CAInbox = inbox_ca_path(),
case read_CAs(CAInbox) of
{ok, []} ->
{error, {CAInbox, empty}};
{ok, NewCAs} ->
load_CAs(NewCAs);
{error, R} ->
{error, R}
end.
load_CAs(CAPropsList) ->
UTCTime = calendar:universal_time(),
LoadTime = calendar:datetime_to_gregorian_seconds(UTCTime),
{ok, _, AddedCAs} =
chronicle_kv:transaction(
kv, [ca_certificates],
fun (Snapshot) ->
{CAs, _Rev} = maps:get(ca_certificates, Snapshot,
{[], undefined}),
ToSet = maybe_append_CA_certs(CAs, CAPropsList, LoadTime),
NewCAs = ToSet -- CAs,
{commit, [{set, ca_certificates, ToSet}], NewCAs}
end, #{}),
{ok, AddedCAs}.
maybe_append_CA_certs(CAs, [], _) ->
?log_error("Appending empty list of certs"),
CAs;
maybe_append_CA_certs(CAs, CAPropsList, LoadTime) ->
MaxId = lists:max([-1] ++ [proplists:get_value(id, CA) || CA <- CAs]),
{_, Res} = lists:foldl(
fun (NewCA, {NextId, Acc}) ->
L = lists:concat(
[public_key:pem_decode(proplists:get_value(pem, CA))
|| CA <- Acc]),
NewPem = proplists:get_value(pem, NewCA),
[NewPemDecoded] = public_key:pem_decode(NewPem),
case lists:member(NewPemDecoded, L) of
true ->
?log_info("Not adding the following CA cert as "
"it is already added: ~p", [NewPem]),
{NextId, Acc};
false ->
?log_info("Adding new CA cert with id ~p: ~p",
[NextId, NewPem]),
NewCA2 = [{id, NextId},
{load_timestamp, LoadTime} | NewCA],
{NextId + 1, [NewCA2 | Acc]}
end
end, {MaxId + 1, CAs}, CAPropsList),
Res.
read_CAs(CAPath) ->
case file:list_dir(CAPath) of
{ok, Files} ->
lists:foldl(
fun (_, {error, R}) -> {error, R};
(F, {ok, Acc}) ->
FullPath = filename:join(CAPath, F),
case read_ca_file(FullPath) of
{ok, CAPropsList} -> {ok, CAPropsList ++ Acc};
{error, R} -> {error, {FullPath, R}}
end
end, {ok, []}, Files);
{error, Reason} -> {error, {CAPath, {read, Reason}}}
end.
read_ca_file(Path) ->
case file:read_file(Path) of
{ok, CertPemBin} ->
case decode_certificates(CertPemBin) of
{ok, PemEntries} ->
Host = misc:extract_node_address(node()),
Extras = [{load_host, iolist_to_binary(Host)},
{load_file, iolist_to_binary(Path)}],
{ok, [cert_props(uploaded, E, Extras)
|| E <- PemEntries]};
{error, Reason} ->
{error, Reason}
end;
{error, Reason} ->
{error, {read, Reason}}
end.
cert_props(Type, DecodedCert, Extras) ->
{Sub, NotBefore, NotAfter} = get_cert_info(DecodedCert),
[{subject, iolist_to_binary(Sub)},
{not_before, NotBefore},
{not_after, NotAfter},
{type, Type},
{pem, public_key:pem_encode([DecodedCert])}] ++ Extras.
get_warnings() ->
Config = ns_config:get(),
Nodes = ns_node_disco:nodes_wanted(Config),
TrustedCAs = trusted_CAs(pem),
NodeWarnings =
lists:flatmap(
fun (Node) ->
Warnings =
case ns_config:search(Config, {node, Node, node_cert}) of
{value, Props} -> node_cert_warnings(TrustedCAs, Props);
false ->
%% Pre-NEO node:
case ns_config:search(Config, {node, Node, cert}) of
{value, Props} ->
node_cert_warnings(TrustedCAs, Props);
false ->
case ns_config:search(cert_and_pkey) of
{value, {_, _}} ->
[self_signed];
_ ->
[mismatch]