/
dzx0_mega.asm
452 lines (446 loc) · 14.8 KB
/
dzx0_mega.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
; -----------------------------------------------------------------------------
; ZX0 decoder by Einar Saukas
; "Mega" version (673 bytes, 28% faster)
; -----------------------------------------------------------------------------
; Parameters:
; HL: source address (compressed data)
; DE: destination address (decompressing)
; -----------------------------------------------------------------------------
dzx0_mega:
ld bc, $ffff ; preserve default offset 1
ld (dzx0m_last_offset+1), bc
inc bc
jr dzx0m_literals0
dzx0m_new_offset6:
ld c, $fe ; prepare negative offset
add a, a ; obtain offset MSB
jp c, dzx0m_new_offset5
add a, a
rl c
add a, a
jp c, dzx0m_new_offset3
add a, a
rl c
add a, a
jp c, dzx0m_new_offset1
dzx0m_elias_offset1:
add a, a
rl c
rl b
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp nc, dzx0m_elias_offset7
dzx0m_new_offset7:
inc c
ret z ; check end marker
ld b, c
ld c, (hl) ; obtain offset LSB
inc hl
rr b ; last offset bit becomes first length bit
rr c
ld (dzx0m_last_offset+1), bc ; preserve new offset
ld bc, 1
jp c, dzx0m_length7 ; obtain length
add a, a
rl c
add a, a
jp c, dzx0m_length5
add a, a
rl c
add a, a
jp c, dzx0m_length3
dzx0m_elias_length3:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_length1
dzx0m_length1:
push hl ; preserve source
ld hl, (dzx0m_last_offset+1)
add hl, de ; calculate destination - offset
ldir ; copy from offset
inc c
ldi ; copy one more from offset
pop hl ; restore source
add a, a ; copy from literals or new offset?
jr c, dzx0m_new_offset0
dzx0m_literals0:
inc c
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a ; obtain length
jp c, dzx0m_literals7
add a, a
rl c
add a, a
jp c, dzx0m_literals5
add a, a
rl c
add a, a
jp c, dzx0m_literals3
dzx0m_elias_literals3:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_literals1
dzx0m_literals1:
ldir ; copy literals
add a, a ; copy from last offset or new offset?
jr c, dzx0m_new_offset0
inc c
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a ; obtain length
jp c, dzx0m_reuse7
add a, a
rl c
add a, a
jp c, dzx0m_reuse5
add a, a
rl c
add a, a
jp c, dzx0m_reuse3
dzx0m_elias_reuse3:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_reuse1
dzx0m_reuse1:
push hl ; preserve source
ld hl, (dzx0m_last_offset+1)
add hl, de ; calculate destination - offset
ldir ; copy from offset
pop hl ; restore source
add a, a ; copy from literals or new offset?
jr nc, dzx0m_literals0
dzx0m_new_offset0:
ld c, $fe ; prepare negative offset
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a ; obtain offset MSB
jp c, dzx0m_new_offset7
add a, a
rl c
add a, a
jp c, dzx0m_new_offset5
add a, a
rl c
add a, a
jp c, dzx0m_new_offset3
dzx0m_elias_offset3:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_offset1
dzx0m_new_offset1:
inc c
ret z ; check end marker
ld b, c
ld c, (hl) ; obtain offset LSB
inc hl
rr b ; last offset bit becomes first length bit
rr c
ld (dzx0m_last_offset+1), bc ; preserve new offset
ld bc, 1
jp c, dzx0m_length1 ; obtain length
add a, a
rl c
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp c, dzx0m_length7
add a, a
rl c
add a, a
jp c, dzx0m_length5
dzx0m_elias_length5:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_length3
dzx0m_length3:
push hl ; preserve source
ld hl, (dzx0m_last_offset+1)
add hl, de ; calculate destination - offset
ldir ; copy from offset
inc c
ldi ; copy one more from offset
pop hl ; restore source
add a, a ; copy from literals or new offset?
jr c, dzx0m_new_offset2
dzx0m_literals2:
inc c
add a, a ; obtain length
jp c, dzx0m_literals1
add a, a
rl c
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp c, dzx0m_literals7
add a, a
rl c
add a, a
jp c, dzx0m_literals5
dzx0m_elias_literals5:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_literals3
dzx0m_literals3:
ldir ; copy literals
add a, a ; copy from last offset or new offset?
jr c, dzx0m_new_offset2
inc c
add a, a ; obtain length
jp c, dzx0m_reuse1
add a, a
rl c
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp c, dzx0m_reuse7
add a, a
rl c
add a, a
jp c, dzx0m_reuse5
dzx0m_elias_reuse5:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_reuse3
dzx0m_reuse3:
push hl ; preserve source
ld hl, (dzx0m_last_offset+1)
add hl, de ; calculate destination - offset
ldir ; copy from offset
pop hl ; restore source
add a, a ; copy from literals or new offset?
jr nc, dzx0m_literals2
dzx0m_new_offset2:
ld c, $fe ; prepare negative offset
add a, a ; obtain offset MSB
jp c, dzx0m_new_offset1
add a, a
rl c
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp c, dzx0m_new_offset7
add a, a
rl c
add a, a
jp c, dzx0m_new_offset5
dzx0m_elias_offset5:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_offset3
dzx0m_new_offset3:
inc c
ret z ; check end marker
ld b, c
ld c, (hl) ; obtain offset LSB
inc hl
rr b ; last offset bit becomes first length bit
rr c
ld (dzx0m_last_offset+1), bc ; preserve new offset
ld bc, 1
jp c, dzx0m_length3 ; obtain length
add a, a
rl c
add a, a
jp c, dzx0m_length1
add a, a
rl c
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp c, dzx0m_length7
dzx0m_elias_length7:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_length5
dzx0m_length5:
push hl ; preserve source
ld hl, (dzx0m_last_offset+1)
add hl, de ; calculate destination - offset
ldir ; copy from offset
inc c
ldi ; copy one more from offset
pop hl ; restore source
add a, a ; copy from literals or new offset?
jr c, dzx0m_new_offset4
dzx0m_literals4:
inc c
add a, a ; obtain length
jp c, dzx0m_literals3
add a, a
rl c
add a, a
jp c, dzx0m_literals1
add a, a
rl c
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp c, dzx0m_literals7
dzx0m_elias_literals7:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_literals5
dzx0m_literals5:
ldir ; copy literals
add a, a ; copy from last offset or new offset?
jr c, dzx0m_new_offset4
inc c
add a, a ; obtain length
jp c, dzx0m_reuse3
add a, a
rl c
add a, a
jp c, dzx0m_reuse1
add a, a
rl c
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp c, dzx0m_reuse7
dzx0m_elias_reuse7:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_reuse5
dzx0m_reuse5:
push hl ; preserve source
ld hl, (dzx0m_last_offset+1)
add hl, de ; calculate destination - offset
ldir ; copy from offset
pop hl ; restore source
add a, a ; copy from literals or new offset?
jr nc, dzx0m_literals4
dzx0m_new_offset4:
ld c, $fe ; prepare negative offset
add a, a ; obtain offset MSB
jp c, dzx0m_new_offset3
add a, a
rl c
add a, a
jp c, dzx0m_new_offset1
add a, a
rl c
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp c, dzx0m_new_offset7
dzx0m_elias_offset7:
add a, a
rl c
rl b
add a, a
jp nc, dzx0m_elias_offset5
dzx0m_new_offset5:
inc c
ret z ; check end marker
ld b, c
ld c, (hl) ; obtain offset LSB
inc hl
rr b ; last offset bit becomes first length bit
rr c
ld (dzx0m_last_offset+1), bc ; preserve new offset
ld bc, 1
jp c, dzx0m_length5 ; obtain length
add a, a
rl c
add a, a
jp c, dzx0m_length3
add a, a
rl c
add a, a
jp c, dzx0m_length1
dzx0m_elias_length1:
add a, a
rl c
rl b
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp nc, dzx0m_elias_length7
dzx0m_length7:
push hl ; preserve source
ld hl, (dzx0m_last_offset+1)
add hl, de ; calculate destination - offset
ldir ; copy from offset
inc c
ldi ; copy one more from offset
pop hl ; restore source
add a, a ; copy from literals or new offset?
jp c, dzx0m_new_offset6
dzx0m_literals6:
inc c
add a, a ; obtain length
jp c, dzx0m_literals5
add a, a
rl c
add a, a
jp c, dzx0m_literals3
add a, a
rl c
add a, a
jp c, dzx0m_literals1
dzx0m_elias_literals1:
add a, a
rl c
rl b
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp nc, dzx0m_elias_literals7
dzx0m_literals7:
ldir ; copy literals
add a, a ; copy from last offset or new offset?
jp c, dzx0m_new_offset6
inc c
add a, a ; obtain length
jp c, dzx0m_reuse5
add a, a
rl c
add a, a
jp c, dzx0m_reuse3
add a, a
rl c
add a, a
jp c, dzx0m_reuse1
dzx0m_elias_reuse1:
add a, a
rl c
rl b
ld a, (hl) ; load another group of 8 bits
inc hl
add a, a
jp nc, dzx0m_elias_reuse7
dzx0m_reuse7:
push hl ; preserve source
dzx0m_last_offset:
ld hl, 0
add hl, de ; calculate destination - offset
ldir ; copy from offset
pop hl ; restore source
add a, a ; copy from literals or new offset?
jr nc, dzx0m_literals6
jp dzx0m_new_offset6
; -----------------------------------------------------------------------------