-
Notifications
You must be signed in to change notification settings - Fork 8
/
ZeroesOnesAndTwos.lean
291 lines (249 loc) · 10.5 KB
/
ZeroesOnesAndTwos.lean
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
/-
Copyright (c) 2023 David Renshaw. All rights reserved.
Released under Apache 2.0 license as described in the file LICENSE.
Authors: David Renshaw
-/
import Mathlib.Data.Nat.ModEq
import Mathlib.Data.Nat.Digits
import ProblemExtraction
problem_file { tags := [.NumberTheory] }
/-!
(From Mathematical Puzzles: A Connoisseur's Collection by Peter Winkler.)
Let n be a natural number. Prove that
(a) n has a (nonzero) multiple whose representation in base 10 contains
only zeroes and ones; and
(b) 2^n has a multiple whose representation contains only ones and twos.
-/
namespace ZerosOnesAndTwos
snip begin
def ones (b : ℕ) : ℕ → ℕ
| k => Nat.ofDigits b (List.replicate k 1)
lemma of_digits_zeros_eq_zero (b m : ℕ) : Nat.ofDigits b (List.replicate m 0) = 0 := by
induction' m with m ih
· dsimp only; rfl
· simp only [Nat.ofDigits, Nat.cast_zero, ih, mul_zero, add_zero]
lemma ones_add (b m n : ℕ) :
ones b (m + n) = ones b m + Nat.ofDigits b ((List.replicate m 0) ++ (List.replicate n 1)) := by
unfold ones; dsimp only
rw [List.replicate_add, Nat.ofDigits_append, Nat.ofDigits_append]
rw [List.length_replicate, List.length_replicate, of_digits_zeros_eq_zero, zero_add]
def map_mod (n : ℕ) (hn: 0 < n) (f : ℕ → ℕ) : ℕ → Fin n
| m => ⟨f m % n, Nat.mod_lt (f m) hn⟩
lemma pigeonhole (n : ℕ) (f : ℕ → Fin n) :
∃ a b : ℕ, a < b ∧ f a = f b :=
let ⟨a, b, hne, hfe⟩ := Finite.exists_ne_map_eq_of_infinite f
hne.lt_or_lt.elim (λ h ↦ ⟨a, b, h, hfe⟩) (λ h ↦ ⟨b, a, h, hfe.symm⟩)
lemma lemma_3 {a n : ℕ} (ha : 0 < a) (hm : a % n = 0) : (∃ k : ℕ+, a = n * k) := by
obtain ⟨k', hk'⟩ := exists_eq_mul_right_of_dvd (Nat.dvd_of_mod_eq_zero hm)
have hkp : 0 < k' := lt_of_mul_lt_mul_left' (hk' ▸ ha)
exact ⟨⟨k', hkp⟩, hk'⟩
lemma two_le_ten : (2 : ℕ) ≤ 10 := tsub_eq_zero_iff_le.mp rfl
lemma one_lt_ten : (2 : ℕ) ≤ 10 := tsub_eq_zero_iff_le.mp rfl
lemma one_le_ten : (1 : ℕ) ≤ 10 := tsub_eq_zero_iff_le.mp rfl
snip end
problem zeroes_and_ones
(n : ℕ) : ∃ k : ℕ+, ∀ e ∈ Nat.digits 10 (n * k), e = 0 ∨ e = 1 := by
obtain (hn0 : n = 0 ) | (hn : n > 0) := Nat.eq_zero_or_pos n
· use 1; rw [hn0]; simp
obtain ⟨a, b, hlt, hab⟩ := pigeonhole n (λm ↦ map_mod n hn (ones 10) m)
dsimp [map_mod] at hab
replace hab : ones 10 b % n = ones 10 a % n := (Fin.mk_eq_mk.mp hab).symm
change ones 10 b ≡ ones 10 a [MOD n] at hab
have hab2 := ones_add 10 a (b-a)
rw [Nat.add_sub_of_le (Nat.le_of_lt hlt)] at hab2
rw [hab2] at hab; clear hab2
have hab' : (Nat.ofDigits 10 ((List.replicate a 0) ++ (List.replicate (b-a) 1))) ≡ 0 [MOD n] :=
Nat.ModEq.add_left_cancel (Nat.ModEq.symm hab) rfl
obtain ⟨c, hc⟩ := Nat.exists_eq_add_of_le' (Nat.sub_pos_of_lt hlt)
have h8 : 0 < Nat.ofDigits 10 (List.replicate a 0 ++ List.replicate (b - a) 1) := by
rw [hc, List.replicate_succ]
calc 0 < 1 := zero_lt_one
_ ≤ List.sum (List.replicate a 0 ++ 1 :: List.replicate c 1) := by
rw [List.sum_append, List.sum_cons, List.sum_replicate, List.sum_replicate]
omega
_ ≤ Nat.ofDigits 10 (List.replicate a 0 ++ 1 :: List.replicate c 1) :=
Nat.sum_le_ofDigits _ one_le_ten
obtain ⟨k, hk⟩ := lemma_3 h8 hab'
use k
rw [←hk]
have h4 : ∀ (l : ℕ), l ∈ List.replicate a 0 ++ List.replicate (b - a) 1 → l < 10 := by
intro l hl
rw [List.mem_append, List.mem_replicate, List.mem_replicate] at hl
omega
have h5 : ∀ (h : List.replicate a 0 ++ List.replicate (b - a) 1 ≠ []),
List.getLast (List.replicate a 0 ++ List.replicate (b - a) 1) h ≠ 0 := by
rw [hc] at *
intro h6
have h7 : List.replicate (c+1) 1 ≠ [] := List.getLast?_isSome.mp rfl
have := List.getLast_append' (List.replicate a 0) _ h7
rw [this, List.getLast_replicate_succ]
exact Nat.one_ne_zero
rw [Nat.digits_ofDigits _ one_lt_ten _ h4 h5]
intro e he
rw [List.mem_append, List.mem_replicate, List.mem_replicate] at he
omega
snip begin
abbrev all_one_or_two (l : List ℕ) : Prop := ∀ e ∈ l, e = 1 ∨ e = 2
def prepend_one (n : ℕ) := 10 ^ (List.length (Nat.digits 10 n)) + n
lemma prepend_one_pos (n: ℕ) : 0 < prepend_one n := by
cases' n
· decide
· rw [prepend_one]; norm_num
lemma digits_len' (n : ℕ) (hn : 0 < n) :
List.length (Nat.digits 10 n) = 1 + List.length (Nat.digits 10 (n / 10)) := by
rw [Nat.digits_def' two_le_ten hn, List.length]
exact add_comm _ _
lemma prepend_one_div (n : ℕ) (hn : 0 < n) : prepend_one n / 10 = prepend_one (n / 10) := by
rw [prepend_one, prepend_one]
cases' n with n
· exact (Nat.lt_asymm hn hn).elim
· rw [digits_len' n.succ (Nat.succ_pos n)]
rw [pow_add, pow_one, add_comm]
rw [Nat.add_mul_div_left _ _ (Nat.succ_pos 9)]
exact add_comm _ _
lemma prepend_one_mod (n : ℕ) (hn : 0 < n) : prepend_one n % 10 = n % 10 := by
rw [prepend_one]
rw [Nat.digits_len _ _ two_le_ten (ne_of_gt hn)]
rw [pow_add, pow_one]
exact Nat.mul_add_mod' _ 10 n
lemma prepend_one_eq_append (n : ℕ) :
Nat.digits 10 (prepend_one n) = (Nat.digits 10 n) ++ [1] := by
induction' n using Nat.strong_induction_on with n' ih
cases' n' with n'
· simp_arith [prepend_one]
· rw [Nat.digits_def' two_le_ten (prepend_one_pos _)]
rw [prepend_one_div _ (Nat.succ_pos n')]
have hns : n'.succ / 10 < n'.succ := Nat.div_lt_self' n' 8
rw [ih _ hns]
rw [←List.cons_append]
rw [prepend_one_mod _ (Nat.succ_pos _), Nat.digits_def' two_le_ten (Nat.succ_pos n')]
lemma prepend_one_all_one_or_two (n : ℕ) (hn : all_one_or_two (Nat.digits 10 n)) :
all_one_or_two (Nat.digits 10 (prepend_one n)) := by
rw [prepend_one_eq_append, all_one_or_two]
rw [all_one_or_two] at hn
intro e he
rw [List.mem_append] at he
cases' he with he he
· exact hn e he
· rw [List.mem_singleton] at he
simp only [he, OfNat.one_ne_ofNat, or_false]
def prepend_two (n : ℕ) := 2 * (10 ^ (List.length (Nat.digits 10 n))) + n
lemma prepend_two_pos (n: ℕ) : 0 < prepend_two n := by
cases n
· norm_num [prepend_two]
· rw [prepend_two]; norm_num
lemma prepend_two_div (n : ℕ) (hn : 0 < n) : prepend_two n / 10 = prepend_two (n / 10) := by
rw [prepend_two, prepend_two]
cases' n with n
· cases Nat.lt_asymm hn hn
· rw [digits_len' n.succ (Nat.succ_pos n)]
rw [pow_add, pow_one, add_comm]
rw [←mul_left_comm]
rw [Nat.add_mul_div_left _ _ (Nat.succ_pos 9)]
exact add_comm _ _
lemma prepend_two_mod (n : ℕ) (hn : 0 < n) : prepend_two n % 10 = n % 10 := by
rw [prepend_two]
rw [Nat.digits_len _ _ two_le_ten (ne_of_gt hn)]
rw [pow_add, pow_one, ←mul_assoc]
exact Nat.mul_add_mod' _ 10 n
lemma prepend_two_eq_append (n : ℕ) :
Nat.digits 10 (prepend_two n) = (Nat.digits 10 n) ++ [2] := by
induction' n using Nat.strong_induction_on with n' ih
cases' n' with n'
· norm_num [prepend_two]
· rw [Nat.digits_def' two_le_ten (prepend_two_pos _)]
rw [prepend_two_div _ (Nat.succ_pos n')]
have hns : n'.succ / 10 < n'.succ := Nat.div_lt_self' n' 8
rw [ih _ hns]
rw [←List.cons_append]
rw [prepend_two_mod _ (Nat.succ_pos _), ←Nat.digits_def' two_le_ten (Nat.succ_pos n')]
lemma prepend_two_all_one_or_two (n : ℕ) (hn : all_one_or_two (Nat.digits 10 n)) :
all_one_or_two (Nat.digits 10 (prepend_two n)) := by
rw [prepend_two_eq_append, all_one_or_two]
rw [all_one_or_two] at hn
intro e he
rw [List.mem_append] at he
cases' he with he he
· exact hn e he
· rw [List.mem_singleton] at he
right; exact he
lemma factor_ten_pow (k : ℕ) : 10 ^ k = (2^k) * (5^k) := by
induction' k with k' ih
· simp only [pow_zero, mul_one]
· rw [pow_succ, pow_succ, pow_succ, ih]; ring
lemma even_5_pow_plus_one (n : ℕ) : 2 ∣ 5 ^ n + 1 := by
apply Nat.dvd_of_mod_eq_zero
rw [Nat.add_mod, Nat.pow_mod]
norm_num
lemma ones_and_twos_aux (n : ℕ) :
∃ k : ℕ+, (List.length (Nat.digits 10 (2^n.succ * k)) = n.succ) ∧
all_one_or_two (Nat.digits 10 (2^n.succ * k)) := by
induction' n with pn hpn
· use 1
norm_num [all_one_or_two]
obtain ⟨pk, hpk1, hpk2⟩ := hpn
/-
Adding a 1 or a 2 to the front of 2^pn.succ * pk increments it by 2^pn.succ * 5^pn.succ or
by 2^{pn.succ+1} * 5^pn.succ, in each case preserving divisibility by 2^pn.succ. Since the
two choices differ by 2^pn.succ * 5^pn.succ, one of them must actually achieve
divisibility by 2^{pn.succ+1}.
-/
obtain ⟨t, ht : ↑pk = t + t⟩ | ⟨t, ht : ↑pk = 2 * t + 1⟩ := (pk : ℕ).even_or_odd
· -- Even case. Prepend 2.
rw [← two_mul] at ht
have hd : 2 ^ pn.succ.succ ∣ prepend_two (2 ^ pn.succ * ↑pk) := by
rw [prepend_two, factor_ten_pow, hpk1, ht]
have hr : 2 * (2 ^ pn.succ * 5 ^ pn.succ) + 2 ^ pn.succ * (2 * t) =
2 ^ pn.succ.succ * (5 ^ pn.succ + t) := by
repeat rw [pow_succ]; ring_nf
rw [hr]
exact Dvd.intro (5 ^ Nat.succ pn + t) rfl
obtain ⟨k', hk'⟩ := hd
have hkp': 0 < k' := by
cases' k'
· exfalso
have hzz := prepend_two_pos (2 ^ pn.succ * ↑pk)
rw [Nat.mul_zero] at hk'
omega
· exact Nat.succ_pos _
use ⟨k', hkp'⟩
rw [PNat.mk_coe, ←hk']
constructor
· rw [prepend_two_eq_append]
rw [List.length_append, List.length_singleton, hpk1]
· exact prepend_two_all_one_or_two _ hpk2
· -- Odd case. Prepend 1.
have hd : 2 ^ pn.succ.succ ∣ prepend_one (2 ^ pn.succ * ↑pk) := by
rw [prepend_one, hpk1, factor_ten_pow, ht]
have h5 : 2 ^ pn.succ * 5 ^ pn.succ + 2 ^ pn.succ * (2 * t + 1) =
2^pn.succ * (2 * (2 * 5 ^ pn + t) + (5^pn + 1)) := by
repeat rw[pow_succ]; ring_nf
rw [h5]
obtain ⟨k5,hk5⟩:= even_5_pow_plus_one pn
rw [hk5]
have h5' : 2 ^ pn.succ * (2 * (2 * 5 ^ pn + t) + 2 * k5) =
2^pn.succ.succ * (2 * 5 ^ pn + t + k5) := by
repeat rw[pow_succ]; ring_nf
rw [h5']
exact Dvd.intro (2 * 5 ^ pn + t + k5) rfl
obtain ⟨k', hk'⟩ := hd
have hkp': 0 < k' := by
cases k'
· exfalso
have hzz := prepend_one_pos (2 ^ pn.succ * ↑pk)
rw[Nat.mul_zero] at hk'
omega
· exact Nat.succ_pos _
use ⟨k', hkp'⟩
rw [PNat.mk_coe,←hk']
constructor
· rw [prepend_one_eq_append]
rw [List.length_append, List.length_singleton, hpk1]
· exact prepend_one_all_one_or_two _ hpk2
snip end
problem ones_and_twos
(n : ℕ) : ∃ k : ℕ+, ∀ e ∈ Nat.digits 10 (2^n * k), e = 1 ∨ e = 2 := by
cases' n with n
· use 1; norm_num
· obtain ⟨k, _, hk2⟩ := ones_and_twos_aux n
exact ⟨k, hk2⟩