forked from Limecraft/ebu-mxfsdk
-
Notifications
You must be signed in to change notification settings - Fork 0
/
configure.ac
273 lines (213 loc) · 8.93 KB
/
configure.ac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
-----------------------------------------------------------------------------
dnl -- Extract package info
dnl-----------------------------------------------------------------------------
dnl extract package name and version from Version.h
m4_define([m4_EBUSDK_LIBRARY_NAME],
m4_esyscmd([(sed -n 's/^.*EBUSDK_LIBRARY_NAME[^\"]*\"\([^\"]*\)\"/\1/p' Version.h | tr -d '\n')]))
m4_define([m4_EBUSDK_VERSION_MAJOR],
m4_esyscmd([(sed -n 's/^.*EBUSDK_VERSION_MAJOR\ *\([0-9][0-9]*\)/\1/p' Version.h | tr -d '\n')]))
m4_define([m4_EBUSDK_VERSION_MINOR],
m4_esyscmd([(sed -n 's/^.*EBUSDK_VERSION_MINOR\ *\([0-9][0-9]*\)/\1/p' Version.h | tr -d '\n')]))
m4_define([m4_EBUSDK_VERSION_MICRO],
m4_esyscmd([(sed -n 's/^.*EBUSDK_VERSION_MICRO\ *\([0-9][0-9]*\)/\1/p' Version.h | tr -d '\n')]))
m4_define([m4_EBUSDK_VERSION],
m4_defn([m4_EBUSDK_VERSION_MAJOR]).m4_defn([m4_EBUSDK_VERSION_MINOR]).m4_defn([m4_EBUSDK_VERSION_MICRO]))
dnl-----------------------------------------------------------------------------
dnl -- Init
dnl-----------------------------------------------------------------------------
AC_INIT(m4_defn([m4_EBUSDK_LIBRARY_NAME]), m4_defn([m4_EBUSDK_VERSION]))
dnl AC_CONFIG_SRCDIR([src/common/BMXException.cpp])
AC_CONFIG_HEADER([config.h])
AC_CONFIG_MACRO_DIR([m4])
AM_INIT_AUTOMAKE
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
dnl-----------------------------------------------------------------------------
dnl -- Version
dnl-----------------------------------------------------------------------------
dnl CURRENT, REVISION, AGE
dnl - library source changed -> increment REVISION
dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
dnl - interfaces added -> increment AGE
dnl - interfaces removed -> AGE = 0
EBUSDK_LIBVERSION="4:0:0"
AC_SUBST(EBUSDK_LIBVERSION)
EBUSDK_MAJORMINOR=m4_defn([m4_EBUSDK_VERSION_MAJOR]).m4_defn([m4_EBUSDK_VERSION_MINOR])
AC_SUBST(EBUSDK_MAJORMINOR)
dnl-----------------------------------------------------------------------------
dnl -- Checks for programs.
dnl-----------------------------------------------------------------------------
AC_PROG_LIBTOOL
AC_PROG_CXX
AC_PROG_CC
AC_PROG_INSTALL
AC_CHECK_PROGS(MD5TOOL, [md5sum md5])
if test x"$MD5TOOL" = x"" ; then
AC_MSG_WARN(Missing md5sum/md5 tool. Cannot make check.)
fi
dnl-----------------------------------------------------------------------------
dnl -- Checks for libraries.
dnl-----------------------------------------------------------------------------
ORIGCFLAGS=$CFLAGS
if test x"$prefix" != x"NONE"; then
CFLAGS="${CFLAGS} -L${prefix}/lib -I${prefix}/include"
fi
dnl Check for UUID generation library
case "$host" in
*-*-*mingw*) os=win ;;
*-*-darwin*) os=mac ;;
esac
if test x"$os" = xwin; then
AC_CHECK_HEADER([windows.h],
[UUIDLIB="-lole32"],
AC_MSG_ERROR(No windows uuid generation function))
elif test x"$os" = xmac; then
UUIDLIB=""
else
AC_CHECK_LIB([uuid], [uuid_generate],
[UUIDLIB="-luuid"],
AC_MSG_ERROR(No uuid generation function))
fi
AC_SUBST(UUIDLIB)
AC_CHECK_LIB(uriparser,uriParseUriA,,
[AC_MSG_ERROR([liburiparser not found])])
if test x"$prefix" = x"NONE"; then
LIBURIPARSER_CFLAGS=""
LIBURIPARSER_LIBS="-luriparser"
else
LIBURIPARSER_CFLAGS="-I${prefix}/include"
LIBURIPARSER_LIBS="-L${prefix}/lib -luriparser"
fi
AC_SUBST(LIBURIPARSER_CFLAGS)
AC_SUBST(LIBURIPARSER_LIBS)
dnl version 0.7.2 has been tested
AC_COMPILE_IFELSE([AC_LANG_SOURCE([
#include <uriparser/Uri.h>
#if (defined(URI_VER_MAJOR) && defined(URI_VER_MINOR) && defined(URI_VER_RELEASE) \
&& ((URI_VER_MAJOR > 0) \
|| ((URI_VER_MAJOR == 0) && (URI_VER_MINOR > 7)) \
|| ((URI_VER_MAJOR == 0) && (URI_VER_MINOR == 7) && (URI_VER_RELEASE >= 2)) \
))
/* FINE */
#else
# error uriparser not recent enough
#endif
])],,[AC_MSG_ERROR([uriparser 0.7.2 or later is required, your copy is too old])])
CFLAGS=$ORIGCFLAGS
dnl-----------------------------------------------------------------------------
dnl -- Check for modules
dnl-----------------------------------------------------------------------------
LIBMXF_MAJORMINOR=1.0
LIBMXFPP_MAJORMINOR=${LIBMXF_MAJORMINOR}
BMX_MAJORMINOR=0.1
AC_SUBST(LIBMXF_MAJORMINOR)
AC_SUBST(LIBMXFPP_MAJORMINOR)
AC_SUBST(BMX_MAJORMINOR)
PKG_CHECK_MODULES(LIBMXF, libMXF-${LIBMXF_MAJORMINOR} >= 1.0.3)
AC_SUBST(LIBMXF_CFLAGS)
AC_SUBST(LIBMXF_LIBS)
PKG_CHECK_MODULES(LIBMXFPP, libMXF++-${LIBMXFPP_MAJORMINOR} >= 1.0.3)
AC_SUBST(LIBMXFPP_CFLAGS)
AC_SUBST(LIBMXFPP_LIBS)
PKG_CHECK_MODULES(BMX, bmx-${BMX_MAJORMINOR} >= 0.0.0)
AC_SUBST(BMX_CFLAGS)
AC_SUBST(BMX_LIBS)
dnl-----------------------------------------------------------------------------
dnl -- Checks for header files.
dnl-----------------------------------------------------------------------------
AC_CHECK_HEADERS([inttypes.h sys/time.h sys/timeb.h unistd.h])
dnl-----------------------------------------------------------------------------
dnl -- Checks for typedefs, structures, and compiler characteristics.
dnl-----------------------------------------------------------------------------
AC_HEADER_STDBOOL
AC_TYPE_INT16_T
AC_TYPE_INT32_T
AC_TYPE_INT64_T
AC_TYPE_INT8_T
AC_TYPE_SIZE_T
AC_TYPE_UINT16_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T
AC_TYPE_UINT8_T
dnl mingw doesn't support the 'z' printf format length modifier for size_t
case "$host" in
*-*-*mingw32) AC_DEFINE([PRIszt], ["u"], [Define printf size_t format specifier]) ;;
*) AC_DEFINE([PRIszt], ["zu"], [Define printf size_t format specifier])
esac
dnl-----------------------------------------------------------------------------
dnl -- Checks for library functions
dnl-----------------------------------------------------------------------------
AC_SYS_LARGEFILE
AC_FUNC_FSEEKO
AC_CHECK_FUNCS([getcwd gettimeofday memmove memset mkdir strerror])
dnl-----------------------------------------------------------------------------
dnl -- Compiler flags etc.
dnl-----------------------------------------------------------------------------
WARN_CFLAGS=
if test x"$GCC" = xyes; then
WARN_CFLAGS="-W -Wall"
fi
AC_SUBST(WARN_CFLAGS)
EBUSDK_CFLAGS="${WARN_CFLAGS} ${LIBMXF_CFLAGS} ${LIBMXFPP_CFLAGS} ${BMX_CFLAGS} \
${LIBURIPARSER_CFLAGS} -I\$(top_srcdir)/CustomMetadataSupport/include -I\$(top_srcdir)/EBUCoreProcessor/include -I\$(top_srcdir)/EBUCoreProcessor/include/xsd -I\$(top_srcdir)/Analyzer/include"
AC_SUBST(EBUSDK_CFLAGS)
EBUSDK_LIBADDLIBS="${UUIDLIB} ${LIBURIPARSER_LIBS} ${LIBMXF_LIBS} ${LIBMXFPP_LIBS} ${BMX_LIBS}"
AC_SUBST(EBUSDK_LIBADDLIBS)
EBUSDK_METADATA_LIBADDLIBS="\$(top_builddir)/CustomMetadataSupport/src/libebucustommetadatasupport.la -lxerces-c"
AC_SUBST(EBUSDK_METADATA_LIBADDLIBS)
EBUSDK_EBUCORE_LIBADDLIBS="\$(top_builddir)/EBUCoreProcessor/src/libebucore.la -lxerces-c"
AC_SUBST(EBUSDK_EBUCORE_LIBADDLIBS)
EBUSDK_ANALYZER_LIBADDLIBS="\$(top_builddir)/Analyzer/src/libebumxfanalyzer.la -lxerces-c"
AC_SUBST(EBUSDK_ANALYZER_LIBADDLIBS)
dnl EBUSDK_LDADDLIBS="${EBUSDK_LIBADDLIBS} ${EBUSDK_METADATA_LIBADDLIBS} ${EBUSDK_EBUCORE_LIBADDLIBS} ${EBUSDK_ANALYZER_LIBADDLIBS}"
EBUSDK_LDADDLIBS="${EBUSDK_LIBADDLIBS} ${EBUSDK_METADATA_LIBADDLIBS} ${EBUSDK_EBUCORE_LIBADDLIBS}"
AC_SUBST(EBUSDK_LDADDLIBS)
EBUSDK_ANALYZER_LDADDLIBS="${EBUSDK_LIBADDLIBS} ${EBUSDK_METADATA_LIBADDLIBS} ${EBUSDK_EBUCORE_LIBADDLIBS} ${EBUSDK_ANALYZER_LIBADDLIBS}"
AC_SUBST(EBUSDK_ANALYZER_LDADDLIBS)
dnl-----------------------------------------------------------------------------
dnl -- Package Config
dnl-----------------------------------------------------------------------------
pkgconfigdir="\$(libdir)/pkgconfig"
AC_SUBST(pkgconfigdir)
dnl add libraries to pkg config "Libs:" for static-only builds
if test x"$enable_shared" = xyes; then
PC_ADD_LIBS="-lebumxfanalyzer"
PC_ADD_PRIVATE_LIBS="${UUIDLIB} ${LIBURIPARSER_LIBS}"
else
PC_ADD_LIBS="${UUIDLIB} ${LIBURIPARSER_LIBS}"
PC_ADD_PRIVATE_LIBS=
fi
AC_SUBST(PC_ADD_LIBS)
AC_SUBST(PC_ADD_PRIVATE_LIBS)
dnl-----------------------------------------------------------------------------
dnl -- Config files
dnl-----------------------------------------------------------------------------
AC_CONFIG_FILES([
Makefile
CustomMetadataSupport/Makefile
CustomMetadataSupport/include/Makefile
CustomMetadataSupport/src/Makefile
EBUCoreProcessor/Makefile
EBUCoreProcessor/include/Makefile
EBUCoreProcessor/include/EBUCore_1_4/Makefile
EBUCoreProcessor/include/EBUCore_1_4/metadata/Makefile
EBUCoreProcessor/include/EBUCore_1_4/metadata/base/Makefile
EBUCoreProcessor/include/EBUCore_1_4/xsd/Makefile
EBUCoreProcessor/include/xsd/Makefile
EBUCoreProcessor/src/Makefile
EBUCoreProcessor/apps/Makefile
EBUCoreProcessor/apps/writers/Makefile
EBUCoreProcessor/apps/raw2bmx/Makefile
EBUCoreProcessor/apps/ebu2mxf/Makefile
EBUCoreProcessor/apps/mxf2ebu/Makefile
EBUCoreProcessor/apps/ebuaudio2mxf/Makefile
EBUCoreProcessor/tools/Makefile
EBUCoreProcessor/tools/gen_ebucore_classes/Makefile
EBUCoreProcessor/msvc_build/Makefile
EBUCoreProcessor/msvc_build/vs10/Makefile
Analyzer/Makefile
Analyzer/include/Makefile
Analyzer/src/Makefile
Analyzer/apps/Makefile
Analyzer/apps/analyzer/Makefile
ebu-mxfsdk.pc])
AC_OUTPUT