-
Notifications
You must be signed in to change notification settings - Fork 169
/
CMakeLists.txt
604 lines (517 loc) · 25.2 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
# ========================= eCAL LICENSE =================================
#
# Copyright (C) 2016 - 2019 Continental Corporation
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
# ========================= eCAL LICENSE =================================
cmake_minimum_required(VERSION 3.15)
include(CMakeDependentOption)
if (POLICY CMP0077)
cmake_policy(SET CMP0077 NEW) # Prevent HDF5 from overwriting our output paths
endif (POLICY CMP0077)
list(APPEND CMAKE_MODULE_PATH
${CMAKE_CURRENT_SOURCE_DIR}/cmake
${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules)
set(eCAL_DIR ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules)
project(eCAL)
set(ECAL_PROJECT_ROOT "${CMAKE_CURRENT_LIST_DIR}")
# --------------------------------------------------------
# set msvc specific options
# --------------------------------------------------------
if(MSVC)
message(STATUS "MSVC detected - Adding flags")
set_property(GLOBAL PROPERTY USE_FOLDERS ON)
add_definitions(-D_SCL_SECURE_NO_WARNINGS -D_CRT_SECURE_NO_WARNINGS)
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP /W4")
# support Windows 7 and newer
add_definitions(-D_WIN32_WINNT=0x0601)
endif()
# --------------------------------------------------------
# set gcc specific options
# --------------------------------------------------------
if(UNIX)
message(STATUS "GCC detected - Adding flags")
add_definitions(-Wall -Wextra)
set(ATOMIC_TEST_CODE "
#include <atomic>
int main() { std::atomic<int64_t> i(0); i++; return 0; }
")
include(CheckCXXSourceCompiles)
check_cxx_source_compiles("${ATOMIC_TEST_CODE}" ATOMIC_IS_BUILTIN)
if (NOT ATOMIC_IS_BUILTIN)
message(STATUS "Adding -latomic flag, as this plattform does not support 64bit atomic operations out of the box.")
set(CMAKE_CXX_LINK_FLAGS "${CMAKE_CXX_LINK_FLAGS} -latomic")
endif ()
endif()
# --------------------------------------------------------
# command line build options
# use it that way cmake .. -DBUILD_APPS=ON -DBUILD_SAMPLES=ON
# --------------------------------------------------------
option(HAS_HDF5 "Platform supports HDF5 library" ON)
# If the user set the legacy HAS_QT5 option, but didn't set the new HAS_QT option, set it to the value of HAS_QT5
if(DEFINED HAS_QT5 AND NOT DEFINED HAS_QT)
set(HAS_QT ${HAS_QT5})
message(WARNING "The option HAS_QT5 is deprecated and may be removed at any time. Please use HAS_QT instead.")
endif()
option(HAS_QT "Platform supports Qt 5 / 6 library." ON)
option(HAS_CURL "Build with CURL (i.e. upload support in the recorder app)" ON)
option(HAS_CAPNPROTO "Platform supports Cap'n Proto library" OFF)
option(HAS_FLATBUFFERS "Platform supports flatbuffers library" OFF)
option(HAS_FTXUI "Platform supports FTXUI library. Requires C++17 and up." ON)
option(BUILD_DOCS "Build the eCAL documentation" OFF)
option(BUILD_APPS "Build the eCAL applications" ON)
option(BUILD_SAMPLES "Build the eCAL samples" ON)
option(BUILD_TIME "Build the eCAL time interfaces" ON)
option(BUILD_PY_BINDING "Build eCAL python binding" OFF)
option(BUILD_STANDALONE_PY_WHEEL "Build eCAL python binding as standalone wheel" OFF)
option(BUILD_CSHARP_BINDING "Build eCAL C# binding" OFF)
option(BUILD_ECAL_TESTS "Build the eCAL google tests" OFF)
option(ECAL_INCLUDE_PY_SAMPLES "Include python language sample projects into CMake" OFF)
option(ECAL_INSTALL_SAMPLE_SOURCES "Install the sources of eCAL samples" ON)
option(ECAL_NPCAP_SUPPORT "Enable the eCAL Npcap Receiver (i.e. the Win10 performance fix)" OFF)
option(ECAL_USE_CLOCKLOCK_MUTEX "Use native mutex with monotonic clock (requires glibc >= 2.30)" OFF)
# Set option regarding third party library builds
# option(ECAL_THIRDPARTY_BUILD_LIBSSH2 "Build libssh2 with eCAL" ON)
# option(ECAL_THIRDPARTY_BUILD_ZLIB "Build zlib with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_ASIO "Build asio with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_CMAKE_FUNCTIONS "Build CMakeFunctions with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_FINEFTP "Build fineFTP with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_FTXUI "Build ftxui with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_GTEST "Build gtest with eCAL" OFF)
option(ECAL_THIRDPARTY_BUILD_RECYCLE "Build steinwurf::recylce with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_SPDLOG "Build spdlog with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_SIMPLEINI "Build simpleini with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_TCLAP "Build tclap library with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_TCP_PUBSUB "Build tcp_pubsub library with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_TERMCOLOR "Build termcolor with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_TINYXML2 "Build tinyxml2 with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_UDPCAP "Build udpcap library with eCAL" OFF)
if(WIN32)
option(ECAL_THIRDPARTY_BUILD_PROTOBUF "Build protobuf with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_YAML-CPP "Build yaml-cpp with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_CURL "Build CURL with eCAL" ON)
option(ECAL_THIRDPARTY_BUILD_HDF5 "Build HDF5 with eCAL" ON)
cmake_dependent_option(ECAL_THIRDPARTY_BUILD_QWT "Build qwt::qwt with eCAL" ON "HAS_QT" OFF)
option(BUILD_SHARED_LIBS "Build shared libraries; required off on MSVC" OFF)
else()
option(ECAL_THIRDPARTY_BUILD_PROTOBUF "Build protobuf with eCAL" OFF)
option(ECAL_THIRDPARTY_BUILD_YAML-CPP "Build yaml-cpp with eCAL" OFF)
option(ECAL_THIRDPARTY_BUILD_CURL "Build CURL with eCAL" OFF)
option(ECAL_THIRDPARTY_BUILD_HDF5 "Build HDF5 with eCAL" OFF)
cmake_dependent_option(ECAL_THIRDPARTY_BUILD_QWT "Build qwt::qwt with eCAL" OFF "HAS_QT" OFF)
# BUILD_SHARED_LIBS left undefined on non-MSVC to match prior behavior
endif()
# This should be ON, unless build ecal hdf5 for Matlab usage
option(ECAL_LINK_HDF5_SHARED "Link shared libs of HDF5" ON)
option(CPACK_PACK_WITH_INNOSETUP "Create Innosetup installer for the Windows build" ON)
set(ECAL_INSTALL_PYTHON_DIR "bin" CACHE PATH "Location to install the Python extension modules. Might be set by setupdtools install.")
set(ECAL_BUILD_VERSION "0.0.0" CACHE STRING "Inject a build version if not building from a git repository")
set(ECAL_CSHARP_BUILD_SAMPLES ${BUILD_SAMPLES})
# there is a CMake issue with testing threading availibility via TEST_RUN
if(${CMAKE_CROSSCOMPILING})
set(THREADS_PTHREAD_ARG "2" CACHE STRING "Forcibly set by CMakeLists.txt." FORCE)
endif()
include(build_location)
# find_project(eCAL calls shall be ignored, eCAL is build as part of the project)
set(as_subproject eCAL)
if(CMAKE_EXPORT_COMPILE_COMMANDS)
message(STATUS "Compilation database will be created")
else()
# to make it visible it is explicitly set to OFF
set(CMAKE_EXPORT_COMPILE_COMMANDS OFF)
endif()
# Normalize backslashes from Windows paths
file(TO_CMAKE_PATH "${CMAKE_MODULE_PATH}" CMAKE_MODULE_PATH)
file(TO_CMAKE_PATH "${CMAKE_PREFIX_PATH}" CMAKE_PREFIX_PATH)
message(STATUS "Module Path: ${CMAKE_MODULE_PATH}")
message(STATUS "Prefix Path: ${CMAKE_PREFIX_PATH}")
# --------------------------------------------------------
# detect qt library
# --------------------------------------------------------
if(MSVC)
if (HAS_QT)
find_package(QT NAMES Qt6 Qt5 COMPONENTS Core QUIET)
if (NOT "${QT_FOUND}")
include("cmake/qt_msvc_path.cmake")
autodetect_qt_msvc_dir()
endif()
endif()
endif()
if(MSVC)
message(STATUS "supress thirdparty warnings for windows platform ..")
set(CMAKE_CXX_FLAGS_OLD "${CMAKE_CXX_FLAGS}")
if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
string(REGEX REPLACE "/W[0-4]" "/W0" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
else()
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W0")
endif()
endif()
# This is a list of subprojects, that might be build with eCAL
# according to how options ECAL_BUILD_<SUBPROJECT> are set
set(possible_subprojects
asio
CMakeFunctions
CURL
fineftp
ftxui
GTest
HDF5
#libssh2
Protobuf
qwt
recycle
simpleini
spdlog
tclap
tcp_pubsub
termcolor
tinyxml2
udpcap
yaml-cpp
#zlib zlibstatic
)
# We should rename the option, but don't know how to do in in a
# backwards compatible way
set(ECAL_THIRDPARTY_BUILD_CMAKEFUNCTIONS ${ECAL_THIRDPARTY_BUILD_CMAKE_FUNCTIONS})
# if a package does need to be build, include the cmake file with build instructions
foreach (dep IN LISTS possible_subprojects)
string(TOUPPER ${dep} dep_upper)
string(TOLOWER ${dep} dep_lower)
if (ECAL_THIRDPARTY_BUILD_${dep_upper})
include(thirdparty/${dep_lower}/build-${dep_lower}.cmake)
endif ()
endforeach ()
if(MSVC)
message(STATUS "reset thirdparty warnings for windows platform ..")
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS_OLD}")
endif()
find_package(CMakeFunctions REQUIRED)
git_revision_information(DEFAULT ${ECAL_BUILD_VERSION})
set(eCAL_VERSION_MAJOR ${GIT_REVISION_MAJOR})
set(eCAL_VERSION_MINOR ${GIT_REVISION_MINOR})
set(eCAL_VERSION_PATCH ${GIT_REVISION_PATCH})
set(eCAL_VERSION_STRING ${eCAL_VERSION_MAJOR}.${eCAL_VERSION_MINOR}.${eCAL_VERSION_PATCH})
set(eCAL_VERSION ${eCAL_VERSION_STRING})
include(helper_functions/ecal_add_functions)
include(helper_functions/ecal_helper_functions)
include(helper_functions/ecal_install_functions)
include(helper_functions/ecal_python_functions)
if(MSVC)
set(eCAL_PLATFORM_TOOLSET ${CMAKE_VS_PLATFORM_TOOLSET})
endif()
# --------------------------------------------------------
# offer the user the choice of overriding the installation directories
# --------------------------------------------------------
set(INSTALL_LIB_DIR lib CACHE PATH "Installation directory for libraries")
set(INSTALL_BIN_DIR bin CACHE PATH "Installation directory for executables")
set(INSTALL_INCLUDE_DIR include CACHE PATH
"Installation directory for header files")
if(WIN32 AND NOT CYGWIN)
set(DEF_INSTALL_CMAKE_DIR CMake)
else()
set(DEF_INSTALL_CMAKE_DIR lib/CMake/eCAL)
endif()
set(INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH
"Installation directory for CMake files")
include(GNUInstallDirs)
set(eCAL_install_app_dir ${CMAKE_INSTALL_BINDIR})
set(eCAL_install_archive_dir ${CMAKE_INSTALL_LIBDIR})
set(eCAL_install_archive_dyn_dir ${CMAKE_INSTALL_LIBDIR})
set(eCAL_install_bin_dir ${CMAKE_INSTALL_BINDIR})
set(eCAL_install_cmake_dir ${CMAKE_INSTALL_LIBDIR}/cmake/eCAL)
set(eCAL_install_config_dir ${CMAKE_INSTALL_SYSCONFDIR}/ecal)
set(eCAL_install_doc_dir ${CMAKE_INSTALL_DOCDIR})
set(eCAL_install_include_dir ${CMAKE_INSTALL_INCLUDEDIR})
set(eCAL_install_lib_dir ${CMAKE_INSTALL_LIBDIR})
set(eCAL_install_samples_dir ${CMAKE_INSTALL_BINDIR})
set(eCAL_install_samples_src_dir ${CMAKE_INSTALL_DATADIR}/ecal/samples/)
set(eCAL_install_tests_dir ${CMAKE_INSTALL_BINDIR})
set(eCAL_config_dir ${CMAKE_CURRENT_BINARY_DIR}/_generated/)
set(eCAL_config ${eCAL_config_dir}/eCALConfig.cmake)
set(eCAL_config_version ${eCAL_config_dir}/eCALConfigVersion.cmake)
file(MAKE_DIRECTORY ${eCAL_config_dir})
if(WIN32)
set(eCAL_install_config_dir cfg)
set(eCAL_install_doc_dir doc)
set(eCAL_install_samples_dir samples/bin/)
set(eCAL_install_samples_src_dir samples/src/)
set(eCAL_install_tests_dir tests)
endif()
set(BUILD_DEPLOY_DIRECTORY ${CMAKE_BINARY_DIR}/_deploy)
set(THREADS_PREFER_PTHREAD_FLAG ON)
if(WIN32)
set(CMAKE_DEBUG_POSTFIX d)
set(CMAKE_MINSIZEREL_POSTFIX minsize)
set(CMAKE_RELWITHDEBINFO_POSTFIX reldbg)
endif()
# --------------------------------------------------------
# protobuf utilities
# --------------------------------------------------------
add_subdirectory(contrib/ecalproto)
# --------------------------------------------------------
# old ecal core protobuf interface (for compatibility)
# --------------------------------------------------------
add_subdirectory(ecal/pb)
# --------------------------------------------------------
# ecal core protobuf interface
# --------------------------------------------------------
add_subdirectory(ecal/core_pb)
# --------------------------------------------------------
# ecal app protobuf interface
# --------------------------------------------------------
add_subdirectory(app/app_pb)
# --------------------------------------------------------
# ecal core
# --------------------------------------------------------
add_subdirectory(ecal/service)
add_subdirectory(ecal/core)
# --------------------------------------------------------
# custom libs
# --------------------------------------------------------
add_subdirectory(lib/ThreadingUtils)
add_subdirectory(lib/CustomTclap)
add_subdirectory(lib/ecal_utils)
if(HAS_QT)
add_subdirectory(lib/CustomQt)
endif()
add_subdirectory(lib/EcalParser)
if(HAS_QT)
add_subdirectory(lib/QEcalParser)
endif()
# --------------------------------------------------------
# ecal mon plugin sdk
# --------------------------------------------------------
if(HAS_QT)
add_subdirectory(app/mon/mon_plugin_lib)
endif()
# --------------------------------------------------------
# ecal rec addon sdk
# --------------------------------------------------------
add_subdirectory(app/rec/rec_addon_core)
add_subdirectory(app/rec/rec_addon_dummy)
# --------------------------------------------------------
# ecal time
# --------------------------------------------------------
if(BUILD_TIME)
if(WIN32)
set(ECAL_TIME_PLUGIN_DIR ecaltime_plugins)
endif()
add_subdirectory(contrib/ecaltime)
endif()
# --------------------------------------------------------
# ecal hdf5 support
# --------------------------------------------------------
if(HAS_HDF5)
add_subdirectory(contrib/measurement/hdf5)
add_subdirectory(contrib/ecalhdf5)
add_subdirectory(contrib/message)
endif()
add_subdirectory(contrib/measurement/base)
# --------------------------------------------------------
# ecal core python binding
# --------------------------------------------------------
if(BUILD_PY_BINDING)
add_subdirectory(lang/python)
endif()
# --------------------------------------------------------
# ecal core csharp binding
# --------------------------------------------------------
if(BUILD_CSHARP_BINDING AND WIN32)
add_subdirectory(lang/csharp)
endif()
# --------------------------------------------------------
# console applications
# --------------------------------------------------------
add_subdirectory(app/apps)
if(BUILD_APPS)
if (HAS_FTXUI)
add_subdirectory(app/mon/mon_tui)
endif()
add_subdirectory(app/mon/mon_cli)
add_subdirectory(app/util/config)
add_subdirectory(app/util/stop)
add_subdirectory(app/sys/sys_core)
add_subdirectory(app/sys/sys_cli)
add_subdirectory(app/sys/sys_client_cli)
add_subdirectory(app/sys/sys_client_core)
if(NOT APPLE)
add_subdirectory(contrib/mma)
endif()
endif()
# --------------------------------------------------------
# applications using hdf5
# --------------------------------------------------------
if(BUILD_APPS AND HAS_HDF5)
add_subdirectory(app/play/play_core)
add_subdirectory(app/play/play_cli)
add_subdirectory(app/rec/rec_client_core)
add_subdirectory(app/rec/rec_server_core)
add_subdirectory(app/rec/rec_client_cli)
add_subdirectory(app/rec/rec_server_cli)
add_subdirectory(app/meas_cutter)
endif()
# --------------------------------------------------------
# qt applications
# --------------------------------------------------------
if(BUILD_APPS AND (HAS_QT))
add_subdirectory(app/sys/sys_gui)
add_subdirectory(app/mon/mon_gui)
if(WIN32)
set(ECAL_MON_PLUGIN_DIR ecalmon_plugins)
else()
set(ECAL_MON_PLUGIN_DIR ecal/plugins/mon)
endif()
add_subdirectory(app/mon/mon_plugins)
add_subdirectory(app/util/launcher)
# --------------------------------------------------------
# qt applications using hdf5
# --------------------------------------------------------
if(HAS_HDF5)
add_subdirectory(app/play/play_gui)
add_subdirectory(app/rec/rec_gui)
endif()
endif()
# --------------------------------------------------------
# samples
# --------------------------------------------------------
if(BUILD_SAMPLES)
add_subdirectory(samples)
endif()
# --------------------------------------------------------
# unit tests
# --------------------------------------------------------
if(BUILD_ECAL_TESTS)
enable_testing()
# ------------------------------------------------------
# test contrib
# ------------------------------------------------------
if(HAS_HDF5)
add_subdirectory(testing/contrib/ecalhdf5/hdf5_test)
endif()
add_subdirectory(testing/contrib/ecalproto/dynproto_test)
add_subdirectory(testing/contrib/ecalproto/ecal_proto_test)
# ------------------------------------------------------
# test ecal
# ------------------------------------------------------
add_subdirectory(testing/ecal/clientserver_test)
add_subdirectory(testing/ecal/core_test)
add_subdirectory(testing/ecal/event_test)
add_subdirectory(testing/ecal/expmap_test)
add_subdirectory(testing/ecal/io_memfile_test)
add_subdirectory(testing/ecal/pubsub_inproc_test)
add_subdirectory(testing/ecal/pubsub_proto_test)
add_subdirectory(testing/ecal/pubsub_test)
add_subdirectory(testing/ecal/topic2mcast_test)
add_subdirectory(testing/ecal/util_test)
# ------------------------------------------------------
# test apps
# ------------------------------------------------------
if (HAS_HDF5 AND HAS_QT)
add_subdirectory(app/rec/rec_tests/rec_rpc_tests)
endif()
endif()
# --------------------------------------------------------
# configs
# --------------------------------------------------------
add_subdirectory(ecal/core/cfg)
if(BUILD_DOCS)
add_subdirectory(doc)
endif()
# --------------------------------------------------------
# debscripts
# --------------------------------------------------------
if (UNIX)
add_subdirectory(cpack/debscripts)
endif()
#install(EXPORT eCALTargets DESTINATION cmake NAMESPACE eCAL::)
include(CMakePackageConfigHelpers)
write_basic_package_version_file(
${eCAL_config_version}
VERSION ${eCAL_VERSION}
COMPATIBILITY SameMajorVersion
)
configure_package_config_file(
cmake/${PROJECT_NAME}Config.cmake.in
${eCAL_config}
INSTALL_DESTINATION ${${PROJECT_NAME}_install_cmake_dir}
PATH_VARS ${PROJECT_NAME}_install_include_dir ${PROJECT_NAME}_install_cmake_dir
)
install(FILES ${eCAL_config} ${eCAL_config_version}
DESTINATION ${eCAL_install_cmake_dir}
COMPONENT sdk
)
install(FILES
cmake/helper_functions/ecal_add_functions.cmake
cmake/helper_functions/ecal_helper_functions.cmake
cmake/helper_functions/ecal_install_functions.cmake
DESTINATION ${${PROJECT_NAME}_install_cmake_dir}/helper_functions
COMPONENT sdk
)
install(EXPORT eCALCoreTargets
FILE ${PROJECT_NAME}Targets.cmake
DESTINATION ${eCAL_install_cmake_dir}
NAMESPACE eCAL::
COMPONENT sdk
)
if(ECAL_INSTALL_SAMPLE_SOURCES)
install(DIRECTORY samples/
DESTINATION ${eCAL_install_samples_src_dir}
)
endif()
# --------------------------------------------------------
# create package
# --------------------------------------------------------
include(cpack/cpack_variables.cmake)
message(STATUS "Build Options:")
message(STATUS "--------------------------------------------------------------------------------")
message(STATUS "CMAKE_EXPORT_COMPILE_COMMANDS : ${CMAKE_EXPORT_COMPILE_COMMANDS}")
message(STATUS "HAS_HDF5 : ${HAS_HDF5}")
message(STATUS "HAS_QT : ${HAS_QT}")
message(STATUS "HAS_CURL : ${HAS_CURL}")
message(STATUS "HAS_CAPNPROTO : ${HAS_CAPNPROTO}")
message(STATUS "HAS_FLATBUFFERS : ${HAS_FLATBUFFERS}")
message(STATUS "HAS_FTXUI : ${HAS_FTXUI}")
message(STATUS "BUILD_SHARED_LIBS : ${BUILD_SHARED_LIBS}")
message(STATUS "BUILD_DOCS : ${BUILD_DOCS}")
message(STATUS "BUILD_APPS : ${BUILD_APPS}")
message(STATUS "BUILD_SAMPLES : ${BUILD_SAMPLES}")
message(STATUS "BUILD_TIME : ${BUILD_TIME}")
message(STATUS "BUILD_PY_BINDING : ${BUILD_PY_BINDING}")
message(STATUS "BUILD_STANDALONE_PY_WHEEL : ${BUILD_STANDALONE_PY_WHEEL}")
message(STATUS "BUILD_CSHARP_BINDING : ${BUILD_CSHARP_BINDING}")
message(STATUS "BUILD_ECAL_TESTS : ${BUILD_ECAL_TESTS}")
message(STATUS "ECAL_INCLUDE_PY_SAMPLES : ${ECAL_INCLUDE_PY_SAMPLES}")
message(STATUS "ECAL_INSTALL_SAMPLE_SOURCES : ${ECAL_INSTALL_SAMPLE_SOURCES}")
message(STATUS "ECAL_NPCAP_SUPPORT : ${ECAL_NPCAP_SUPPORT}")
message(STATUS "ECAL_THIRDPARTY_BUILD_ASIO : ${ECAL_THIRDPARTY_BUILD_ASIO}")
message(STATUS "ECAL_THIRDPARTY_BUILD_CMAKE_FUNCTIONS : ${ECAL_THIRDPARTY_BUILD_CMAKE_FUNCTIONS}")
message(STATUS "ECAL_THIRDPARTY_BUILD_CURL : ${ECAL_THIRDPARTY_BUILD_CURL}")
message(STATUS "ECAL_THIRDPARTY_BUILD_FINEFTP : ${ECAL_THIRDPARTY_BUILD_FINEFTP}")
message(STATUS "ECAL_THIRDPARTY_BUILD_FTXUI : ${ECAL_THIRDPARTY_BUILD_FTXUI}")
message(STATUS "ECAL_THIRDPARTY_BUILD_GTEST : ${ECAL_THIRDPARTY_BUILD_GTEST}")
message(STATUS "ECAL_THIRDPARTY_BUILD_HDF5 : ${ECAL_THIRDPARTY_BUILD_HDF5}")
message(STATUS "ECAL_THIRDPARTY_BUILD_PROTOBUF : ${ECAL_THIRDPARTY_BUILD_PROTOBUF}")
message(STATUS "ECAL_THIRDPARTY_BUILD_QWT : ${ECAL_THIRDPARTY_BUILD_QWT}")
message(STATUS "ECAL_THIRDPARTY_BUILD_RECYCLE : ${ECAL_THIRDPARTY_BUILD_RECYCLE}")
message(STATUS "ECAL_THIRDPARTY_BUILD_SIMPLEINI : ${ECAL_THIRDPARTY_BUILD_SIMPLEINI}")
message(STATUS "ECAL_THIRDPARTY_BUILD_SPDLOG : ${ECAL_THIRDPARTY_BUILD_SPDLOG}")
message(STATUS "ECAL_THIRDPARTY_BUILD_TCLAP : ${ECAL_THIRDPARTY_BUILD_TCLAP}")
message(STATUS "ECAL_THIRDPARTY_BUILD_TCP_PUBSUB : ${ECAL_THIRDPARTY_BUILD_TCP_PUBSUB}")
message(STATUS "ECAL_THIRDPARTY_BUILD_TERMCOLOR : ${ECAL_THIRDPARTY_BUILD_TERMCOLOR}")
message(STATUS "ECAL_THIRDPARTY_BUILD_TINYXML2 : ${ECAL_THIRDPARTY_BUILD_TINYXML2}")
message(STATUS "ECAL_THIRDPARTY_BUILD_UDPCAP : ${ECAL_THIRDPARTY_BUILD_UDPCAP}")
message(STATUS "ECAL_THIRDPARTY_BUILD_YAML-CPP : ${ECAL_THIRDPARTY_BUILD_YAML-CPP}")
message(STATUS "ECAL_LINK_HDF5_SHARED : ${ECAL_LINK_HDF5_SHARED}")
message(STATUS "CPACK_PACK_WITH_INNOSETUP : ${CPACK_PACK_WITH_INNOSETUP}")
message(STATUS "--------------------------------------------------------------------------------")