-
Notifications
You must be signed in to change notification settings - Fork 7
/
EcoreMerger.xtend
315 lines (267 loc) · 10.4 KB
/
EcoreMerger.xtend
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
package fr.inria.diverse.melange.lib
import com.google.inject.ImplementedBy
import com.google.inject.Inject
import java.util.List
import org.eclipse.emf.common.util.Diagnostic
import org.eclipse.emf.ecore.EAnnotation
import org.eclipse.emf.ecore.EAttribute
import org.eclipse.emf.ecore.EClass
import org.eclipse.emf.ecore.EClassifier
import org.eclipse.emf.ecore.EDataType
import org.eclipse.emf.ecore.EEnum
import org.eclipse.emf.ecore.ENamedElement
import org.eclipse.emf.ecore.EObject
import org.eclipse.emf.ecore.EOperation
import org.eclipse.emf.ecore.EPackage
import org.eclipse.emf.ecore.EParameter
import org.eclipse.emf.ecore.EReference
import org.eclipse.emf.ecore.EStructuralFeature
import org.eclipse.emf.ecore.EcoreFactory
import org.eclipse.emf.ecore.util.Diagnostician
import org.eclipse.emf.ecore.util.EcoreUtil
import org.eclipse.xtend.lib.annotations.Data
import org.eclipse.emf.ecore.EcorePackage
@ImplementedBy(PackageMergeMerger)
interface EcoreMerger {
/**
* Note: assuming that receiving and merged are valid wrt Ecore
*/
def EPackage merge(EPackage receiving, EPackage merged)
def List<EPackage> merge(List<EPackage> receiving, List<EPackage> merged)
def List<Conflict> getConflicts()
@Data
static class Conflict {
EObject receiving
EObject merged
EStructuralFeature feature
String message
Diagnostic emfDiagnostic
}
}
/**
* Inspired from UML2.5 PackageMerge specification,
* as refined by Dingel et al.
* "Understanding and improving UML package merge"
*
* - If any constraint is violated, EcoreMergerException is thrown
* - Which implies that any resulting EPackage is valid
* - Receiving package and resulting package are *different*. The
* receiving package does not play a dual role. Thus, the constraints
* on cycle detection do not make sense.
* - Ignores generics
* - Ignores constraints
* - The resulting EPackage is checked using Diagnostician
* - All elements inserted from the merged package are marked with an annotation
*/
class PackageMergeMerger implements EcoreMerger {
@Inject extension EcoreExtensions
List<Conflict> conflicts
static final String ORIGIN_ANNOTATION_SOURCE = "http://www.inria.fr/melange/origin"
override merge(EPackage receiving, EPackage merged) {
conflicts = newArrayList
val resulting = EcoreUtil::copy(receiving)
if (receiving === null || merged === null)
return null
if (receiving == merged || receiving.nsURI == merged.nsURI)
addConflict(receiving, merged, null, "Cannot merge packages with same URI")
if (receiving.allSubPkgs.contains(merged))
addConflict(receiving, merged, null, "Receiving package cannot contain merged package")
if (merged.allSubPkgs.contains(receiving))
addConflict(receiving, merged, null, "Merged package cannot contain receiving package")
// FIXME: We should check for forbidden cross-refs between receiving/merged
// but this is quite costly
if (receiving.doMatch(merged))
resulting.doMerge(merged)
if (!conflicts.empty)
return null
resulting.updateReferences
val diag = Diagnostician.INSTANCE.validate(resulting)
if (diag.severity != Diagnostic::OK) {
diag.children.forEach[d |
val diagSource = d.data.head
if (diagSource instanceof ENamedElement) {
diagSource.EAnnotations.filter[source == ORIGIN_ANNOTATION_SOURCE].forEach[ann |
val receivingElement = ann.references.head as ENamedElement
val feature = ann.references.get(1) as EStructuralFeature
addConflict(diagSource, receivingElement, feature, d)
]
}
]
return null
} else return resulting
}
def void updateReferences(EPackage pkg) {
EcoreUtil.ExternalCrossReferencer.find(pkg).forEach[o, s |
s.forEach[ss |
if (ss.EStructuralFeature !== null && !ss.EStructuralFeature.derived && !ss.EStructuralFeature.many) {
if (o instanceof EClassifier) {
val corresponding = pkg.EClassifiers.findFirst[name == o.name]
if (corresponding !== null)
ss.EObject.eSet(ss.EStructuralFeature, corresponding)
} else if (o instanceof EReference) {
if (o.EOpposite !== null) {
val correspondingCls = pkg.EClassifiers.findFirst[name == o.EContainingClass.name] as EClass
val correspondingRef = correspondingCls.EReferences.findFirst[name == o.name]
if (correspondingRef !== null)
ss.EObject.eSet(ss.EStructuralFeature, correspondingRef)
}
}
}
]
]
}
override merge(List<EPackage> receiving, List<EPackage> merged) {
merged.forEach[mergedPkg |
val correspondingPkg = receiving.findFirst[doMatch(mergedPkg)]
if (correspondingPkg !== null)
merge(correspondingPkg, mergedPkg)
else
receiving += EcoreUtil::copy(mergedPkg)
]
return receiving
}
private def dispatch boolean doMatch(ENamedElement rcv, ENamedElement merged) {
return false
}
private def dispatch boolean doMatch(EPackage rcv, EPackage merged) {
return rcv.name == merged.name
}
private def dispatch boolean doMatch(EClass rcv, EClass merged) {
return rcv.name == merged.name
}
private def dispatch boolean doMatch(EDataType rcv, EDataType merged) {
return rcv.name == merged.name
}
private def dispatch boolean doMatch(EEnum rcv, EEnum merged) {
return rcv.name == merged.name
}
private def dispatch boolean doMatch(EAttribute rcv, EAttribute merged) {
return
rcv.name == merged.name
&& typesMatch(rcv.EType, merged.EType)
}
private def dispatch boolean doMatch(EReference rcv, EReference merged) {
return
rcv.name == merged.name
&& typesMatch(rcv.EType, merged.EType)
}
private def dispatch boolean doMatch(EOperation rcv, EOperation merged) {
return
rcv.name == merged.name
&& typesMatch(rcv.EType, merged.EType)
}
private def dispatch boolean doMatch(EParameter rcv, EParameter merged) {
return rcv.name == merged.name
}
private def dispatch boolean doMatch(EAnnotation rcv, EAnnotation merged) {
return false // TODO
}
private def boolean typesMatch(EClassifier eA, EClassifier eB) {
return eA == eB || doTypesMatch(eA, eB)
}
private def dispatch boolean doTypesMatch(EClassifier eA, EClassifier eB) {
return false
}
private def dispatch boolean doTypesMatch(EClass clsA, EClass clsB) {
return
clsA.name == clsB.name
|| clsA.EAllSuperTypes.exists[name == clsB.name]
}
private def dispatch boolean doTypesMatch(EDataType dtA, EDataType dtB) {
// FIXME: Should we match instanceClass instead?
return dtA.name == dtB.name
}
private def dispatch boolean doTypesMatch(EEnum enumA, EEnum enumB) {
return enumA.name == enumB.name
}
private def dispatch void doMerge(EPackage rcv, EPackage merged) {
// TODO: what about URIs, prefix, etc. ?
doCollectionsMerge(rcv, EcorePackage.Literals.EPACKAGE__ECLASSIFIERS, rcv.EClassifiers, merged.EClassifiers)
doCollectionsMerge(rcv, EcorePackage.Literals.EPACKAGE__ESUBPACKAGES, rcv.ESubpackages, merged.ESubpackages)
}
private def dispatch void doMerge(EClass rcv, EClass merged) {
rcv.abstract = rcv.abstract && merged.abstract
rcv.interface = rcv.interface && merged.interface
doCollectionsMerge(rcv, EcorePackage.Literals.ECLASS__ESTRUCTURAL_FEATURES, rcv.EStructuralFeatures, merged.EStructuralFeatures)
doCollectionsMerge(rcv, EcorePackage.Literals.ECLASS__EOPERATIONS, rcv.EOperations, merged.EOperations)
doCollectionsMerge(rcv, EcorePackage.Literals.ECLASS__ESUPER_TYPES, rcv.ESuperTypes, merged.ESuperTypes)
}
private def dispatch void doMerge(EDataType rcv, EDataType merged) {
}
private def dispatch void doMerge(EEnum rcv, EEnum merged) {
}
private def dispatch void doMerge(EAttribute rcv, EAttribute merged) {
rcv.derived = rcv.derived || merged.derived
rcv.transient = rcv.transient || merged.transient
rcv.volatile = rcv.volatile || merged.volatile
rcv.unsettable = rcv.unsettable && merged.unsettable
rcv.changeable = rcv.changeable || merged.changeable
rcv.ordered = rcv.ordered || merged.ordered
rcv.unique = rcv.unique || merged.unique
rcv.lowerBound = #[rcv.lowerBound, merged.lowerBound].min
rcv.upperBound = maxBound(rcv.upperBound, merged.upperBound)
}
private def dispatch void doMerge(EReference rcv, EReference merged) {
rcv.derived = rcv.derived || merged.derived
rcv.transient = rcv.transient || merged.transient
rcv.volatile = rcv.volatile || merged.volatile
rcv.unsettable = rcv.unsettable && merged.unsettable
rcv.changeable = rcv.changeable || merged.changeable
rcv.ordered = rcv.ordered || merged.ordered
rcv.unique = rcv.unique || merged.unique
rcv.lowerBound = #[rcv.lowerBound, merged.lowerBound].min
rcv.upperBound = maxBound(rcv.upperBound, merged.upperBound)
if (rcv.containment != merged.containment)
addConflict(rcv, merged, null, "Conflicting containment values for reference")
}
private def dispatch void doMerge(EOperation rcv, EOperation merged) {
rcv.ordered = rcv.ordered || merged.ordered
rcv.unique = rcv.ordered || merged.unique
rcv.lowerBound = #[rcv.lowerBound, merged.lowerBound].min
rcv.upperBound = maxBound(rcv.upperBound, merged.upperBound)
}
private def dispatch void doMerge(EParameter rcv, EParameter merged) {
}
private def dispatch void doMerge(EAnnotation rcv, EAnnotation merged) {
}
private def <T extends ENamedElement> void deepCopy(ENamedElement context, EStructuralFeature f, List<T> receiving, T merged) {
receiving += EcoreUtil::copy(merged)
context.EAnnotations += EcoreFactory.eINSTANCE.createEAnnotation => [
source = ORIGIN_ANNOTATION_SOURCE
references += merged
references += f
]
}
private def <T extends ENamedElement> void doCollectionsMerge(ENamedElement context, EStructuralFeature f, List<T> rcv, List<T> merged) {
merged.forEach[m |
val match = rcv.findFirst[r | r.doMatch(m)]
if (match !== null)
match.doMerge(m)
else
deepCopy(context, f, rcv, m)
]
}
private def int maxBound(int a, int b) {
return
if (a == -1 || b == -1) -1
else #[a, b].max
}
private def void addConflict(ENamedElement rcv, ENamedElement merged, EStructuralFeature f, String message) {
addConflict(rcv, merged, f, message, null)
}
private def void addConflict(ENamedElement rcv, ENamedElement merged, EStructuralFeature f, Diagnostic d) {
addConflict(
rcv,
merged,
f,
'''Cannot merge «merged.uniqueId» with «rcv.uniqueId».«f.name»: «d.message»''',
d
)
}
private def void addConflict(ENamedElement rcv, ENamedElement merged, EStructuralFeature f, String message, Diagnostic d) {
conflicts += new Conflict(rcv, merged, f, message, d)
}
override List<Conflict> getConflicts() {
return conflicts
}
}