-
Notifications
You must be signed in to change notification settings - Fork 15k
/
atom_application_delegate.mm
172 lines (145 loc) · 6.09 KB
/
atom_application_delegate.mm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
// Copyright (c) 2013 GitHub, Inc.
// Use of this source code is governed by the MIT license that can be
// found in the LICENSE file.
#import "shell/browser/mac/atom_application_delegate.h"
#include <memory>
#include <string>
#include "base/allocator/allocator_shim.h"
#include "base/allocator/buildflags.h"
#include "base/mac/mac_util.h"
#include "base/mac/scoped_objc_class_swizzler.h"
#include "base/strings/sys_string_conversions.h"
#include "base/values.h"
#include "shell/browser/browser.h"
#import "shell/browser/mac/atom_application.h"
#include "shell/browser/mac/dict_util.h"
#if BUILDFLAG(USE_ALLOCATOR_SHIM)
// On macOS 10.12, the IME system attempts to allocate a 2^64 size buffer,
// which would typically cause an OOM crash. To avoid this, the problematic
// method is swizzled out and the make-OOM-fatal bit is disabled for the
// duration of the original call. https://crbug.com/654695
static base::mac::ScopedObjCClassSwizzler* g_swizzle_imk_input_session;
@interface OOMDisabledIMKInputSession : NSObject
@end
@implementation OOMDisabledIMKInputSession
- (void)_coreAttributesFromRange:(NSRange)range
whichAttributes:(long long)attributes // NOLINT(runtime/int)
completionHandler:(void (^)(void))block {
// The allocator flag is per-process, so other threads may temporarily
// not have fatal OOM occur while this method executes, but it is better
// than crashing when using IME.
base::allocator::SetCallNewHandlerOnMallocFailure(false);
g_swizzle_imk_input_session->GetOriginalImplementation()(self, _cmd, range,
attributes, block);
base::allocator::SetCallNewHandlerOnMallocFailure(true);
}
@end
#endif // BUILDFLAG(USE_ALLOCATOR_SHIM)
@implementation AtomApplicationDelegate {
@private
bool isFirstActivation_;
}
- (void)setApplicationDockMenu:(electron::AtomMenuModel*)model {
menu_controller_.reset([[AtomMenuController alloc] initWithModel:model
useDefaultAccelerator:NO]);
}
- (void)applicationWillFinishLaunching:(NSNotification*)notify {
// Don't add the "Enter Full Screen" menu item automatically.
[[NSUserDefaults standardUserDefaults]
setBool:NO
forKey:@"NSFullScreenMenuItemEverywhere"];
electron::Browser::Get()->WillFinishLaunching();
}
- (void)applicationDidFinishLaunching:(NSNotification*)notify {
NSUserNotification* user_notification =
[notify userInfo][(id) @"NSApplicationLaunchUserNotificationKey"];
if (user_notification.userInfo != nil) {
std::unique_ptr<base::DictionaryValue> launch_info =
electron::NSDictionaryToDictionaryValue(user_notification.userInfo);
electron::Browser::Get()->DidFinishLaunching(*launch_info);
} else {
electron::Browser::Get()->DidFinishLaunching(base::DictionaryValue());
}
#if BUILDFLAG(USE_ALLOCATOR_SHIM)
// Disable fatal OOM to hack around an OS bug https://crbug.com/654695.
if (base::mac::IsOS10_12()) {
g_swizzle_imk_input_session = new base::mac::ScopedObjCClassSwizzler(
NSClassFromString(@"IMKInputSession"),
[OOMDisabledIMKInputSession class],
@selector(_coreAttributesFromRange:whichAttributes:completionHandler:));
}
#endif
isFirstActivation_ = true;
}
- (NSMenu*)applicationDockMenu:(NSApplication*)sender {
if (menu_controller_)
return [menu_controller_ menu];
else
return nil;
}
- (BOOL)application:(NSApplication*)sender openFile:(NSString*)filename {
std::string filename_str(base::SysNSStringToUTF8(filename));
return electron::Browser::Get()->OpenFile(filename_str) ? YES : NO;
}
- (void)applicationDidBecomeActive:(NSNotification*)notify {
// Originally `applicationShouldHandleReopen:hasVisibleWindows:` was used to
// emit Activate event. But the message is sent only when application is
// activated via Dock or Finder ignoring the App Switcher (cmd+tab).
//
// Using `applicationDidBecomeActive' is more reliable but to maintain
// compatibility with previous implementation we ignore activation
// immediately after the application launch, and compute the
// hasVisibleWindows on our own.
//
// Details in https://github.com/electron/electron/pull/23727.
if (isFirstActivation_) {
isFirstActivation_ = false;
return;
}
NSApplication* app = notify.object;
bool hasVisibleWindows = false;
for (NSWindow* win in app.windows) {
if (win.isVisible || win.miniaturized) {
hasVisibleWindows = true;
break;
}
}
electron::Browser* browser = electron::Browser::Get();
browser->Activate(hasVisibleWindows);
}
- (BOOL)application:(NSApplication*)sender
continueUserActivity:(NSUserActivity*)userActivity
restorationHandler:
#ifdef MAC_OS_X_VERSION_10_14
(void (^)(NSArray<id<NSUserActivityRestoring>>* restorableObjects))
#else
(void (^)(NSArray* restorableObjects))
#endif
restorationHandler {
std::string activity_type(base::SysNSStringToUTF8(userActivity.activityType));
std::unique_ptr<base::DictionaryValue> user_info =
electron::NSDictionaryToDictionaryValue(userActivity.userInfo);
if (!user_info)
return NO;
electron::Browser* browser = electron::Browser::Get();
return browser->ContinueUserActivity(activity_type, *user_info) ? YES : NO;
}
- (BOOL)application:(NSApplication*)application
willContinueUserActivityWithType:(NSString*)userActivityType {
std::string activity_type(base::SysNSStringToUTF8(userActivityType));
electron::Browser* browser = electron::Browser::Get();
return browser->WillContinueUserActivity(activity_type) ? YES : NO;
}
- (void)application:(NSApplication*)application
didFailToContinueUserActivityWithType:(NSString*)userActivityType
error:(NSError*)error {
std::string activity_type(base::SysNSStringToUTF8(userActivityType));
std::string error_message(
base::SysNSStringToUTF8([error localizedDescription]));
electron::Browser* browser = electron::Browser::Get();
browser->DidFailToContinueUserActivity(activity_type, error_message);
}
- (IBAction)newWindowForTab:(id)sender {
electron::Browser::Get()->NewWindowForTab();
}
@end