-
Notifications
You must be signed in to change notification settings - Fork 1
/
auth_provider.gleam
171 lines (157 loc) · 4.41 KB
/
auth_provider.gleam
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
import gleam/result
import gleam/option.{type Option, None, Some}
import glitch/api/auth.{type GetTokenRequest}
import glitch/error.{
type AuthError, type TwitchError, AccessTokenExpired, AuthError,
TokenFetcherFetchError, ValidateTokenError,
}
import glitch/types/access_token.{type AccessToken}
pub opaque type AuthProvider {
ClientCredentialsAuthProvider(
access_token: Option(AccessToken),
client_id: String,
client_secret: String,
)
RefreshingAuthProvider(
access_token: AccessToken,
client_id: String,
client_secret: String,
on_refresh: Option(fn(AccessToken) -> Nil),
)
StaticAuthProvider(access_token: AccessToken, client_id: String)
}
pub fn new_client_credentials_provider(
client_id: String,
client_secret: String,
) -> AuthProvider {
ClientCredentialsAuthProvider(None, client_id, client_secret)
}
pub fn new_static_provider(
access_token: AccessToken,
client_id: String,
) -> AuthProvider {
StaticAuthProvider(access_token, client_id)
}
pub fn new_refreshing_provider(
access_token: AccessToken,
client_id: String,
client_secret: String,
on_refresh: Option(fn(AccessToken) -> Nil),
) -> AuthProvider {
RefreshingAuthProvider(access_token, client_id, client_secret, on_refresh)
}
pub fn client_id(auth_provider: AuthProvider) -> String {
case auth_provider {
ClientCredentialsAuthProvider(_, client_id, _) -> client_id
RefreshingAuthProvider(_, client_id, _, _) -> client_id
StaticAuthProvider(_, client_id) -> client_id
}
}
pub fn access_token(
auth_provider: AuthProvider,
) -> Result(AccessToken, TwitchError) {
case auth_provider {
ClientCredentialsAuthProvider(access_token, client_id, client_secret) ->
access_token_for_client_credential_provider(
access_token,
client_id,
client_secret,
)
RefreshingAuthProvider(access_token, client_id, client_secret, on_refresh) -> {
access_token_for_refreshing_provider(
access_token,
client_id,
client_secret,
on_refresh,
)
}
StaticAuthProvider(access_token, ..) -> Ok(access_token)
}
}
fn access_token_for_client_credential_provider(
access_token: Option(AccessToken),
client_id: String,
client_secret: String,
) -> Result(AccessToken, TwitchError) {
case access_token {
None ->
fetch_token(auth.new_client_credentials_grant_request(
client_id,
client_secret,
))
Some(access_token) -> {
case
access_token.is_expired(access_token),
access_token.needs_validated(access_token)
{
True, _ -> Error(AuthError(AccessTokenExpired))
False, True -> {
use validate_token_response <- result.try(
auth.validate_token(access_token)
|> result.map_error(fn(error) {
AuthError(ValidateTokenError(error))
}),
)
Ok(access_token.set_expires_in(
access_token,
validate_token_response.expires_in,
))
}
False, False -> {
Ok(access_token)
}
}
}
}
}
fn access_token_for_refreshing_provider(
access_token: AccessToken,
client_id: String,
client_secret: String,
on_refresh: Option(fn(AccessToken) -> Nil),
) -> Result(AccessToken, TwitchError) {
case
access_token.is_expired(access_token),
access_token.needs_validated(access_token)
{
True, _ -> {
use refresh_token <- result.try(access_token.refresh_token(access_token))
let refresh_token_request =
auth.new_refresh_token_grant_request(
client_id,
client_secret,
refresh_token,
)
use refreshed_token <- result.try(auth.refresh_token(
refresh_token_request,
))
case on_refresh {
None -> Ok(refreshed_token)
Some(on_refresh) -> {
on_refresh(refreshed_token)
Ok(refreshed_token)
}
}
}
False, True -> {
use validate_token_response <- result.try(
auth.validate_token(access_token)
|> result.map_error(fn(error) { AuthError(ValidateTokenError(error)) }),
)
Ok(access_token.set_expires_in(
access_token,
validate_token_response.expires_in,
))
}
False, False -> {
Ok(access_token)
}
}
}
fn fetch_token(request: GetTokenRequest) {
request
|> auth.get_token
|> result.map_error(fn(error) {
AuthError(TokenFetcherFetchError(cause: error))
})
}