-
Notifications
You must be signed in to change notification settings - Fork 5
/
transformers.cue
166 lines (153 loc) · 3.4 KB
/
transformers.cue
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
package kubernetes
import (
"guku.io/devx/v1"
"guku.io/devx/v1/traits"
appsv1 "k8s.io/api/apps/v1"
corev1 "k8s.io/api/core/v1"
)
_#DeploymentResource: {
appsv1.#Deployment
$metadata: labels: driver: "kubernetes"
kind: "Deployment"
apiVersion: "apps/v1"
}
_#ServiceAccountResource: {
corev1.#ServiceAccount
$metadata: labels: driver: "kubernetes"
kind: "ServiceAccount"
apiVersion: "v1"
}
_#ServiceResource: {
corev1.#Service
$metadata: labels: driver: "kubernetes"
kind: "Service"
apiVersion: "v1"
}
#AddDeployment: v1.#Transformer & {
v1.#Component
traits.#Workload
$metadata: _
containers: _
appName: string | *$metadata.id
serviceAccountName: string | *$metadata.id
$resources: {
"\(appName)-deployment": _#DeploymentResource & {
metadata: {
name: appName
labels: app: appName
}
spec: {
selector: matchLabels: app: appName
template: {
metadata: {
annotations: {}
labels: app: appName
}
spec: {
"serviceAccountName": serviceAccountName
securityContext: {
runAsUser: 1099
runAsGroup: 1099
fsGroup: 1099
}
"containers": [
for k, container in containers {
{
name: k
image: container.image
command: container.command
args: container.args
env: [
for name, value in container.env {
{
"name": name
"value": value
}
},
]
if container.resources.limits.cpu != _|_ {
resources: limits: cpu: container.resources.limits.cpu
}
if container.resources.limits.memory != _|_ {
resources: limits: memory: container.resources.limits.memory
}
if container.resources.requests.cpu != _|_ {
resources: requests: cpu: container.resources.requests.cpu
}
if container.resources.requests.memory != _|_ {
resources: requests: memory: container.resources.requests.memory
}
}
},
]
}
}
}
}
"\(appName)-sa": _#ServiceAccountResource & {
metadata: {
name: serviceAccountName
labels: app: appName
}
}
}
}
#AddService: v1.#Transformer & {
v1.#Component
traits.#Exposable
$metadata: _
endpoints: _
appName: string | *$metadata.id
endpoints: default: host: appName
$resources: "\(appName)-svc": _#ServiceResource & {
metadata: name: "\(appName)"
spec: {
selector: app: "\(appName)"
ports: [
for p in endpoints.default.ports {
{
name: "\(p.port)"
port: p.port
}
},
]
}
}
}
#AddReplicas: v1.#Transformer & {
v1.#Component
traits.#Workload
traits.#Replicable
$metadata: _
replicas: _
appName: string | *$metadata.id
$resources: {
"\(appName)-deployment": _#DeploymentResource & {
spec: "replicas": replicas.min
}
}
}
#AddPodLabels: v1.#Transformer & {
v1.#Component
traits.#Workload
$metadata: _
podLabels: [string]: string
appName: string | *$metadata.id
$resources: {
"\(appName)-deployment": _#DeploymentResource & {
spec: template: metadata: labels: podLabels
}
}
}
#AddPodAnnotations: v1.#Transformer & {
v1.#Component
traits.#Workload
$metadata: _
podAnnotations: [string]: string
appName: string | *$metadata.id
$resources: {
"\(appName)-deployment": _#DeploymentResource & {
spec: template: metadata: annotations: podAnnotations
}
}
}