Passing blocks around returning value

[TPei]

Hey, I'm passing a block around but for some reason, the initially called method never gets a return value. I'm not sure if / what I am doing wrong. I tried different things:

class SomeClass
  # some methods omitted
  def self.wait_for(&block)
    self.new.wait_for &block
  end

  def wait_for
    create_spinner_fiber
    value = yield
    @finished = true
    value
  end
end

I also tried:

class SomeClass
  def self.wait_for(&block)
    self.new.wait_for { block.call }
  end

  def wait_for
    create_spinner_fiber
    value = yield
    @finished = true
    value
  end
end

Calling SomeClass.wait_for { 1 } always returns nil, while SomeClass.new.wait_for { 1 } returns 1

Crystal 0.22.0 [3c71228] (2017-04-20) LLVM 3.5.0

[bew]

You must specify the block's return type if you want to get a value back from a captured block:

class SomeClass
  def self.wait_for(&block : -> Int32)
    new.wait_for &block
  end

  def wait_for
    value = yield
    @finished = true
    value
  end
end

puts SomeClass.wait_for { 1 }

https://carc.in/#/r/28nh

This is fully documented in the docs: https://crystal-lang.org/docs/syntax_and_semantics/capturing_blocks.html

You should also look at: https://crystal-lang.org/docs/syntax_and_semantics/block_forwarding.html

Try to avoid forwarding blocks like this if doing yield is enough.

Your example can be rewritten without block capture as:

class SomeClass
  def self.wait_for
    new.wait_for { yield }
  end

  def wait_for
    value = yield
    @finished = true
    value
  end
end

puts SomeClass.wait_for { 1 }

https://carc.in/#/r/28ni