-
Notifications
You must be signed in to change notification settings - Fork 1.4k
/
enum.ex
110 lines (84 loc) · 3 KB
/
enum.ex
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
defmodule Ecto.Enum do
@moduledoc """
A custom type that maps atoms to strings.
`Ecto.Enum` must be used whenever you want to keep atom values in a field.
Since atoms cannot be persisted to the database, `Ecto.Enum` converts them
to string when writing to the database and converts them back to atoms when
loading data. It can be used in your schemas as follows:
field :status, Ecto.Enum, values: [:foo, :bar, :baz]
Composite types, such as `:array`, are also supported:
field :roles, {:array, Ecto.Enum}, values: [:Author, :Editor, :Admin]
`:values` must be a list of atoms. String values will be cast to atoms safely
and only if the atom exists in the list (otherwise an error will be raised).
Attempting to load any string not represented by an atom in the list will be
invalid.
The helper function `values/2` returns the values for a given schema and
field, which can be used in places like form drop-downs. For example,
given the following schema:
defmodule EnumSchema do
use Ecto.Schema
schema "my_schema" do
field :my_enum, Ecto.Enum, values: [:foo, :bar, :baz]
end
end
you can call `values/2` like this:
> Ecto.Enum.values(EnumSchema, :my_enum)
[:foo, :bar, :baz]
"""
use Ecto.ParameterizedType
@impl true
def type(_params), do: :string
@impl true
def init(opts) do
values = Keyword.get(opts, :values, nil)
unless is_list(values) and Enum.all?(values, &is_atom/1) do
raise ArgumentError, """
Ecto.Enum types must have a values option specified as a list of atoms. For example:
field :my_field, Ecto.Enum, values: [:foo, :bar]
"""
end
on_load = Map.new(values, &{Atom.to_string(&1), &1})
on_dump = Map.new(values, &{&1, Atom.to_string(&1)})
%{on_load: on_load, on_dump: on_dump, values: values}
end
@impl true
def cast(nil, _params), do: {:ok, nil}
def cast(data, params) do
case params do
%{on_load: %{^data => as_atom}} -> {:ok, as_atom}
%{on_dump: %{^data => _}} -> {:ok, data}
_ -> :error
end
end
@impl true
def load(nil, _, _), do: {:ok, nil}
def load(data, _loader, %{on_load: on_load}) do
case on_load do
%{^data => as_atom} -> {:ok, as_atom}
_ -> :error
end
end
@impl true
def dump(nil, _, _), do: {:ok, nil}
def dump(data, _dumper, %{on_dump: on_dump}) do
case on_dump do
%{^data => as_string} -> {:ok, as_string}
_ -> :error
end
end
@impl true
def equal?(a, b, _params), do: a == b
@impl true
def embed_as(_, _), do: :self
def values(schema, field) do
try do
schema.__changeset__()
rescue
_ in UndefinedFunctionError -> raise ArgumentError, "#{inspect schema} is not an Ecto schema"
else
%{^field => {:parameterized, Ecto.Enum, %{values: values}}} -> values
%{^field => {_, {:parameterized, Ecto.Enum, %{values: values}}}} -> values
%{} -> raise ArgumentError, "#{field} is not an Ecto.Enum field"
end
end
end